?? 9t.bak
字號:
; *************************************
; * *
; * 遙控編碼控制器 *
; * *
; * 采用89C2051 *
; *************************************
;
; P1.0口按紐為前進，P1.1口按紐為后退，P1.2口按紐為左轉彎，P1.3口按紐為右轉彎，
; P1.4口按紐為自動駕駛，P3.5為編碼輸出
;
;*************************************
;* *
;* 主程序和中斷程序入口 *
;* *
;*************************************
ORG 0000H ;程序執行開始地址
LJMP START ;跳至START執行
ORG 0003H ;外中斷0中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 000BH ;定時器T0中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 0013H ;外中斷1中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 001BH ;定時器T1中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 0023H ;串行口中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 002BH ;定時器T2中斷入口地址
RETI ;中斷返回（不開中斷）
;
;*************************************
;* *
;* 初始化程序中的各變量 *
;* *
;*************************************
CLEARMEMIO: CLR A ;清A
DEC A ;A為#0FFH
MOV P1,A ; P1口置1
MOV P3,A ; P3口置1
MOV IE,#00H ;關所有中斷
RET ;子程序返回
;
;
;
;*************************************
;* *
;* 主 程 序 *
;* *
;*************************************
START: LCALL CLEARMEMIO ;調用初始化
; 主體程序
MAIN: LCALL KEYWORK ;調用查鍵子程序
LJMP MAIN ;轉MAIN循環
NOP ;PC值出錯處理
NOP
NOP
LJMP START ;轉START重新啟動
;
;**************************
;* *
;* 鍵盤工作子程序 *
;**************************
KEYWORK: MOV P1,#0FFH ;置輸入狀態
JNB P1.0,KEY0 ; 讀P1.0口，為0轉KEY0
JNB P1.1,KEY1 ; 讀P1.1口，為0轉KEY1
JNB P1.4,KEY4 ; 讀P1.4口，為0轉KEY4
KEYOUT: RET ;沒鍵按下，退出
;
KEY0: LCALL DL10MS ;延時10毫秒消抖
JB P1.0,KEYOUT ;干擾，退出
LJMP KEYFUN00 ;轉KEYFUN00
KEY1: LCALL DL10MS ;
JB P1.1,KEYOUT ; 干擾，退出
LJMP KEYFUN01 ; 轉KEYFUN01
KEY2: LCALL DL10MS ; 延時10毫秒消抖
JB P1.2,KEYOUT ; 干擾，退出
LJMP KEYFUN02 ; 轉KEYFUN02
KEY3: LCALL DL10MS ; 延時10毫秒消抖
JB P1.3,KEYOUT ; 干擾，退出
LJMP KEYFUN03 ; 轉KEYFUN03
KEY4: LCALL DL10MS ; 延時10毫秒消抖
JB P1.4,KEYOUT ; 干擾，退出
LJMP KEYFUN04 ; 轉KEYFUN04
KEYWORK1: JNB P1.2,KEY2 ;P1.2口為0轉KEY2
JNB P1.3,KEY3 ; P1.3口為0轉KEY3
LCALL KEYFUN05 ;調轉彎復位子程序
RET ;返回
;
KEYFUN00: MOV A,#02H ;發2個脈沖賦值
LCALL REMOTE ;發射2個脈沖（前進）
WAIT0: LCALL KEYWORK1 ;調一次轉彎查鍵子程序
JNB P1.0,WAIT0 ;等待按鍵釋放
LCALL KEYFUN06 ;釋放時發8個脈沖（停止）
RET ;返回
;
KEYFUN01: MOV A,#03H ;發3個脈沖賦值
LCALL REMOTE ;發射3個脈沖（前進）
WAIT1: LCALL KEYWORK1 ;調一次轉彎查鍵子程序
JNB P1.1,WAIT1 ;等待按鍵釋放
LCALL KEYFUN06 ;釋放時發8個脈沖（停止）
RET ;
;
KEYFUN02: MOV A,#04H ;發4個脈沖賦值
LCALL REMOTE ;發射4個脈沖（左轉）
JNB P1.2,KEYOUT1 ;鍵按下不放，轉KEYOUT1返回
LCALL DL10MS ;左轉鍵放開，延時10毫秒
JNB P1.2,KEYOUT1 ;為0（干擾），轉KEYOUT1返回
LCALL KEYFUN05 ;左轉鍵放開發7個脈沖（轉彎復位）
RET ;返回
;
KEYFUN03: MOV A,#05H ;發5個脈沖賦值
LCALL REMOTE ;發射5個脈沖（右轉）
JNB P1.3,KEYOUT1 ;鍵按下不放，轉KEYOUT1返回
LCALL DL10MS ;右轉鍵放開，延時10毫秒
JNB P1.3,KEYOUT1 ;為0（干擾），轉KEYOUT1返回
LCALL KEYFUN05 ;右轉鍵放開發7個脈沖（轉彎復位）
RET ;返回
KEYOUT1: LJMP KEYOUT ;跳至KEYOUT返回
;
KEYFUN04: JNB P1.4,KEYFUN04 ;等待按鍵釋放
LCALL DL10MS ;延時消抖動
JNB P1.4,KEYFUN04 ;P1.4為0，系干擾，轉KEYFUN04再等待
MOV A,#06H ;按鍵釋放，發6個脈沖（進入自動駕駛）
LCALL REMOTE ;發射一次
RET ;返回
;
KEYFUN05: MOV A,#07H ;發7個脈沖程序（轉彎復位）
LCALL REMOTE ;發射一次
RET ;返回
KEYFUN06: MOV A,#08H ;發8個脈沖程序（停車）
LCALL REMOTE ;發射一次
RET ;返回
;
;
;*************************************
;* *
;* 編碼發送程序 *
;* *
;*************************************
;按A中數值發射脈沖
REMOTE: MOV R1,A ;發射脈數入A
LJMP OUT3 ;第一個脈沖處理
OUT: MOV R0,#55H ;1MS脈寬定時值
OUT1: CLR P3.5 ;發低電平脈寬
NOP ;延時循環（周期約為21微秒）
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
DJNZ R0,OUT1 ;定時時間未到，轉OUT1循環
MOV R0,#55H ;1MS脈寬定時值
OUT2: SETB P3.5 ;發高電平脈寬
NOP ;延時循環（周期約為21微秒）
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
DJNZ R0,OUT2 ;定時時間未到，轉OUT2循環
DJNZ R1,OUT ;脈沖數未發完轉OUT再循環
LCALL DL10MS ;脈沖發完延時10毫秒
RET ;返回
OUT3: MOV R0,#0FFH ;3MS脈寬定時值
LJMP OUT1 ;轉OUT1紅外線發射
;
;
;
;*************************************
;* *
;* 延時 255 X 2 ＝ 512 us *
;* *
;*************************************
DELAY: MOV R2,#0FFH
DELAY1: DJNZ R2,DELAY1
RET
;
;*************************************
;* *
;* 延時10ms程序 *
;* （消按鍵抖動用） *
;*************************************
DL10MS: MOV R3,#14H
DL10MS1: LCALL DELAY
DJNZ R3,DL10MS1
RET
DL500MS: MOV R4,#32H
DL500MS1: LCALL DL10MS
DJNZ R4,DL500MS1
RET
;
;
END ;程序結束
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -