(* 
     lit 0, a  load constant a
     opr 0, a  execute opr a
     lod l, a  load variable l, a
     sto l, a  store variable l, a
     cal l, a  call procedure a at level l
     int 0, a  increment t-register by a
     jmp 0, a  jump to a
     jpc 0, a  jump conditional to a 
  *)
var (* 全局變量定義 *)
  fa: text; (* 文本文件fa用于列出源程序 *)
  fa1, fa2: text; (* 文本文件fa1用于列出類PCODE代碼、fa2用于記錄解釋執行類PCODE代碼的過程 *)
  listswitch: boolean; (* true set list object code *) (* 如果本變量置true，程序編譯后將為列出類PCODE代碼，
                                                          否則不列出類PCODE代碼 *)
  ch: char; (* last char read *) (* 主要用于詞法分析器，存放最近一次從文件中讀出的字符 *)
  sym: symbol; (* last symbol read *) (* 詞法分析器輸出結果之用，存放最近一次識別出來的token的類型 *)
  id: alfa;  (* last identifier read *) (* 詞法分析器輸出結果之用，存放最近一次識別出來的標識符的名字 *)
  num: integer; (* last number read *) (* 詞法分析器輸出結果之用，存放最近一次識別出來的數字的值 *)
  cc: integer;  (* character count *) (* 行緩沖區指針 *) 
  ll: integer;  (* line length *) (* 行緩沖區長度 *)
  kk: integer;  (* 引入此變量是出于程序性能考慮，見getsym過程注釋 *)
  cx: integer;  (* code allocation index *) (* 代碼分配指針，代碼生成模塊總在cx所指位置生成新的代碼 *)
  line: array[1..81] of char; (* 行緩沖區，用于從文件讀出一行，供詞法分析獲取單詞時之用 *)
  a: alfa; (* 詞法分析器中用于臨時存放正在分析的詞 *)
  code: array[0..cxmax] of instruction; (* 生成的類PCODE代碼表，存放編譯得到的類PCODE代碼 *)
  word: array[1..norw] of alfa; (* 保留字表 *)
  wsym: array[1..norw] of symbol; (* 保留字表中每一個保留字對應的symbol類型 *)
  ssym: array[' '..'^'] of symbol; (* 一些符號對應的symbol類型表 *)
    (* wirth uses "array[char]" here *)
  mnemonic: array[fct] of packed array[1..5] of char;(* 類PCODE指令助記符表 *)
  declbegsys, statbegsys, facbegsys: symset; (* 聲明開始、表達式開始和項開始符號集合 *)
  table: array[0..txmax] of record (* 符號表 *)
    name: alfa; (* 符號的名字 *)
    case kind: object1 of (* 符號的類型 *)
      constant: (* 如果是常量名 *)
        (val: integer); (* val中放常量的值 *)
      variable, procedur:  (* 如果是變量名或過程名 *)
        (level, adr, size: integer) (* 存放層差、偏移地址和大小 *)
        (* "size" lacking in orginal. I think it belons here *)
  end;
  fin, fout: text; (* fin文本文件用于指向輸入的源程序文件，fout程序中沒有用到 *)
  fname: string; (* 存放PL/0源程序文件的文件名 *)
  (* 我修改的代碼：原程序在此處使用alfa類型，無法在Turbo Pascal 7.0中通過，readln函數的參數不能為alfa型 *)
  err: integer; (* 出錯總次數 *)
(* 出錯處理過程error *)
(* 參數：n:出錯代碼 *)
procedure error(n: integer);
begin
  writeln('****', ' ': cc-1, '!', n:2); (* 在屏幕cc-1位置顯示!與出錯代碼提示，由于cc
                                           是行緩沖區指針，所以!所指位置即為出錯位置 *)
  writeln(fa1, '****', ' ': cc-1, '!', n:2); (* 在文件cc-1位置輸出!與出錯代碼提示 *)
  err := err + 1 (* 出錯總次數加一 *)
