<!--#include file="MarcosCB.asp"-->
<%
	dim url,page,theAct,boardId,boardName,topicId,replyId
	page=getPost("page")
	theAct=getPost("theAct")
	boardId=getPost("boardId")
	topicId=getPost("topicId")
	replyId=getPost("replyId")
	boardName=getPost("boardName")
	
	if not (isNumeric(topicId) and isNumeric(boardId)) then
		echo "錯誤的參數!"
		response.end
	end if
	
	if not isNumeric(replyId) and replyId<>"" then
		echo "錯誤的數據參數！"
		closeConn()
		response.End()
	end if
	
	getConn()
	canSet(boardId)
	url="topicShow.asp?boardId="&boardId&"&boardName="&boardName&"&topicId="&topicId&"&page="&page
	
	select case theAct
		case "setTop"
			conn.execute("update Marcos_Topic set isTop=true where topicId="&topicId)
		case "unTop"
			conn.execute("update Marcos_Topic set isTop=false where topicId="&topicId)
		case "setLock"
			conn.execute("update Marcos_Topic set isLocked=true where topicId="&topicId)
		case "unLock"
			conn.execute("update Marcos_Topic set isLocked=false where topicId="&topicId)
		case "setBest"
			conn.execute("update Marcos_Topic set isBest=true where topicId="&topicId)
		case "unBest"
			conn.execute("update Marcos_Topic set isBest=false where topicId="&topicId)
		case "recycled"
			if isNumeric(replyId) then
				conn.execute("update Marcos_Reply set isRecycled=true,recycleTime='"&now()&"' where replyId="&replyId)
				conn.execute("update Marcos_Topic set replyCount=replyCount-1 where topicId="&topicId)
				rem 判斷主題是否已被回收,未回收則對版塊參數進行相應的修改
				sql="select isRecycled from Marcos_Topic where topicId="&topicId
				set rs_sys=conn.execute(sql)
				if rs_sys(0)=false then
					conn.execute("update Marcos_Board set replyCount=replyCount-1 where boardId="&boardId)
				end if
			 else
				sql="select boardId,replyCount from Marcos_Topic where topicId="&topicId
				set rs_sys=conn.execute(sql)
				conn.execute("update Marcos_Board set topicCount=topicCount-1,replyCount=replyCount-"&rs_sys(1)&" where boardId="&rs_sys(0))
				conn.execute("update Marcos_Topic set isRecycled=true,recycleTime='"&now()&"' where topicId="&topicId)
			end if
			delPageIndex()
			updatePostInfo(boardId)
		case "recover"
			if isNumeric(replyId) then
				conn.execute("update Marcos_Reply set isRecycled=false where replyId="&replyId)
				conn.execute("update Marcos_Topic set replyCount=replyCount+1 where topicId="&topicId)
				rem 判斷主題是否已被回收,未回收則對版塊參數進行相應的修改
				sql="select isRecycled from Marcos_Topic where topicId="&topicId
				set rs_sys=conn.execute(sql)
				if rs_sys(0)=false then
					conn.execute("update Marcos_Board set replyCount=replyCount+1 where boardId="&boardId)
				end if
			 else
				sql="select boardId,replyCount from Marcos_Topic where topicId="&topicId
				set rs_sys=conn.execute(sql)
				conn.execute("update Marcos_Board set topicCount=topicCount+1,replyCount=replyCount+"&rs_sys(1)&" where boardId="&rs_sys(0))
				conn.execute("update Marcos_Topic set isRecycled=false where topicId="&topicId)
			end if
			delPageIndex()
			updatePostInfo(boardId)
	end select

	locate url
	
	closeConn()
%>