在VB中直接用ODBC API訪問數據庫
中國航空信息中心 吳斌 計算機世界 19980608

開放數據庫互連(ODBC)已經成為Client/Server數據庫應用系統中訪問遠程數據庫的一個標準。作為強大的前端開發工具,Visual Basic為開發者提供了多種訪問ODBC數據源的途徑,如JET數據庫引擎、ODBC API函數、RDO接口等。比較而言,直接使用ODBC API函數的編程難度最大,但獲得的存取數據庫的性能也最佳。

ODBC API函數的聲明方法
與使用其它動態庫函數一樣,在VB中使用ODBC API函數之前,必須事先聲明將要使用
的函數、常量和數據結構。ODBC API函數駐留在ODBC運行動態庫ODBC.DLL(16位)或ODBC
32.DLL(32位)中,該動態庫位于Windows子目錄system中。通常做法是在VB項目中單獨使
用一個模塊文件,然后將ODBC API聲明語句加入其中,下面就是本文實例中使用的模塊文
件module1.bas的內容:

Declare Function SQLAllocEnv Lib "odbc32.dll" (phenv&) As Integer
Declare Function SQLAllocConnect Lib "odbc32.dll" (ByVal henv&, phdbc&) As Integer
Declare Function SQLAllocStmt Lib "odbc32.dll" (ByVal hdbc&, phstmt&) AsInteger
Declare Function SQLConnect Lib "odbc32.dll" (ByVal hdbc&, ByVal szDSN$,ByVal cbDSN%, ByVal szUID$, ByVal cbUID%, ByVal szAuthStr$, ByVal cbAuthStr%) As Integer
Declare Function SQLColAttributesString Lib "odbc32.dll" Alias "SQLColAttributes" (ByVal hstmt&, ByVal icol%, ByVal fDescType%, ByVal rgbDesc As String, ByVal cbDescMax%, pcbDesc%, pfDesc&) As Integer
Declare Function SQLDisconnect Lib "odbc32.dll" (ByVal hdbc&) As Integer
Declare Function SQLExecDirect Lib "odbc32.dll" (ByVal hstmt&, ByVal szSqlStr$, ByVal cbSqlStr&) As Integer
Declare Function SQLFetch Lib "odbc32.dll" (ByVal hstmt&) As Integer
Declare Function SQLFreeConnect Lib "odbc32.dll" (ByVal hdbc&) As Integer
Declare Function SQLFreeEnv Lib "odbc32.dll" (ByVal henv&) As Integer
Declare Function SQLFreeStmt Lib "odbc32.dll" (ByVal hstmt&, ByVal fOption%) As Integer
Declare Function SQLGetData Lib "odbc32.dll" (ByVal hstmt&, ByVal icol%,ByVal fCType%, ByVal rgbValue As String, ByVal cbValueMax&, pcbValue&) As Integer
Declare Function SQLNumResultCols Lib "odbc32.dll" (ByVal hstmt&, pccol%) As Integer
Global Const SQL_C_CHAR As Long = 1
Global Const SQL_COLUMN_LABEL As Long = 18
Global Const SQL_DROP As Long = 1
Global Const SQL_ERROR As Long = -1
Global Const SQL_NO_DATA_FOUND As Long = 100
Global Const SQL_SUCCESS As Long = 0

需要說明的是,在函數聲明時,應該根據程序的運行環境選擇相應的動態庫。在VB子
目錄samples\remauto\db_odbc中有兩個文本文件ODBC16.TXT和ODBC32.TXT,分別存有所
有16位和32位ODBC API函數、常量和數據結構的聲明語句,編程時可以從中拷貝所需的聲
明語句。

