;/****************************************Copyright (c)**************************************************
;**                               廣州周立功單片機發(fā)展有限公司
;**                                     研    究    所
;**                                        產(chǎn)品一部 
;**
;**                                 http://www.zlgmcu.com
;**
;**--------------文件信息--------------------------------------------------------------------------------
;**文   件   名: vectors.s
;**創(chuàng)   建   人: 陳明計
;**最后修改日期: 2003年6月13日
;**描        述: lpc210x異常向量入口及異常向量與c語言代碼的接口(for μCOS-II)，包括初始化堆棧的代碼
;**              每個工程應當有獨立的這個文件的拷貝，并進行相應的修改   
;**--------------歷史版本信息----------------------------------------------------------------------------
;** 創(chuàng)建人: 陳明計
;** 版  本: v1.0
;** 日　期: 2003年6月5日
;** 描　述: 原始版本
;**
;**------------------------------------------------------------------------------------------------------
;** 修改人: 陳明計
;** 版  本: v1.1
;** 日　期: 2003年6月9日
;** 描　述: 使用宏使得中斷程序更加容易編寫
;**
;**------------------------------------------------------------------------------------------------------
;** 修改人: 陳明計
;** 版  本: v1.2
;** 日　期: 2003年6月11日
;** 描　述: 更改IRQ嵌套丟失CPSR的BUG
;**
;**------------------------------------------------------------------------------------------------------
;** 修改人: 陳明計
;** 版  本: v1.2
;** 日　期: 2003年6月13日
;** 描　述: 按照μCOS-II V2.52的要求修改（以前是基于μCOS-II V2.0）
;**
;**------------------------------------------------------------------------------------------------------
;** 修改人: 陳明計
;** 版  本: V1.3
;** 日　期: 2003年6月19日
;** 描　述: 不完全按照μCOS-II V2.52的要求以提高效率
;**
;**------------------------------------------------------------------------------------------------------
;** 修改人: 陳明計
;** 版  本: V1.4
;** 日　期: 2003年10月9日
;** 描　述: 修改中斷嵌套時的一個隱蔽錯誤，極端情況下它會造成系統(tǒng)崩潰
;**
;**--------------當前版本修訂------------------------------------------------------------------------------
;** 修改人: 
;** 日　期: 
;** 描　述: 
;**
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/

;定義堆棧的大小，根據(jù)需要改變
FIQ_STACK_LEGTH     EQU         0
IRQ_STACK_LEGTH     EQU         64
ABT_STACK_LEGTH     EQU         0
UND_STACK_LEGTH     EQU         0
VICVectAddr         EQU         0xFFFFF030
NoInt       EQU 0x80


;引入的外部標號在這聲明
        IMPORT  FIQ_Exception                   ;快速中斷異常處理程序
        IMPORT  Reset                           ;復位向量入口
        IMPORT  OSIntCtxSw                      ;中斷中任務切換函數(shù)
        IMPORT  OSIntExit                       ;中斷退出函數(shù)


;給外部使用的標號在這聲明，InitStack是必須的
        EXPORT  InitStack                       
        EXPORT  Vectors


    CODE32

    AREA    StartUp,CODE,READONLY

    ENTRY
;中斷向量表
Vectors
        LDR     PC, ResetAddr
        LDR     PC, UndefinedAddr
        LDR     PC, SWI_Addr
        LDR     PC, PrefetchAddr
        LDR     PC, DataAbortAddr
        DCD     0xb9205f80
        LDR     PC, [PC, #-0xff0]
        LDR     PC, FIQ_Addr

ResetAddr           DCD     Reset
UndefinedAddr       DCD     Undefined
SWI_Addr            DCD     0
PrefetchAddr        DCD     PrefetchAbort
DataAbortAddr       DCD     DataAbort
nouse               DCD     0
IRQ_Addr            DCD     IRQ_Handler
FIQ_Addr            DCD     FIQ_Handler


    MACRO
$IRQ_Label HANDLER $IRQ_Exception

        EXPORT  $IRQ_Label                      ; 輸出的標號
        IMPORT  $IRQ_Exception                  ; 引用的外部標號

$IRQ_Label
        SUB     LR, LR, #4                      ; 計算返回地址
        STMFD   SP!, {R0-R3, R12, LR}           ; 保存任務環(huán)境
        MRS     R3, SPSR                        ; 保存狀態(tài)
        STMFD   SP!, {R3}

        ;LDR     R2,  =OSIntNesting              ; OSIntNesting++
        ;LDRB    R1, [R2]
        ;ADD     R1, R1, #1
        ;STRB    R1, [R2]
        SWI     0x42                            ; 包括前面注釋的代碼
        
        BL      $IRQ_Exception                  ; 調(diào)用c語言的中斷處理程序

        MSR     CPSR_c, #0x92
        BL      OSIntExit

;        MRS     R0, CPSR
;        BIC     R0, R0, #NoInt
;        MSR     CPSR_c, R0

;        LDR     R0, =OSTCBHighRdy
;        LDR     R0, [R0]
;        LDR     R1, =OSTCBCur
;        LDR     R1, [R1]
;        CMP     R0, R1
        SWI     0x43                            ; 返回1需要切換
        CMP     R0, #0
        
        LDMFD   SP!, {R3}
        MSR     SPSR_cxsf, R3

        LDMEQFD SP!, {R0-R3, R12, PC}^          ; 不進行任務切換
        LDR     PC, =OSIntCtxSw                 ; 進行任務切換
    MEND

;未定義指令
Undefined
        b       Undefined

;取指令中止
PrefetchAbort
        b       PrefetchAbort

;取數(shù)據(jù)中止
DataAbort
        b       DataAbort

;中斷
IRQ_Handler	HANDLER IRQ_Exception

;快速中斷
FIQ_Handler
        STMFD   SP!, {R0-R3, LR}
        BL      FIQ_Exception
        LDMFD   SP!, {R0-R3, LR}
        SUBS    PC,  LR,  #4

;定時器0中斷
Timer0_Handler  HANDLER Timer0_Exception

;/*********************************************************************************************************
;** 函數(shù)名稱: InitStack
;** 功能描述: 初始化堆棧
;** 輸　入:   無
;** 輸　出 :  無
;** 全局變量: 無
;** 調(diào)用模塊: 無
;** 
;** 作　者: 陳明計
;** 日　期: 2003年6月5日
;**-------------------------------------------------------------------------------------------------------
;** 修　改: 
;** 日　期: 
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
InitStack    
        MOV     R0, LR
;設置中斷模式堆棧
        MSR     CPSR_c, #0xd2
        LDR     SP, StackIrq
;設置快速中斷模式堆棧
        MSR     CPSR_c, #0xd1
        LDR     SP, StackFiq
;設置中止模式堆棧
        MSR     CPSR_c, #0xd7
        LDR     SP, StackAbt
;設置未定義模式堆棧
        MSR     CPSR_c, #0xdb
        LDR     SP, StackUnd
;設置系統(tǒng)模式堆棧
        MSR     CPSR_c, #0xdf
        LDR     SP, StackIrq
        MOV     PC, R0

StackIrq           DCD     (IrqStackSpace + IRQ_STACK_LEGTH * 4 - 4)
StackFiq           DCD     (FiqStackSpace + FIQ_STACK_LEGTH * 4 - 4)
StackAbt           DCD     (AbtStackSpace + ABT_STACK_LEGTH * 4 - 4)
StackUnd           DCD     (UndtStackSpace + UND_STACK_LEGTH * 4 - 4)

;/* 分配堆棧空間 */
        AREA    MyStacks, DATA, NOINIT
IrqStackSpace      SPACE   IRQ_STACK_LEGTH * 4  ;中斷模式堆棧空間
FiqStackSpace      SPACE   FIQ_STACK_LEGTH * 4  ;快速中斷模式堆棧空間
AbtStackSpace      SPACE   ABT_STACK_LEGTH * 4  ;中止義模式堆棧空間
UndtStackSpace     SPACE   UND_STACK_LEGTH * 4  ;未定義模式堆棧




    END
;/*********************************************************************************************************
;**                            End Of File
;********************************************************************************************************/