;/*
;*********************************************************************************************************
;* 文件: OS_CPU_A.S
;* 描述: uC/OS-II在 LPC210X 上的移植代碼匯編代碼部分.
;* 編寫: 深思 (001-12345@sohu.com).
;*********************************************************************************************************
;*/

        AREA    os_cpu_a, CODE, READONLY
        CODE32

        IMPORT  OSTCBCur                                ; 指向當前任務(wù)TCB的指針.
        IMPORT  OSTCBHighRdy                            ; 指向?qū)⒁\行的任務(wù)TCB的指針.
        IMPORT  OSPrioCur                               ; 當前任務(wù)的優(yōu)先級.
        IMPORT  OSPrioHighRdy                           ; 將要運行的任務(wù)的優(yōu)先級.
        IMPORT  OSTaskSwHook                            ; 任務(wù)切換的鉤子函數(shù).
        IMPORT  OsEnterSum                              ; 關(guān)中斷計數(shù)器（關(guān)中斷信號量）.
        IMPORT  OSRunning                               ; uC/OS-II運行標志.

        EXPORT  OSIntCtxSw2                             ; 中斷級任務(wù)切換函數(shù).
        EXPORT  OSCtxSw                                 ; 任務(wù)級任務(wù)切換函數(shù).
        EXPORT  OSStartHighRdy2                         ; 開始最高優(yōu)先級任務(wù).

NoInt       EQU 0x80                                    ; 關(guān)中斷.
SYS32Mode   EQU 0x1f                                    ; 系統(tǒng)模式代碼.
IRQ32Mode   EQU 0x12                                    ; IRQ中斷模式代碼.
SVC32Mode   EQU 0x13                                    ; 管理模式代碼.

;/*
;*********************************************************************************************************
;* 函數(shù): OSIntCtxSw2.
;* 描述: IRQ 中斷級任務(wù)切換.
;*********************************************************************************************************
;*/
OSIntCtxSw2
        STMFD   SP!,        {R0-R1}
        MRS     R0,         SPSR
        MOV     R1,         LR
        MSR     CPSR_c,     #(NoInt | SVC32Mode)        ; 切到管理模式.
        MOV     LR,         R1
        MSR     SPSR_cxsf,  R0
        MSR     CPSR_c,     #(NoInt | IRQ32Mode)        ; 切回 IRQ 模式.
        LDMFD   SP!,        {R0-R1}
        B       OSCtxSw

;/*
;*********************************************************************************************************
;* 函數(shù): OSCtxSw.
;* 描述: 任務(wù)級任務(wù)切換.
;*********************************************************************************************************
;*/
OSCtxSw
        MSR     CPSR_c,     #(NoInt | SYS32Mode)        ; 切換到系統(tǒng)模式.
        STMFD   SP!,        {R0-R12,R14}                ; 保存 LR.R12-R0.
        MOV     R0,         SP
        MSR     CPSR_c,     #(NoInt | SVC32Mode)        ; 切回管理模式.
        MOV     R12,        LR
        MRS     R11,        SPSR
        LDR     R10,        =OsEnterSum
        LDR     R10,        [R10]
        STMFD   R0!,        {R10-R12}                   ; 保存 PC,CPSR,OsEnterSum.

        LDR     R1,         =OSTCBCur
        LDR     R1,         [R1]
        STR     R0,         [R1]                        ; OSTCBCur->OSTCBStkPtr = SP.

        BL      OSTaskSwHook                            ; 調(diào)用鉤子函數(shù).

        LDR     R0,         =OSPrioCur                  ; OSPrioCur = OSPrioHighRdy.
        LDR     R1,         =OSPrioHighRdy
        LDRB    R1,         [R1]
        STRB    R1,         [R0]

        LDR     R0,         =OSTCBCur                   ; OSTCBCur  = OSTCBHighRdy.
        LDR     R1,         =OSTCBHighRdy
        LDR     R1,         [R1]
        STR     R1,         [R0]
OSCtxSw_10
        LDR     R0,         [R1, #0]                    ; 獲取新任務(wù)堆棧指針 OSTCBHighRdy->OSTCBStkPtr.

        LDMFD   R0!,        {R10-R12}                   ; 恢復 PC,SPSR,OsEnterSum.
        LDR     R1,         =OsEnterSum
        STR     R10,        [R1]
        MSR     SPSR_cxsf,  R11
        MOV     LR,         R12

        MSR     CPSR_c,     #(NoInt | SYS32Mode)        ; 切換到系統(tǒng)模式.
        MOV     SP,         R0
        LDMFD   SP!,        {R0-R12,R14}                ; 恢復 LR.R12-R0.
        
        MSR     CPSR_c,     #(NoInt | SVC32Mode)        ; 進入管理模式.
        MOVS    PC,         LR                          ; 運行新任務(wù).

;/*
;*********************************************************************************************************
;* 函數(shù): OSStartHighRdy2.
;* 描述: OS 啟動時通過調(diào)用此程序切換到當前最高級任務(wù).
;*********************************************************************************************************
;*/
OSStartHighRdy2
        BL      OSTaskSwHook                            ; 調(diào)用鉤子函數(shù).

        LDR     R0,         =OSRunning                  ; 告訴 uC/OS-II自身已經(jīng)運行.
        MOV     R1,         #1
        STRB    R1,         [R0]

        LDR     R1,         =OSTCBHighRdy
        LDR     R1,         [R1]
        B       OSCtxSw_10

;/*
;*********************************************************************************************************
        END
;*********************************************************************************************************
;*/