使用ODBC API的編程方法
在VB中調用ODBC API函數訪問ODBC數據庫,代碼編寫一般按下列過程進行:
1.初始化ODBC
在這個過程中,應用程序將通過調用SQLAlloEnv函數初始化ODBC接口,獲取ODBC環境句柄。ODBC環境句柄是其它所有ODBC資源句柄的父句柄,因此無論程序將建立多少個ODBC連接,這個過程只需執行一次即可。例如:
Dim rc As Integer 'ODBC函數的返回碼
Dim henv As Long 'ODBC環境句柄
rc = SQLAllocEnv(henv) '獲取ODBC環境句柄
2.與ODBC數據源建立連接
這個過程由下列兩個步驟組成:
*S調用SQLAllocConnect函數獲取連接句柄。例如:
Dim hdbc As Long '連接句柄
rc = SQLAllocConnect(henv, hdbc) '獲取連接句柄
*S建立連接。這個步驟可以通過多種方法實現,最簡單直觀的方法是調用SQLConnect函數。例如:
Dim DSN As String, UID As String, PWD As String
DSN = "DataSourceName" 'ODBC數據源名稱
UID = "UserID"
'用戶帳號
PWD = "Password"
'用戶口令
rc = SQLConnect(hdbc, DSN, Len(DSN), UID, Len(UID), PWD, Len(PWD)) '建立
連接
3.存取數據
用戶對ODBC數據源的存取操作,都是通過SQL語句實現的。在這個過程中,應用程序將通過連接向ODBC數據庫提交SQL語句,完成用戶請求的操作,具體步驟如下:
*S調用SQLAllocStmt函數獲取語句句柄,例如:
Dim hstmt As Long
rc = SQLAllocStmt(hdbc, hstmt)
*S執行SQL語句。執行SQL語句的方法比較多,最簡單明了的方法是調用SQLAllocStmt函數,例如:
Dim SQLstmt As String
SQLstmt = "SELECT * FROM authors"
rc = SQLExecDirect(hstmt, SQLstmt, Len(SQLstmt))
4.檢索結果集
如果SQL語句順利提交并正確執行,那么就會產生一個結果集。檢索結果集的方法很多,最簡單、最直接的方法是調用SQLFetch和SQLGetData函數。SQLFetch函數的功能是將結果集的當前記錄指針移至下一個記錄,SQLGetData函數的功能是提取結果集中當前記錄的某個字段值。通常可以采用一個循環提取結果集中所有記錄的所有字段值,該循環重復執行SQLFetch和SQLGetData函數,直至SQLFetch函數返回SQL_NO_DATA_FOUND,這表示已經到達結果集的末尾。
Dim ColVal As String * 225
ColVal = String(255, 0)
Do Until SQLFetch(hstmt) = SQL_NO_DATA_FOUND
rc = SQLGetData(hstmt, i, SQL_C_CHAR, ColVal, Len(ColVal), SQL_NULL_DATA
Loop
5.結束應用程序
在應用程序完成數據庫操作、退出運行之前,必須釋放程序中使用的系統資源。這些系統資源包括:語句句柄、連接句柄和ODBC環境句柄。完成這個過程的步驟如下:
*S調用SQLFreeStmt函數釋放語句句柄及其相關的系統資源。例如:
rc = SQLFreeStmt(hstmt, SQL_DROP)
*S調用SQLDisconnect函數關閉連接,例如:
rc = SQLDisconnect(hdbc)
*S調用SQLFreeConnect函數釋放連接句柄及其相關的系統資源,例如:
rc = SQLFreeConnect(hdbc)
*S調用SQLFreeEnv函數釋放環境句柄及其相關的系統資源,停止ODBC操作,例如:
rc = SQLFreeEnv(henv)
此外,在編制程序時還有一個需要重點考慮的問題,這就是錯誤處理。所有ODBC API函數,若在執行期間發生錯誤,都將返回一個標準錯誤代碼SQL_ERROR。一般來講,在每次調用ODBC API函數之后,都應該檢查該函數返回值,確定該函數是否成功地執行,再決定是否繼續后續過程。而詳細的錯誤信息,可以調用SQLError函數獲得。SQLError函數將返回下列信息:
*S標準的ODBC錯誤狀態碼;
*SODBC數據源提供的內部錯誤編碼;
*S錯誤信息串。
簡單應用實例
本實例將編制一個客戶機端VB應用程序,通過Windows NT局域網查詢服務器端MS SQL Server 6.5樣板數據庫PUBS中的AUTHORS數據表,在一個Grid控件中顯示查詢結果。首先,使用Windows控制面板中的ODBC驅動管理器新建一個ODBC數據源,定義數據源名稱為ODBC_API_DEMO,定義登錄數據庫為PUBS,其它信息應根據用戶的環境正確設置。然后啟動VB,新建一個項目Project1,在缺省窗體Form1中加入一個Grid控件Grid1、兩個CommandButton控件cmdQuery和cmdClose,在Project1中插入一個模塊Module1,將前面列舉的聲明語句加入其中,程序代碼如下:
Private Sub Form_Load()
Dim rc As Integer
rc = SQLAllocEnv(henv)
If rc <> 0 Then
MsgBox "無法初始化ODBC"
End
End If
rc = SQLAllocConnect(henv, hdbc)
If rc <> 0 Then
MsgBox "無法獲得連接句柄"
rc = SQLFreeEnv(henv)
End
End If
Dim DSN As String, UID As String, PWD As String
DSN = "ODBC_API_DEMO"
UID = "guest"
PWD = ""
rc = SQLConnect(hdbc, DSN, Len(DSN), UID, Len(UID), PWD, Len(UID))
If rc = SQL_ERROR Then
MsgBox "無法建立與ODBC數據源的連接"
End
End If
End Sub
Private Sub cmdQuery_Click()
Dim hstmt As Long
Dim SQLstmt As String
Dim RSCols As Integer, RSRows As Long
Dim rc As Integer, i As Integer, j As Integer
Dim ColVal As String * 1024
Dim ColValLen As Long, ColLabLen As Integer, larg As Long
rc = SQLAllocStmt(hdbc, hstmt)
If rc <> SQL_SUCCESS Then
MsgBox "無法獲得SQL語句句柄"
Exit Sub
End If
SQLstmt = "SELECT * FROM authors"
rc = SQLExecDirect(hstmt, SQLstmt, Len(SQLstmt))
If rc <> SQL_SUCCESS Then
MsgBox "SQL語句執行失敗"
Exit Sub
End If
rc = SQLNumResultCols(hstmt, RSCols)
If RSCols > 1 Then
Grid1.Cols = RSCols
Grid1.Rows = 10
Grid1.Row = 0
Else
Exit Sub
End If
For i = 1 To RSCols
rc = SQLColAttributesString(hstmt, i, SQL_COLUMN_LABEL, ColVal, 255, Col
LabLen, larg)
Grid1.Col = i - 1
Grid1.Text = Left(ColVal, ColLabLen)
Next i
Do Until SQLFetch(hstmt) = SQL_NO_DATA_FOUND
ColVal = String$(1024, 0)
If Grid1.Row + 1 >= Grid1.Rows Then
Grid1.Rows = Grid1.Rows + 1
End If
Grid1.Row = Grid1.Row + 1
For i = 1 To RSCols
rc = SQLGetData(hstmt, i, SQL_C_CHAR, ColVal, Len(ColVal), ColValLen)
Grid1.Col = i - 1
Grid1.Text = Left$(ColVal, ColValLen)
Next i
Loop
rc = SQLFreeStmt(hstmt, SQL_DROP)
End Sub
Private Sub cmdClose_Click()
Dim rc As Integer
If hdbc <> 0 Then
rc = SQLDisconnect(hdbc)
End If
rc = SQLFreeConnect(hdbc)
If henv <> 0 Then
rc = SQLFreeEnv(henv)
End If
End
End Sub