/* 
 * file: bsetest.dld
 *
 * Barnett Systems Engineering
 * MPC8xxFADS Linker Command File for embedded Diab Environment
 * MPC8xxFADS specific
 *
 * Author: Harry E. Barnett  11/11/99
 * harryb@hbbse.com http://www.hbbse.com
 *
 * Version V1.00
 *
 */

/* 
 *	4MB RAM at address 0x0000000
 */ 

MEMORY
{
	ram:	org = 0x000000, len = 0x400000
}

SECTIONS
{
	/*
	 * The first GROUP contains code and constant data.
	 */

	GROUP : {
		/* Take all code from all objects and libraries.	    */

		.text (TEXT)	: {
			*(.text)
			*(.rdata)
			*(.rodata)
			*(.frame_info)
			*(.init)
			*(.fini)
		}
		__ETEXT = .;

		.sdata2 (DATA)	: {}   /* small CONST area */

	} > ram

	/*
	 * The second GROUP allocates space for the initialized data and
	 * uninitialized data in the "ram" section.
	 */

	GROUP : {
		__DATA_ROM	= .;
		__DATA_RAM	= .;
		.data (DATA)	: {}

		/* .sdata is the "small data area" */

		.sdata (DATA)	: { *(.sdata) }
		__DATA_END	= .;

		/* Allocate uninitialized sections. */

		__BSS_START	= .;
		.sbss (BSS)	: {}
		.bss  (BSS)	: {}
		__BSS_END	= .;


		/* Any remaining space will be used as a heap. */

		__HEAP_START	= .;
	} > ram
}

__SP_INIT	= ADDR(ram) + SIZEOF(ram);
__SP_END	= __SP_INIT - 0x100000;	/* Stack is 1MB. */
__HEAP_END	= __SP_END;	/* Heap contiguous with stack. */