@echo off
rem Creates all ASYNC modules and updates ASYNCx.LIB.
:begin
if *%1==*t goto good
if *%1==*s goto good
if *%1==*c goto good
if *%1==*m goto good
if *%1==*l goto good
if *%1==*h goto good
echo usage: CREASYNC model ...
echo where model is one of the letters t, s, c, m, l, or h.
echo The letter must be in lower case. t is for TINY, s is for
echo SMALL, c is for COMPACT, m is for MEDIUM, l is for LARGE,
echo and h is for HUGE.
echo Select the memory model you want from among these 6 choices
echo or use "CREASYNC t s c m l h" to create all 6 models.
goto nextarg
:good
echo on
tcc -c -m%1 async break eof getc getlcr getlsr getmcr getmsr
@if errorlevel==1 goto end
tcc -c -m%1 gets iflush oflush printf puts putc read setlcr
@if errorlevel==1 goto end
tcc -c -m%1 setmcr setxon ungetc waitfor waitquie write
@if errorlevel==1 goto end
tlib async%1 /C -+async-+break-+eof-+getc-+getlcr-+getlsr-+getmcr-+getmsr
@if errorlevel==1 goto end
tlib async%1 /C -+gets-+iflush-+oflush-+printf-+puts-+putc-+read-+setlcr
@if errorlevel==1 goto end
tlib async%1 /C -+setmcr-+setxon-+ungetc-+waitfor-+waitquie-+write
@if errorlevel==1 goto end
del *.obj
del async%1.bak
@echo off
:nextarg
if *%2==* goto end
shift
goto begin
:end