data segment
ioport equ 0e800h-280h
io8255a equ ioport+288h
io8255b equ ioport+289h
io8255c equ ioport+28ah
io8255ctrl equ ioport+28bh
io8253a equ ioport+280h
io8253b equ ioport+281h
io8253ctrl equ ioport+283h
message1 db 0dh,0ah,'Please input the time to delay $'
message2 db 0dh,0ah,'South-North direction :$'
message3 db 0dh,0ah,'East-West direction :$'
message4 db 0dh,0ah,'Please turn off the console switch !!'
	  db 0dh,0ah,'After you turn off it,the system will work ... $'

led db 3fh,06h,5bh,4fh,66h,6dh,7dh,07h,7fh,6fh
time1 db 30
time2 db 30
count db ?
light db ?
data ends
				;-------------------------------------------------------
				;              本實(shí)驗(yàn)的一些簡化假設(shè)
				;   緊急控制可以打斷正常行車、夜間行車、路燈全滅3種狀態(tài)，
				;但是在調(diào)節(jié)時(shí)間狀態(tài)下不能有其他的打斷；在緊急控制、
				;夜間行車和路燈全滅時(shí)才能設(shè)置兩方向的顯示時(shí)間；
				;-------------------------------------------------------

;-----------------------------------------------------------
;C口用于輸出交通燈和數(shù)碼管的選通腳S1、S0
;PC7～PC5對應(yīng)南北路口紅黃綠燈，PC2～PC0對應(yīng)東西路口的紅黃綠燈
;PC4接S1
;PC3接S0
;A口用于輸出LED數(shù)碼管顯示
;B口用于輸入
;PB0用于判斷是否有緊急控制信號
;PB1用于判斷是否有夜間行車的信號
;PB2用于判斷是否有設(shè)置兩個(gè)方向的亮?xí)r時(shí)間
;PB3用于輸入8253產(chǎn)生的一秒的時(shí)鐘信號
;PB4用于控制交通燈全滅
;-----------------------------------------------------------

code   segment 
	assume cs:code
start :mov ax, data
	mov ds, ax 
	call init8253
	mov dx,io8255ctrl
       mov al,82h          ;工作方式0為A,C口輸出，B口輸入
	out dx,al           ;置方式控制字
;------------------------------------------------------
;十字路口交通燈的控制主程序段
;------------------------------------------------------
repeat: 
	mov al,00100100b    ;初始設(shè)南北路口綠燈亮，東西路口紅燈亮
	mov dx,io8255c     
	out dx,al
	mov light,al        ;保存當(dāng)前燈的狀態(tài)
	mov cl,time1
	call delay          ;延時(shí)30秒
	mov al,01000100b    ;置南北路口黃燈亮，東西路口紅燈亮
	out dx,al
	mov light,al        ;保存當(dāng)前燈的狀態(tài)
	mov cl,5	      
	call delay          ;延時(shí)5秒
	mov al,10000001b    ;置南北路紅燈亮,東西路綠燈亮
	out dx,al
	mov light,al        ;保存當(dāng)前燈的狀態(tài)
	mov cl,time2
	call delay          ;延時(shí)30秒
	mov al,10000010b    ;置南北路紅燈亮,東西路黃燈亮
	out dx,al
	mov light,al        ;保存當(dāng)前燈的狀態(tài)
	mov cl,5
	call delay          ;延時(shí)5秒

	mov ah,1            ;讀鍵盤緩沖
	int 16h
	jz repeat           ;無按下鍵則繼續(xù)
	mov ah,4ch          ;按下任意鍵退出
	int 21h

;-----------------------------------------
;延時(shí)子模塊，CX傳遞要延時(shí)的長度
;-----------------------------------------
delay  proc near
	push ax            ;保護(hù)現(xiàn)場
	push dx
	mov count,cl       ;CL的值為要顯示的時(shí)間長度付給count
lop:   cmp count,0
 	jz exit
 
	call init8253      ;初始化8253
wait1s:		
	mov dx,io8255b     ;讀PB口
	in al,dx
	and al,00000001b   ;判斷PB0是否為1
	cmp al,0
	jz next            ;為0跳到下一步
	call emergency     ;否則調(diào)用緊急控制子程序
next:       
	in al,dx           ;讀PB口
	and al,00000010b   ;判斷PB1是否為1
	cmp al,0
	jz next1           ;為0跳到下一步
	call nighting      ;否則調(diào)用夜間行車子程序
