Attribute VB_Name = "modMethod"
'點群分析
Option Explicit
'數據的標準差標準化變換
'X(1 To n,1 To m)：原始數據，執行后保存變換后的數據
Public Sub Data_S1(X() As Double)
    Dim M As Integer, N As Integer, I As Integer, J As Integer
    Dim Ave As Double, S As Double
    N = UBound(X, 1): M = UBound(X, 2)          'n:樣品數；m:變量數
    For J = 1 To M
        Ave = 0
        For I = 1 To N
            Ave = Ave + X(I, J)
        Next I
        Ave = Ave / N                           'Ave是平均值
        S = 0
        For I = 1 To N
            S = S + (X(I, J) - Ave) ^ 2
        Next I
        S = Sqr(S / N)                          'S是標準差
        For I = 1 To N
            X(I, J) = (X(I, J) - Ave) / S       '標準差標準化變換
        Next I
    Next J
End Sub

'數據的極差標準化變換
'X(1 To n,1 To m)：原始數據，執行后保存變換后的數據
Public Sub Data_S2(X() As Double)
    Dim M As Integer, N As Integer, I As Integer, J As Integer
    Dim xMax As Double, xMin As Double, Ave As Double, D As Double
    N = UBound(X, 1): M = UBound(X, 2)          'n:樣品數；m:變量數
    For J = 1 To M
        Ave = 0
        For I = 1 To N
            Ave = Ave + X(I, J)
        Next I
        Ave = Ave / N                           'Ave是平均值
        xMax = -100000000: xMin = 100000000
        For I = 1 To N
            If X(I, J) > xMax Then xMax = X(I, J)
            If X(I, J) < xMin Then xMin = X(I, J)
        Next I
        D = xMax - xMin                         'D是極差
        For I = 1 To N
            X(I, J) = (X(I, J) - Ave) / D       '極差標準化變換
        Next I
    Next J
End Sub

'數據的極差正規化變換
'X(1 To n,1 To m)：原始數據，執行后保存變換后的數據
Public Sub Data_S3(X() As Double)
    Dim M As Integer, N As Integer, I As Integer, J As Integer
    Dim xMax As Double, xMin As Double, D As Double
    N = UBound(X, 1): M = UBound(X, 2)          'n:樣品數；m:變量數
    For J = 1 To M
        xMax = -100000000: xMin = 100000000
        For I = 1 To N
            If X(I, J) > xMax Then xMax = X(I, J)
            If X(I, J) < xMin Then xMin = X(I, J)
        Next I
        D = xMax - xMin                         'D是極差
        For I = 1 To N
            X(I, J) = (X(I, J) - xMin) / D      '極差標準化變換
        Next I
    Next J
End Sub