*********************************************************************************
*       (C) COPYRIGHT TEXAS INSTRUMENTS, INC. 1996                              *
*********************************************************************************
*                                                                               *
* MODULE NAME:  power.asm                                                       *
*                                                                               *
* AUTHORS:      Simon Lau and Nathan Baltz                                      *
*                                                                               *
* DESCRIPTION:  PHASE FIVE  Power Spectrum                                      *
*               This function is called from the main module of the 'C54x Real  *
*               FFT code.  It computes the power spectrum of the Real FFT       *
*               output.                                                         *
*                                                                               *
* REGISTER USAGE:   AR2   pointer to AR[k], AI[k]                               *
*                   AR3   pointer to output buffer                              *
*                   BRC                                                         *
*                                                                               *
* DATE:         7-16-1996                                                       *
*                                                                               *
*********************************************************************************

        .mmregs
        .include    "fft_size.inc"
        .def        power
        .ref        fft_data, real_fft_output

        .asg    AR2,AX
        .asg    AR3,OUTPUT_BUF


        .text

power:
        STM     #fft_data,AX                    ; AR2 points to AR[0]
        STM     #K_FFT_SIZE*2-1,BRC
        RPTBD   power_end-1
        STM     #real_fft_output,OUTPUT_BUF

        SQUR    *AX+,A                          ; A := AR^2
        SQURA   *AX+,A                          ; A := AR^2 + AI^2
        STH     A,*OUTPUT_BUF+                 

power_end:
        RET                                     ; return to Real FFT main module

        .end