next1: 

	in al,dx           ;讀PB口
	and al,00010000b   ;判斷PB4是否為1
	cmp al,0
	jz next3           ;為1就跳到下一步
	call turnoff       ;否則調(diào)用路燈全滅子程序
next3:
	call display       ;顯示剩余時(shí)間
	in al,dx           ;讀PB口
	and al,00001000b   ;判斷PB3是否為0
	cmp al,0
	jnz wait1s         ;不為0，則表示還沒到一秒，等待
	dec count          ;綠燈延時(shí)長度減一
	jmp lop
exit:  pop dx             ;恢復(fù)現(xiàn)場
	pop ax
	ret
delay  endp

;---------------------------------------------
;顯示剩余時(shí)間子程序
;---------------------------------------------
display proc near
	
	push ax             ;保護(hù)現(xiàn)場
	push bx
	push cx
	push dx

	mov bx, offset led
  
	mov cl, 10
	mov al, count       ;要顯示的數(shù)為count的值
	mov ah, 0
	div cl              ;除10，求出十位及個(gè)位，商（即十位）在AL，余數(shù)（即個(gè)位）在AH
 
	xlat                ;轉(zhuǎn)換對應(yīng)的碼值	
	mov dx, io8255a    
	out dx, al	      ;把十位送到LED燈顯示
	mov dx, io8255ctrl
	mov al, 00000110b   ;PC3置0，即關(guān)閉數(shù)碼管的S0
	out dx,al
	mov dx, io8255ctrl 
	mov al, 00001001b   ;PC4置1，即選通數(shù)碼管的S1
	out dx, al

	mov cx,30000
lop1:   loop lop1          ;延時(shí)
	
	mov dx, io8255a
	mov al, ah          ;個(gè)位的值放到AL中
	xlat                ;轉(zhuǎn)換對應(yīng)的碼值
	out dx,al           ;把個(gè)位送到LED燈顯示
	mov dx, io8255ctrl 
	mov al, 00001000b   ;PC4置0，即關(guān)閉數(shù)碼管的S1
	out dx, al
	mov dx, io8255ctrl
	mov al, 00000111b   ;PC3置1，即選通數(shù)碼管的S0
	out dx,al
	mov cx,30000
lop2:  loop lop2           ;延時(shí)

	pop dx              ;恢復(fù)現(xiàn)場
	pop cx
	pop bx
	pop ax
	ret
display endp

;-----------------------------------------
;初始化8253子程序
;-----------------------------------------
init8253 proc near
	push dx              ;保護(hù)現(xiàn)場
	push ax
	mov dx, io8253ctrl
	mov al, 36h
	out dx, al
	mov ax, 1000
	mov dx, io8253a
	out dx, al
	xchg ah, al
	out dx, al
	mov dx, io8253ctrl
	mov al, 76h
	out dx, al
	mov ax, 2000
	mov dx, io8253b
	out dx, al
	xchg ah, al
	out dx, al
	pop ax            ;恢復(fù)現(xiàn)場
	pop dx
	ret
init8253 endp

;------------------------------------
;路燈全滅子程序
;------------------------------------
turnoff proc near
	push ax          ;保護(hù)現(xiàn)場
	push bx
	push cx
	push dx
	mov dx,io8255c
	mov al,0
	out dx,al        ;燈全滅
	mov bl,count
	mov count,0      ;數(shù)碼管顯示0
again:
	call display
	mov dx,io8255b
	in al,dx
	and al,00000001b
	cmp al,0
	jz noemergency
	call emergency
noemergency:
	mov dx,io8255b     ;讀PB口
	in al,dx
	and al,00000100b   ;判斷PB2是否為1
	cmp al,0
	jz noadjust           ;為0跳到下一步
	call adjust        ;否則調(diào)用調(diào)節(jié)兩方向了綠燈的時(shí)間
noadjust:
	mov dx,io8255b     ;讀PB口
	in al,dx
	and al,00010000b
	cmp al,0
	jnz again
	call init8253
	mov count,bl
	pop dx            ;恢復(fù)現(xiàn)場
	pop cx
	pop bx
	pop ax
	ret
turnoff endp


;------------------------------------
;緊急控制子程序OK
;------------------------------------
emergency proc near
	push ax          ;保護(hù)現(xiàn)場
	push bx
	push cx
	push dx
	mov al,count     ;保存count
	push ax

	mov count,30     ;使數(shù)碼管要顯示的時(shí)間為30
	mov dx,io8255c
	mov al,10000100b ;使兩路口紅燈亮
	out dx,al
	mov dx,io8255b
