;  繪點子程序S_DOT
;  占用內部寄存器：O_XL,O_XH,O_YL,A,B
;  內部調用子程序：PR1,PR2,PR3
;  程序調用入口： S_DOT
;  程序輸入變量： O_XL,O_XH,O_YL
        S_DOT:  MOV     A,O_YL          ; 取行坐標地址
                MOV     B,#PARA1        ; 設置顯示域寬度
                MUL     AB              ; 計算顯示RAM地址
                MOV     O_YL,B          ; 高8位暫存O_YL
                MOV     DAT1,A          ; 低8位暫存DAT1
                MOV     A,O_XL          ; 取列坐標低地址
                PUSH    ACC             ; 入棧
                MOV     B,#03H          ; 設置循環量=3(除以8)
        S_DOT1: MOV     A,O_XH          ; 取列坐標地址高3位
                RRC     A               ; 右移一位至C
                MOV     O_XH,A          ; 暫存
                MOV     A,O_XL          ; 取列坐標地址低8位
                RRC     A               ; 右移入一位
                MOV     O_XL,A          ; 存除以8的商(一字節)
                DJNZ    B,S_DOT1        ; 循環
                ADD     A,DAT1          ; 計算顯示RAM地址
                MOV     DAT1,A          ; 存低8位
                CLR     A
                ADDC    A,O_YL
                MOV     O_YL,A          ; 存高8位
                MOV     COM,#0AH        ; 設置光標指針
                LCALL   PR1
                LCALL   PR2             ; 低8位
                MOV     COM,#0BH
                LCALL   PR1
                MOV     DAT1,O_YL       ; 高8位
                LCALL   PR2
                MOV     COM,#0FH        ; 設置"位置位"代碼
                LCALL   PR1
                POP     ACC             ; 出棧
                ANL     A,#07H          ; 取點位置值
                MOV     DAT1,A          ; 設置置"1"位
                LCALL   PR2
                RET