@echo off
rem
rem MFilt.bat: Simple driver for compiling from the command line with MSVC 
rem using STL Error Decryption

rem ***************************************************************
rem * Runs *AS IS* under Windows NT/2000/XP.                      *
rem * For use under Win9x, see comments near the end of the file. *
rem ***************************************************************

rem (Updated 9/01/2002)

rem ********************************************************************
rem Configure the following variables as appropriate for your system:

rem COMPILER: Your compiler command (for MSVC, this needs to be the name
rem           of your native MSVC compiler. The name is normally CL,
rem	          unless you've installed the Proxy CL and renamed your native CL
rem	          to CL2--in that case, set COMPILER to CL2):
rem STLFILT:  Full pathname of the Perl script
rem MOPTIONS: Options for MSVC compiler (for VC7, this MUST be at least /WL)
rem POPTIONS: Options to Perl interpreter
rem FOPTIONS: Options to Filter (the Decryptor Perl script)
rem
rem The value of the environment variable FOPTS is concatenated onto the
rem value of FOPTIONS. This permits trying out different filtering options
rem without editing this batch file: just set FOPTS to the desired options
rem before running MFilt.BAT.
rem *********************************************************************

set COMPILER=cl
set STLFILT=c:\stlfilt.pl
set MOPTIONS=
set POPTIONS=
set FOPTIONS=/width:79

rem ********************************************************************

if not "%1" == "" goto compile

echo Usage: mfilt [MSVC options] source-file
echo Compiles source-file, filters errors through STL Error Decryptor.
echo (to supply Decryptor options, set the FOPTIONS variable in MFILT.BAT to
echo  your "permanent" options, and/or the FOPTS variable in your environment 
echo  to "temporary" options.)
echo.
goto done

:compile

%COMPILER% %MOPTIONS% %*  | perl %POPTIONS% %STLFILT% %FOPTIONS% %FOPTS%

rem For Windows9x/ME, rem out the line above and replace it with the one below:
rem %COMPILER% %MOPTIONS% %1 %2 %3 %4 %5 %6 %7 %8 %9  | perl %POPTIONS% %STLFILT% %FOPTIONS% %FOPTS%

:done