Unit Main;

Interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls, Menus, DXClass, DXSprite, DXInput, DXDraws;

type

  TDirection = (DrUp, DrDown, DrLeft, DrRight, DrUpLeft, DrUpRight, DrDownLeft, DrDownRight);
  {自定義游戲中所用到的方向}

  TPlayerSprite = class (TImageSprite)
  CanMove: Boolean;
  protected
    procedure DoMove(MoveCount: Integer); override;
    procedure MoveTo(MoveCount:Integer; Direction: TDirection);
    procedure DoCollision(Sprite: TSprite; var Done: Boolean); override;
  end;

  TMainForm = class(TDXForm) {此處使用優(yōu)化過的TDXForm來代替TForm}
    DXTimer: TDXTimer;
    DXDraw: TDXDraw;
    DXSpriteEngine: TDXSpriteEngine;
    DXInput: TDXInput;
    ImageList: TDXImageList;
    procedure FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
    procedure DXDrawFinalize(Sender: TObject);
    procedure DXDrawInitialize(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure DXTimerTimer(Sender: TObject; LagCount: Integer);
    procedure DXDrawMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
    procedure DXDrawMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
    procedure DXDrawMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    AnchorX: Integer;
    AnchorY: Integer; {鼠標(biāo)點(diǎn)擊發(fā)生的位置}
    MouseX: Integer;
    MouseY: Integer; {鼠標(biāo)當(dāng)前位置}
    PlayerSprite: TPlayerSprite; {游戲中我們所用鼠標(biāo)控制的人物}
    BackSprite: TBackGroundSprite; {游戲的背景圖}
  end;

const
  speed=5; {游戲人物向各個(gè)方向運(yùn)動(dòng)時(shí)的動(dòng)畫播放速度}

var
  MainForm: TMainForm;
  Steps: Integer; {用于控制切換精靈動(dòng)畫圖片的參數(shù)}


implementation

{$R *.DFM}

procedure TPlayerSprite.DoCollision(Sprite: TSprite; var Done: Boolean);
begin
  Done:=False; {已經(jīng)偵測(cè)到碰撞，不再重復(fù)檢測(cè)碰撞}
  {檢測(cè)游戲人物是否與其它精靈發(fā)生了碰撞，此處可以擴(kuò)展為對(duì)話等情節(jié)}
end;

procedure TPlayerSprite.DoMove(MoveCount: Integer);
var
  l,r,d,u: Boolean;
  absX,absY: Integer; {游戲人物的當(dāng)前位置與目的地的絕對(duì)距離}
begin
  inherited DoMove(MoveCount);
  MoveCount:=Trunc(MoveCount*1.5);
  l:=false; r:=false; u:=false; d:=false;

  if (Trunc(X)-MainForm.AnchorX>0) then l:=true else r:=true;
  if (Trunc(Y)-MainForm.AnchorY>0) then u:=true else d:=true;

  absX:=abs(Trunc(X)-MainForm.AnchorX);
  absY:=abs(Trunc(Y)-MainForm.AnchorY);

  if absX<4 then begin l:=false; r:=false; end;
  if absY<4 then begin u:=false; d:=false; end;
  {如果絕對(duì)距離已經(jīng)小于四個(gè)象素，則認(rèn)為已經(jīng)到達(dá)目的地}

  if u and l and not d and not r then MoveTo(MoveCount,DrUpLeft);
  if u and r and not l and not d then MoveTo(MoveCount,DrUpRight);
  if d and l and not r and not u then MoveTo(MoveCount,DrDownLeft);
  if d and r and not u and not l then MoveTo(MoveCount,DrDownRight);
  if d and not l and not r and not u then MoveTo(MoveCount,DrDown);
  if u and not l and not r and not d then MoveTo(MoveCount,DrUp);
  if l and not u and not r and not d then MoveTo(MoveCount,DrLeft);
  if r and not l and not u and not d then MoveTo(MoveCount,DrRight);
  {根據(jù)目的地來判斷運(yùn)動(dòng)的方向，從而播放相應(yīng)方向運(yùn)動(dòng)的動(dòng)畫}

  Collision; {檢測(cè)碰撞}
  Engine.X := -X+Engine.Width div 2 - Width div 2;
  Engine.Y := -Y+Engine.Height div 2 - Height div 2;
  {移動(dòng)引擎，從而是游戲人物處于舞臺(tái)的正中央}
end;


procedure TMainForm.DXTimerTimer(Sender: TObject; LagCount: Integer);
begin
  if not DXDraw.CanDraw then exit;
  {檢測(cè)DXDraw是否可以畫，否則退出}
  DXInput.Update;
  {捕捉各類設(shè)備輸入，這里我們用來檢測(cè)鼠標(biāo)的輸入}

  LagCount := 1000 div 60;
  {用來控制整個(gè)游戲運(yùn)行速度的參數(shù)}
  DXSpriteEngine.Move(LagCount);
  DXSpriteEngine.Dead;

  DXDraw.Surface.Fill(0);
  {將整個(gè)屏幕填充為黑色}
  DXSpriteEngine.Draw;

  with DXDraw.Surface.Canvas do
  begin
    brush.style:=bsclear;
    pen.style:=psclear;
    pen.color:=clwhite;
    Font.Color:=clWhite;
    Font.Size:=10;

    textout(10,10,'Press ESC to Quit');
    textout(100,100,'X: '+IntToStr(AnchorX)+'Y: '+IntToStr(AnchorY));
    {鼠標(biāo)點(diǎn)擊的位置經(jīng)轉(zhuǎn)換后在游戲世界中的坐標(biāo)}
    textout(100,200,'Sprit x:'+IntToStr(Trunc(PlayerSprite.x))+'Y: '+IntToStr(Trunc(PlayerSprite.y)));
    {精靈在游戲世界中的坐標(biāo)}
    textout(100,300,'Relative x:'+IntToStr(AnchorX-Trunc(PlayerSprite.x))+'Y: '+IntToStr(AnchorY-Trunc(PlayerSprite.y)));
    {精靈當(dāng)前位置與目的地之間的絕對(duì)距離}
    textout(200,100,'Mouse x:'+IntToStr(MainForm.MouseX)+'Y: '+IntToStr(MainForm.MouseY));
    {鼠標(biāo)當(dāng)前位置，相對(duì)于窗口左上角，未轉(zhuǎn)換為游戲世界坐標(biāo)}
    Release;
  end;
  {在字母上輸出相應(yīng)參數(shù)，用于程序調(diào)試}
  DXDraw.Flip;
  {將內(nèi)存中的后臺(tái)表面翻轉(zhuǎn)到當(dāng)前并且顯示}
end;

procedure TMainForm.DXDrawFinalize(Sender: TObject);
begin
  DXTimer.Enabled := False;
  {關(guān)閉定時(shí)器}
end;

procedure TMainForm.DXDrawInitialize(Sender: TObject);
begin
  DXTimer.Enabled := True;
  {啟動(dòng)定時(shí)器}
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  Steps:=0;
  AnchorX:=0;
  AnchorY:=0;

  MouseX:=320;
  MouseY:=240;
  {默認(rèn)使鼠標(biāo)處于屏幕的中央}


  ImageList.Items.MakeColorTable;

  DXDraw.ColorTable := ImageList.Items.ColorTable;
  DXDraw.DefColorTable := ImageList.Items.ColorTable;
  DXDraw.UpdatePalette;
  {更新系統(tǒng)調(diào)色板}

  BackSprite:=TBackgroundSprite.Create(DXSpriteEngine.Engine);
  with TBackgroundSprite(BackSprite) do
  begin
    SetMapSize(1, 1);{設(shè)定背景顯示樣式為1×1}
    Image := ImageList.Items.Find('background'); {載入背景圖片}
    Z := -2;  {設(shè)定背景層次}
    Tile := True; {設(shè)定背景填充樣式為平鋪}
  end;

  PlayerSprite := TPlayerSprite.Create(DXSpriteEngine.Engine);
  with TPlayerSprite(PlayerSprite) do
  begin
    Image := ImageList.Items.Find('player');
    Z := 2;
    Width := Image.Width;
    Height := Image.Height;
  end;
  {載入游戲人物}
end;

procedure TMainForm.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  {如果按了Esc，則退出}
  if Key=VK_ESCAPE then
    Close;

  {全屏模式和窗口模式的切換}
  if (ssAlt in Shift) and (Key=VK_RETURN) then
  begin
    DXDraw.Finalize;

    if doFullScreen in DXDraw.Options then
    begin
      RestoreWindow;

      DXDraw.Cursor := crNone;
      BorderStyle := bsSizeable;
      DXDraw.Options := DXDraw.Options - [doFullScreen];
    end else
    begin
      StoreWindow;

      DXDraw.Cursor := crNone;
      BorderStyle := bsNone;
      DXDraw.Options := DXDraw.Options + [doFullScreen];
    end;

    DXDraw.Initialize;
  end;
end;


procedure TMainForm.DXDrawMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  AnchorX := x + Trunc(PlayerSprite.x)-320;
  AnchorY := y + Trunc(PlayerSprite.y)-240;
  {將鼠標(biāo)在屏幕上點(diǎn)擊的位置轉(zhuǎn)換到游戲世界中}
  PlayerSprite.CanMove:=True;
  {此參數(shù)允許鼠標(biāo)拖動(dòng)}
end;

procedure TMainForm.DXDrawMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  if PlayerSprite.CanMove then
  begin
    AnchorX := x + Trunc(PlayerSprite.x)-320;
    AnchorY := y + Trunc(PlayerSprite.y)-240;
    {在鼠標(biāo)拖動(dòng)過程中將鼠標(biāo)在屏幕上點(diǎn)擊的位置轉(zhuǎn)換到游戲世界中}
  end;

  MouseX:=X;
  MouseY:=Y;
  {鼠標(biāo)當(dāng)前位置}
end;

procedure TMainForm.DXDrawMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  PlayerSprite.CanMove:=False;
end;


procedure TMainForm.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  DXSpriteEngine.Free;
end;

procedure TPlayerSprite.MoveTo(MoveCount: Integer; Direction: TDirection);
begin
  {控制精靈往各個(gè)方向移動(dòng)}
  case Direction of
  DrUp:
    begin
      Y := Y-(150/1000)*MoveCount;
      Inc(steps);
      AnimPos:=steps div speed+20+1;
      {當(dāng)前動(dòng)畫中播放的圖片序號(hào)}
      if steps>4*speed-2 then steps:=0;
    end;
  DrDown:
    begin
      Y := Y+(150/1000)*MoveCount;
      Inc(steps);
      AnimPos:=steps div speed+1;
      if steps> 4*speed-2 then steps:=0;
    end;
  DrLeft:
    begin
      X := X-(150/1000)*MoveCount;
      Inc(steps);
      AnimPos:=steps div speed+10+1;
      if steps>4*speed-2 then steps:=0;
    end;
  DrRight:
    begin
      X := X+(150/1000)*MoveCount;
      Inc(steps);
      AnimPos:=steps div speed+30+1;
      if steps>4*speed-2 then steps:=0;
    end;
  DrUpLeft:
    begin
      X := X-(150/1000)*MoveCount;
      Y := Y-(150/1000)*MoveCount;
      Inc(steps);
      AnimPos:=steps div speed+15+1;
      if steps>4*speed-2 then steps:=0;
    end;
  DrUpRight:
    begin
      X := X+(150/1000)*MoveCount;
      Y := Y-(150/1000)*MoveCount;
      Inc(steps);
      AnimPos:=steps div speed+25+1;
      if steps>4*speed-2 then steps:=0;
    end;
  DrDownLeft:
    begin
      X := X-(150/1000)*MoveCount;
      Y := Y+(150/1000)*MoveCount;
      Inc(steps);
      AnimPos:=steps div speed+5+1;
      if steps>4*speed-2 then steps:=0;
    end;
  DrDownRight:
    begin
      X := X + (150/1000)*MoveCount;
      Y := Y + (150/1000)*MoveCount;
      Inc(steps);
      AnimPos:=steps div speed+35+1;
      if steps>4*speed-2 then steps:=0;
    end;
  end;
end;

end.