?? os_cpu_a.src
字號(hào):
#line 1 "c:\software\ucos-ii\c167\tasking\source\os_cpu_a.asm"
;********************************************************************************************************
; uC/OS-II
; The Real-Time Kernel
;
; (c) Copyright 1992-1999, Jean J. Labrosse, Weston, FL
; All Rights Reserved
;
; Infineon C167
; Extended Architecture Specific Code
; LARGE MEMORY MODEL
;
;
; Module Title : uC/OS-II C167
; System Platform : Target System Infineon C167
; Compile with : TASKING C166/ST10 V2.0 R1 Cross-Assembler
; Author : Michael Awosika, Karl Wannenmacher
; Date : 5 Dez. 2000
; Revision : 1.00
; File Name : OS_CPU_A.ASM
; Description : This uC/OS-II port is intended for Infineon Technologies
; C167 Extended Architecture Micro Controller Targets
;********************************************************************************************************
$DEBUG
$NOLOCALS
$EXTEND
$NOMOD166
$STDNAMES(Reg167.def)
$SEGMENTED
$CASE
$MODEL(LARGE)
$CHECKCPU16
NAME OS_CPU_C16x
ASSUME DPP3:SYSTEM
REGBAS REGBANK R0
COMAREA COMREG R1 - R15
; 1 [State] = 2 * 1/ f CPU [s] for f CPU = variable
; = 100 [ns] for f CPU = 20 MHz
;********************************************************************************************************
; External Code
;********************************************************************************************************
EXTERN _OSIntExit:FAR
EXTERN _OSTimeTick:FAR
EXTERN _OSTaskSwHook:FAR
EXTERN _OSIntEnter:FAR
;********************************************************************************************************
; External Data
;********************************************************************************************************
EXTERN _OSIntNesting:BYTE
EXTERN _OSPrioHighRdy:BYTE
EXTERN _OSPrioCur:BYTE
EXTERN _OSRunning:BYTE
EXTERN _OSTCBCur:WORD
EXTERN _OSTCBHighRdy:WORD
UCOS_C16X SECTION CODE WORD PUBLIC 'CPROGRAM'
PUBLIC _OSStartHighRdy
PUBLIC _OSCtxSw
PUBLIC _OSIntCtxSw
PUBLIC _OSTickISR
UCOS_C16X ENDS
;********************************************************************************************************
; START MULTITASKING
; void OSStartHighRdy (void)
;
; Note : OSStartHighRdy() MUST:
; a) Call OSTaskSwHook() then,
; b) Set OSRunning to TRUE.
;
; The user stack frame of the task to start looks as follows:
;
; TASK STACK AREA (High Memory)
; +12 TASK DATA PARAMETER PAGE pointer
; +10 TASK DATA PARAMETER OFFSET pointer
; +0E SEGMENT of task code address
; +0C OFFSET of task code address
; +0A USER STACK OFFSET POINTER (R0) of task
; +08 USER STACK PAGE POINTER (DPP1) of task
; +06 PSW flags of task
; +04 OFFSET of task code address
; +02 SEGMENT of task code address
; OSTCBHighRdy->OSTCBStkPtr --> 0
; -02 R[1 ..15] General Purpose registers of task
; -20 CP Context pointer of task
; -22 DPP3 Data page pointer 3 of task
; -24 DPP2 Data page pointer 2 of task
; -26 DPP0 Data page pointer 0 of task
; -28 MDC Multiply/Divide Control of task
; -2A MDH Multiply/Divide High register of task
; -2C MDL Multiply/Divide Low register of task (Low Memory)
;********************************************************************************************************
UCOS_C16X SECTION CODE
_OSStartHighRdy PROC FAR
MOV R9,#SOF _ADDR00 ; Call user defined task switch hook
MOV [-R0],R9
MOV R9,#SEG _ADDR00
MOV [-R0],R9
JMPS SEG(_OSTaskSwHook),SOF( _OSTaskSwHook)
_ADDR00:
MOVB RL1,#01h ; Indicate that multitasking has started
EXTP #PAG _OSRunning,#01h
MOVB POF _OSRunning,RL1
BCLR IEN ; Disable interrupts
EXTP #PAG _OSTCBHighRdy,#02h ; OSTCBCur = OSTCBHighRdy;
MOV R12,POF _OSTCBHighRdy
MOV R13,POF (_OSTCBHighRdy+2)
EXTP #PAG _OSTCBCur,#02h
MOV POF (_OSTCBCur),R12
MOV POF (_OSTCBCur+2),R13
EXTP R13,#02h ; pStack = OSTCBCur->OSTCBStkPtr;
MOV R14,[R12+] ; Load Offset pointer
MOV R15,[R12] ; Load Page pointer
; ; Load Task's Context from TCB
EXTP R15,#02h ; Start Of Task USR Stack Offset
MOV R0,[R14+#0AH] ; Task R0
MOV R1,[R14+#08H] ; Task DPP1
EXTP R15,#02h
MOV R2,[R14+#04H] ; Task IP
MOV R3,[R14+#02H] ; Task CSP
MOV DPP1,R1 ; Start Of Task USER Stack Page
PUSH R3 ; Load "saved" CSP on System Stack
PUSH R2 ; Load "saved" IP on System Stack
MOV R1,[R0+] ; Restore MDL
MOV MDL,R1 ;
MOV R1,[R0+] ; Restore MDH
MOV MDH,R1 ;
MOV R1,[R0+] ; Restore MDC
MOV MDC,R1 ;
MOV R1,[R0+] ; Restore DPP0
MOV DPP0,R1 ;
MOV R1,[R0+] ; Restore DPP2
MOV DPP2,R1 ;
MOV R1,[R0+] ; Restore DPP3
MOV DPP3,R1 ;
MOV R1,[R0+] ; Restore CP
MOV CP,R1 ;
NOP
MOV R15,[R0+] ; Restore R15
MOV R14,[R0+] ; Restore R14
MOV R13,[R0+] ; Restore R13
MOV R12,[R0+] ; Restore R12
MOV R11,[R0+] ; Restore R11
MOV R10,[R0+] ; Restore R10
MOV R9,[R0+] ; Restore R9
MOV R8,[R0+] ; Restore R8
MOV R7,[R0+] ; Restore R7
MOV R6,[R0+] ; Restore R6
MOV R5,[R0+] ; Restore R5
MOV R4,[R0+] ; Restore R4
MOV R3,[R0+] ; Restore R3
MOV R2,[R0+] ; Restore R2
MOV R1,[R0+] ; Restore R1; Restore context.
BSET IEN ; Enable interrupts
RETS ; Execute Task
_OSStartHighRdy ENDP
UCOS_C16X ENDS
;********************************************************************************************************
; PERFORM A CONTEXT SWITCH (From task level)
; void OSCtxSw(void)
;
; Note(s): 1) Upon entry,
; OSTCBCur points to the OS_TCB of the task to suspend
; OSTCBHighRdy points to the OS_TCB of the task to resume
;
; 2) The system stack frame of the task to suspend looks as follows:
; SYSTEM STACK AREA
; SP -> +00 OFFSET of task to suspend (Low memory)
; +02 SEGMENT of task to suspend
; +04 PSW of task to suspend (High memory)
;
; 3) The user stack frame of the task to resume looks as follows:
;
; TASK STACK AREA (High Memory)
; +12 TASK DATA PARAMETER PAGE pointer of task
; +10 TASK DATA PARAMETER OFFSET pointer of task
; +0E SEGMENT of task code address
; +0C OFFSET of task code address
?? 快捷鍵說(shuō)明
復(fù)制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號(hào)
Ctrl + =
減小字號(hào)
Ctrl + -