lop3:   
	call display
	in al,dx
	and al,00000100b   ;判斷PB2是否為1
	cmp al,0
	jz noadjust1        ;為0跳到下一步
	call adjust        ;否則調(diào)用調(diào)節(jié)兩方向了綠燈的時(shí)間
noadjust1:
	
	in al,dx
	and al,00000001b
	cmp al,0
	jnz lop3            ;PB0的信號仍為1，即交通在緊急狀態(tài)下,繼續(xù)等待
	
	mov al,light      ;否則恢復(fù)當(dāng)前交通秩序 
	mov dx,io8255c
	out dx,al
	call init8253

	pop ax
	mov count,al      ;恢復(fù)count
	pop dx            ;恢復(fù)現(xiàn)場
	pop cx
	pop bx
	pop ax
	ret
emergency endp

;-------------------------------------
;夜間行車子程序
;-------------------------------------
nighting proc near
	push ax            ;保護(hù)現(xiàn)場
	push bx
	push cx
	push dx
	mov al,count       ;保存count
	push ax
	mov count,0        ;數(shù)碼管顯示0
	mov al,01000010b   ;兩路口的黃燈亮
	mov bx,ax          ;把a(bǔ)x的值即黃燈的狀態(tài)保存到bx
lop4:	mov ax,bx
	mov dx,io8255c     ;兩黃燈的狀態(tài)由8255C口輸出
	out dx,al
	mov dx,io8255b
wait1:
	call display       ;顯示剩余時(shí)間

	in al,dx           ;讀8255B口
	and al,00000001b   ;判斷PB0是否為1
	cmp al,0
	jz skip            ;不為1跳到下一步
	call emergency     ;為1則執(zhí)行緊急控制
skip:
	in al,dx           ;讀PB口
	and al,00000100b   ;判斷PB2是否為1
	cmp al,0
	jz noadjust2
	call adjust
noadjust2:
	
	in al,dx
	and al,00001000b   ;判斷PB3是否為0,為0時(shí)到了一秒
	cmp al,0
	jnz wait1          ;為1，則表示還沒到一秒，循環(huán)等待，制造黃燈亮一秒
	mov ax,bx
	xor al,11111111b   
	and al,01000010b   ;兩路口的黃燈與前一秒的狀態(tài)相反，使達(dá)到閃爍的效果
	mov bx,ax          ;把a(bǔ)x的值即兩黃燈的狀態(tài)保存到bx

	in al,dx           ;讀PB口
	and al,00000010b
	cmp al,0           ;測試PB1是否為1
	jnz lop4           ;若為1則表示夜間行車信號仍存在，繼續(xù)等待

	mov al,light       ;否則恢復(fù)當(dāng)前交通秩序 
	mov dx,io8255c
	out dx,al
	call init8253
	pop ax
	mov count,al       ;恢復(fù)count
	pop dx             ;恢復(fù)現(xiàn)場
	pop cx
	pop bx
	pop ax

	ret
nighting endp

;-------------------------------
;調(diào)節(jié)兩方向的延時(shí)時(shí)間OK
;-------------------------------
adjust proc near
	push ax               ;保護(hù)現(xiàn)場
	push bx
	push cx
	push dx
	
	mov dx,offset message1
	mov ah,9
	int 21h
	mov dx,offset message2
	mov ah,9
	int 21h
	call read
	mov time1,dl          ;設(shè)置南北路口延時(shí)參數(shù)
	mov dx,offset message3
	mov ah,9
	int 21h
	call read
	mov time2,dl          ;設(shè)置東西路口延時(shí)參數(shù)
		
	mov dx,offset message4
	mov ah,9
	int 21h
	mov dx,io8255b
lop5:  in al,dx
	and al,00000100b
	cmp al,0	
	jnz lop5              ;調(diào)節(jié)控制開關(guān)沒有關(guān)上

	pop dx                ;恢復(fù)現(xiàn)場
	pop cx
	pop bx
	pop ax
	ret
adjust endp
;----------------------------------------
;從鍵盤讀數(shù)
;結(jié)果放在DX中
;----------------------------------------
read proc near
	push ax               ;保護(hù)現(xiàn)場
	push bx
	push cx
	
	mov dx,0
dec1:  mov ah,1
	int 21h
	sub al,30h
	jl dec2
	cmp al,9
	jg dec2
	cbw
	push ax
	mov ax,dx
	mov cx,10
	mul cx
	mov dx,ax
	pop ax
	add dx,ax
	jmp dec1
dec2:         
	pop cx          ;恢復(fù)現(xiàn)場
	pop bx
	pop ax
	ret
read endp
code ends
	end start