;/****************************************Copyright (c)**************************************************
;**                               廣州周立功單片機發展有限公司
;**                                     研    究    所
;**                                        產品一部 
;**
;**                                 http://www.zlgmcu.com
;**
;**--------------文件信息--------------------------------------------------------------------------------
;**文   件   名: IRQ.inc
;**創   建   人: 陳明計
;**最后修改日期: 2004年8月27日
;**描        述: 定義IRQ匯編接口代碼宏
;**
;**--------------歷史版本信息----------------------------------------------------------------------------
;** 創建人: 陳明計
;** 版  本: v1.0
;** 日　期: 2004年8月27日
;** 描　述: 原始版本
;**
;**--------------當前版本修訂------------------------------------------------------------------------------
;** 修改人:
;** 日　期:
;** 描　述:
;**
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/

NoInt       EQU 0x80

USR32Mode   EQU 0x10
SVC32Mode   EQU 0x13
SYS32Mode   EQU 0x1f
IRQ32Mode   EQU 0x12
FIQ32Mode   EQU 0x11


;引入的外部標號在這聲明
        IMPORT  OSIntCtxSw                      ;任務切換函數
        IMPORT  OSIntExit                       ;中斷退出函數
        IMPORT  OSTCBCur
        IMPORT  OSTCBHighRdy
        IMPORT  OSIntNesting                    ;中斷嵌套計數器
        IMPORT  StackUsr
        IMPORT  OsEnterSum

    CODE32

    AREA    IRQ,CODE,READONLY

    MACRO
$IRQ_Label HANDLER $IRQ_Exception_Function

        EXPORT  $IRQ_Label                      ; 輸出的標號
        IMPORT  $IRQ_Exception_Function         ; 引用的外部標號

$IRQ_Label
        SUB     LR, LR, #4                      ; 計算返回地址
        STMFD   SP!, {R0-R3, R12, LR}           ; 保存任務環境
        MRS     R3, SPSR                        ; 保存狀態
        STMFD   SP, {R3, SP, LR}^               ; 保存用戶狀態的R3,SP,LR,注意不能回寫
                                                ; 如果回寫的是用戶的SP，所以后面要調整SP
        LDR     R2,  =OSIntNesting              ; OSIntNesting++
        LDRB    R1, [R2]
        ADD     R1, R1, #1
        STRB    R1, [R2]

        SUB     SP, SP, #4*3
        
        MSR     CPSR_c, #(NoInt | SYS32Mode)    ; 切換到系統模式
        CMP     R1, #1
        LDREQ   SP, =StackUsr
        
        BL      $IRQ_Exception_Function         ; 調用c語言的中斷處理程序

        MSR     CPSR_c, #(NoInt | SYS32Mode)    ; 切換到系統模式
        LDR     R2, =OsEnterSum                 ; OsEnterSum,使OSIntExit退出時中斷關閉
        MOV     R1, #1
        STR     R1, [R2]

        BL      OSIntExit

        LDR     R2, =OsEnterSum                 ; 因為中斷服務程序要退出，所以OsEnterSum=0
        MOV     R1, #0
        STR     R1, [R2]

        MSR     CPSR_c, #(NoInt | IRQ32Mode)    ; 切換回irq模式
        LDMFD   SP, {R3, SP, LR}^               ; 恢復用戶狀態的R3,SP,LR,注意不能回寫
                                                ; 如果回寫的是用戶的SP，所以后面要調整SP
        LDR     R0, =OSTCBHighRdy
        LDR     R0, [R0]
        LDR     R1, =OSTCBCur
        LDR     R1, [R1]
        CMP     R0, R1

        ADD     SP, SP, #4*3                    ; 
        MSR     SPSR_cxsf, R3
        LDMEQFD SP!, {R0-R3, R12, PC}^          ; 不進行任務切換
        LDR     PC, =OSIntCtxSw                 ; 進行任務切換
    MEND

    END
;/*********************************************************************************************************
;**                            End Of File
;********************************************************************************************************/