/* 
 * file: dcc_ucos_flash.dld
 *
 * Barnett Systems Engineering
 * MPC8xxFADS Linker Command File for embedded Diab Environment
 * MPC8xxFADS specific
 *
 * Author: Harry E. Barnett  11/11/99
 * harryb@hbbse.com http://www.hbbse.com
 *
 * Version V1.00
 *
 * Changed for burning ROM
 * 	by SiNgeR
 * 	2004.7.20
 */



/* 
 * MEMORY
 *   |
 *   +-- 16 MB RAM at address 0xff000000
 *   |
 *   +-- 4  MB ROM at address 0x00000000 (2 chips)
 *	 |
 *	 +-- 2  MB ROM at address 0x00000000
 *	 |
 *	 +-- 2  MB ROM at address 0x00200000
 */ 

MEMORY
{
	/* Other RAM */
	ram2:	org = 0xff000000, len = 0x00f00000
	
	/* Vector Table */
	ram1:	org = 0xfff00000, len = 0x00005000
	
	/* System Stack */
	stack:	org = 0xfff05000, len = 0x000fb000
	

	
	rom1:	org = 0x00000000, len = 0x00005000
	rom2:	org = 0x00005000, len = 0x000fb000	
	
}

SECTIONS
{	

	.startup (TEXT)	: 
	{
		bsestart.o(.text)
		bsecrt0.o(.text)
		*(.startup)
		__SOURCE = (. + 3) & ~3;
		
	} > rom2


	/* Other Code, copy to RAM */
	
	GROUP : 
	{
		__DESTINATION = .;

		.text (TEXT) LOAD(__SOURCE) : 
		{
			*(.text)
			*(.rdata)
			*(.rodata)
			*(.frame_info)
			*(.init)
			*(.fini)
	
		}

		__ETEXT = .;
		__DATA_ROM_START = __SOURCE + __ETEXT - __DESTINATION;

		.sdata2 (DATA) LOAD(__DATA_ROM_START) : {}
		
		__DATA_LOC = .;
		__DATA_LOC_ROM = __DATA_ROM_START + __DATA_LOC - __ETEXT;
		
		.data (DATA) LOAD(__DATA_LOC_ROM) : {}
		
		__SDA2_LOC = .;
		__SDA2_LOC_ROM = __DATA_ROM_START + __SDA2_LOC - __ETEXT;
		
		.sdata (DATA) LOAD(__SDA2_LOC_ROM) : { *(.sdata) }

		__DATA_END = .;

		__BSS_START	= .;
		.sbss (BSS)	: {}
		.bss  (BSS)	: {}
		__BSS_END	= .;

		__HEAP_START	= .;

	} > ram2
}

__DATA_ROM 	= 0;
__DATA_RAM	= __DATA_ROM;

/*
__SP_INIT	= ADDR(ram2) + SIZEOF(ram2);
__SP_END	= __SP_INIT - 0x100000;
*/
__SP_INIT	= ADDR(stack) + SIZEOF(stack);
__SP_END	= ADDR(stack);


__HEAP_END	= __SP_END;	/* Heap contiguous with stack. */