//============================================================
// 文件名稱：flash.asm     
// 實現(xiàn)功能: SPCE061 32K flash 的讀寫
// 日期： 2003/6/9
//============================================================



.INCLUDE hardware.inc

.DEFINE C_FLASH_SIZE			0x8000
.DEFINE C_FLASH_BLOCK_SIZE		0x100
.DEFINE C_FLASH_MATCH			0xAAAA
.DEFINE C_FLASH_PAGE_ERASE		0x5511		//擦除一頁
.DEFINE C_FLASH_MASS_ERASE		0x5522		//
.DEFINE C_FLASH_1WORD_PGM		0x5533		//寫一個字
.DEFINE C_FLASH_SEQUENT_PGM		0x5544		//寫多個字
.DEFINE C_FLASH_MAIN_BLOCK		0x5555		
.DEFINE C_FLASH_INFORM_BLOCK	0x5566		


.CODE
//============================================================================================
//函數(shù): F_FlashWrite1Word()
//語法：void F_FlashWrite1Word(int addr,int Value )
//描述：寫一個字到FLASH中
//參數(shù)：1、被寫數(shù)據(jù)的存儲地址  2、被寫數(shù)據(jù)
//返回：無
//===============================================================================================
.PUBLIC _F_FlashWrite1Word
.DEFINE  P_Flash_Ctrl  0x7555
_F_FlashWrite1Word:	 .proc 
	push bp to [sp]
	bp = sp+1
	r1 = C_FLASH_MATCH				//AAAA
	[P_Flash_Ctrl] = r1
	r1 = C_FLASH_1WORD_PGM			//5533
	[P_Flash_Ctrl] = r1
	r1 =  [bp+3]					//flash address
	r2 =  [bp+4]					//data
	[r1] = r2
	
	pop bp from [sp]
	retf
	.ENDP

//=============================================================================================
//函數(shù)：F_FlashWrite()
//語法：F_FlashWrite(int sector,int &num, int size)
//描述：順序寫多個字
//參數(shù)：1、被寫數(shù)據(jù)的起始地址 2、被寫數(shù)據(jù) 3、寫數(shù)據(jù)的數(shù)量
//返回：無
//============================================================================================= 
.PUBLIC _F_FlashWrite
_F_FlashWrite: .proc 
	push bp to [sp]
	bp = sp+1
	r1 = [bp+3]						//flash base address
	r2 = [bp+4]						//data
	r3 = [bp+5]						//多個字節(jié)	
	r4 = C_FLASH_MATCH				//AAAA
	[P_Flash_Ctrl] = r4
L_FlashWriteLoop:
	r4 = C_FLASH_SEQUENT_PGM		//5544
	[P_Flash_Ctrl] = r4
	r4 = [r2++]
	[r1++] = r4

	r3 -= 1
	jnz L_FlashWriteLoop
	[P_Flash_Ctrl] = r3				//寫結束
	pop bp from [sp]
	retf
	.ENDP


// ============================================================================================
//函數(shù)：F_FlashErase()
//語法：void F_FlashErase(sector)
//描述：擦除256字節(jié)
//參數(shù): 1、擦除頁的起始地址
//返回：無
// ============================================================================================
.PUBLIC _F_FlashErase
_F_FlashErase: .proc 
	push bp to [sp]
	bp = sp + 1
	r1 = C_FLASH_MATCH				//AAAA
	[P_Flash_Ctrl] = r1
	r1 = C_FLASH_PAGE_ERASE			//5511
	[P_Flash_Ctrl] = r1
	r1 = [bp+3]						//擦除一頁
	[r1] = r1

	pop bp from [sp]
	retf
	.ENDP
    .END