end (* error *);
(* 詞法分析過程getsym *)
procedure getsym;
var 
  i, j, k: integer;
  (* 讀取原程序中下一個字符過程getch *)
  procedure getch;
  begin
    if cc = ll then (* 如果行緩沖區指針指向行緩沖區最后一個字符就從文件讀一行到行緩沖區 *)
    begin
      if eof(fin) then (* 如果到達文件末尾 *)
      begin
        write('Program incomplete'); (* 出錯，退出程序 *)
        close(fa);
        close(fa1);
        close(fin);
        halt(0);        
        {goto 99}
        (* 我修改的代碼，由于Turbo Pascal 7.0中不允許跨過程的goto，就只能用上面的方法退出程序了。 *)
      end;
      ll := 0; (* 行緩沖區長度置0 *)
      cc := 0; (* 行緩沖區指針置行首 *)
      write(cx: 4, ' '); (* 輸出cx值，寬度為4 *)
      write(fa1, cx: 4, ' '); (* 輸出cx值，寬度為4到文件 *)
      while not eoln(fin) do (* 當未到行末時 *)
      begin
        ll := ll + 1; (* 行緩沖區長度加一 *)
        read(fin, ch); (* 從文件讀入一個字符到 ch *)
        write(ch); (* 在屏幕輸出ch *)
        write(fa1, ch); (* 把ch輸出到文件 *)
        line[ll] := ch; (* 把讀到的字符存入行緩沖區相應的位置 *)
      end;
      (* 可見，PL/0源程序要求每行的長度都小于81個字符 *)
      writeln; 
      ll := ll + 1; (* 行緩沖區長度加一，用于容納即將讀入的回車符CR *)
      read(fin, line[ll]);(* 把#13(CR)讀入行緩沖區尾部 *)
      read(fin, ch); (* 我添加的代碼。由于PC上文本文件換行是以#13#10(CR+LF)表示的，
                        所以要把多余的LF從文件讀出，這里放在ch變量中是由于ch變量的
                        值在下面即將被改變，把這個多余值放在ch中沒有問題 *)
      writeln(fa1); 
    end;
    cc := cc + 1; (* 行緩沖區指針加一，指向即將讀到的字符 *)
    ch := line[cc] (* 讀出字符，放入全局變量ch *)
  end (* getch *); 
begin (* getsym *)
  while (ch = ' ') or (ch = #13) do (* 我修改的代碼：這句原來是用于讀一個有效的字符
                                       (跳過讀出的字符中多余的空格)，但實際上還要跳
                                       過多余的回車 *)
    getch; 
  if ch in ['a'..'z'] then (* 如果讀出的字符是一個字母，說明是保留字或標識符 *)
  begin
    k := 0; (* 標識符緩沖區指針置0 *)
    repeat (* 這個循環用于依次讀出源文件中的字符構成標識符 *)
      if k < al then (* 如果標識符長度沒有超過最大標識符長度(如果超過，就取前面一部分，把多余的拋棄) *)
      begin
        k := k + 1; 
        a[k] := ch;
      end;
      getch (* 讀下一個字符 *)
    until not (ch in ['a'..'z','0'..'9']); (* 直到讀出的不是字母或數字，由此可知PL/0的標識符構成規則是:
                                              以字母開頭，后面跟若干個字母或數字 *)
    if k >= kk then (* 如果當前獲得的標識符長度大于等于kk *)
      kk := k (* 令kk為當前標識符長度 *)
    else
      repeat (* 這個循環用于把標識符緩沖后部沒有填入相應字母或空格的空間用空格補足 *)
        a[kk] := ' ';
        kk := kk - 1
      until kk = k;
    (* 在第一次運行這個過程時，kk的值為al，即最大標識符長度，如果讀到的標識符長度小于kk，
       就把a數組的后部沒有字母的空間用空格補足。
       這時，kk的值就成為a數組前部非空格字符的個數。以后再運行getsym時，如果讀到的標識符長度大于等于kk，
       就把kk的值變成當前標識符的長度。
       這時就不必在后面填空格了，因為它的后面肯定全是空格。反之如果最近讀到的標識符長度小于kk，那就需要從kk位置向前，
       把超過當前標識長度的空間填滿空格。
       以上的這樣一個邏輯，完全是出于程序性能的上考慮。其實完全可以簡單的把a數組中a[k]元素以后的空間不管三七二十一全填空格。 
    *)
    (* 下面開始二分法查找看讀出的標識符是不是保留字之一 *)
    id := a; (* 最后讀出標識符等于a *)
    i := 1; (* i指向第一個保留字 *)
    j := norw; (* j指向最后一個保留字 *)
    repeat
      k := (i + j) div 2; (* k指向中間一個保留字 *)
      if id <= word[k] then (* 如果當前的標識符小于k所指的保留字 *)
        j := k - 1; (* 移動j指針 *)
      if id >= word[k] then (* 如果當前的標識符大于k所指的保留字 *)
        i := k + 1 (* 移動i指針 *)
    until i > j; (* 循環直到找完保留字表 *)
    if i - 1 > j then (* 如果i - 1 > j表明在保留字表中找到相應的項，id中存的是保留字 *)
      sym := wsym[k] (* 找到保留字，把sym置為相應的保留字值 *)
    else
      sym := ident (* 未找到保留字，把sym置為ident類型，表示是標識符 *)
  end(* 至此讀出字符為字母即對保留字或標識符的處理結束 *)
  else (* 如果讀出字符不是字母 *)
    if ch in ['0'..'9'] then (* 如果讀出字符是數字 *)
    begin (* number *) (* 開始對數字進行處理 *)
      k := 0; (* 數字位數 *)
      num := 0; (* 數字置為0 *)
      sym := number; (* 置sym為number，表示這一次讀到的是數字 *)
      repeat (* 這個循環依次從源文件中讀出字符，組成數字 *)
        num := 10 * num + (ord(ch) - ord('0')); (* num * 10加上最近讀出的字符ASCII減'0'的ASCII得到相應的數值 *)
        k := k + 1; (* 數字位數加一 *)
        getch
      until not (ch in ['0'..'9']); (* 直到讀出的字符不是數字為止 *)
      if k > nmax then (* 如果組成的數字位數大于最大允許的數字位數 *)
        error(30) (* 發出30號錯 *)
    end(* 至此對數字的識別處理結束 *)
    else
      if ch = ':' then (* 如果讀出的不字母也不是數字而是冒號 *)
      begin
        getch; (* 再讀一個字符 *)
        if ch = '=' then (* 如果讀到的是等號，正好可以與冒號構成賦值號 *)
        begin
          sym := becomes; (* sym的類型設為賦值號becomes *)
          getch (* 再讀出下一個字 *)
        end
        else
          sym := nul; (* 如果不是讀到等號，那單獨的一個冒號就什么也不是 *)
      end(* 以上完成對賦值號的處理 *)
    else (* 如果讀到不是字母也不是數字也不是冒號 *)
      if ch = '<' then (* 如果讀到小于號 *)
      begin
        getch; (* 再讀一個字符 *)
        if ch = '=' then (* 如果讀到等號 *)
        begin
          sym := leq; (* 購成一個小于等于號 *)
          getch (* 讀一個字符 *)
        end
        else (* 如果小于號后不是跟的等號 *)
          sym := lss (* 那就是一個單獨的小于號 *)
      end
      else (* 如果讀到不是字母也不是數字也不是冒號也不是小于號 *)