unit MonForm;

interface

uses
	WinTypes, WinProcs, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs, Tapi,
	StdCtrls;

type
	TfrmTAPIMon = class(TForm)
    Memo1: TMemo;
		procedure FormCreate(Sender: TObject);
		procedure FormDestroy(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
	private
		{ Private declarations }
		lineApp: THLineApp;// TAPI應用句柄
		line: THLine;      // 呼叫句柄
	public
		{ Public declarations }
	end;

var
	frmTAPIMon: TfrmTAPIMon;

implementation

{$R *.DFM}

uses Main;

var
	buf:array[0..1023] of char;
	callinfo: TLineCallInfo absolute buf;
	{
    這兩個變量指向同一個地址
    而lineGetCallInfo函數需要一個TLineCallInfo類型的指針
	}

{
  TAPI回調函數，處理TAPI各類的消息。
  主要用于實現監視線路狀態
}
procedure lineCallback(hDevice, dwMsg, dwCallbackInstance,
		dwParam1, dwParam2, dwParam3: LongInt);		stdcall;
	var
		s: string;
		hCall: THCall;
    
	begin
  {線路狀態發生了改變}
	if dwMsg = LINE_CALLSTATE then
		begin
		hCall := THCall(hDevice);//獲取當前呼叫句柄
		case dwParam1 of

      { 呼叫無效 }
			LINECALLSTATE_IDLE:
				if hcall <> 0 then
					begin
					lineDeallocateCall(hCall);	// 釋放呼叫句柄 
					frmTAPIMon.Memo1.Lines.Add( 'Idle - monitored call deallocated');
					end;

      { 呼叫建立成功 }
			LINECALLSTATE_CONNECTED:
				if hCall <> 0 then
					begin
					frmTAPIMon.Memo1.Lines.Add('Connected');
					callinfo.dwTotalSize := 4096;
					if lineGetCallInfo(hCall, callinfo) = 0 then
						begin
						if callinfo.dwAppNameSize > 0 then
							begin
              //返回當前使用該線路的程序名稱
							s := ' * AppName: ' + (buf + callinfo.dwAppNameOffset); 
							frmTAPIMon.Memo1.Lines.Add(s);
							end;
						end;
					end;

      { 呼叫處理過程中  }
			LINECALLSTATE_PROCEEDING:
				frmTAPIMon.Memo1.Lines.Add( 'Proceeding');
      { 呼叫撥號過程中  }         
			LINECALLSTATE_DIALING:
				frmTAPIMon.Memo1.Lines.Add( 'Dialing');
      { 呼叫遠端掛起  }           
			LINECALLSTATE_DISCONNECTED:
				frmTAPIMon.Memo1.Lines.Add('Disconnected');
			end;
		end;
	end;

procedure TfrmTAPIMon.FormCreate(Sender: TObject);
	var
		nDevs, tapiVersion: Longint;
		extid: TLineExtensionID;
    
	begin
	{ 初始化 TAPI }
	if lineInitialize(lineApp, HInstance,
			lineCallback, nil, nDevs) < 0 then		{ < 0 是錯誤的 }
		lineApp := 0

  { 如果沒有設備則釋放線路設備 }
	else if nDevs = 0 then
		begin
		lineShutDown(lineApp);
		lineApp := 0;
		end
    
  {檢查TAPI的版本號}
	else if lineNegotiateAPIVersion(lineApp, 0, $00010000, $10000000,
			tapiVersion, extid) < 0 then
		begin
		lineShutDown(lineApp);
		lineApp := 0;
		end

	{ 打開線路，得到由Windows返回的線路設備句柄，通常是Modem }
  { 指定參數dwPrivileges為LINECALLPRIVILEGE_MONITOR，用于實現監控 }  
	else if lineOpen(lineApp, 0, line, tapiVersion, 0, 0,
			LINECALLPRIVILEGE_MONITOR, LINEMEDIAMODE_DATAMODEM, nil) < 0 then
		begin
		lineShutDown(lineApp);
		lineApp := 0;
		line := 0;
		end;

  {顯示信息}  
	if lineApp <> 0 then
		Memo1.Lines.Add( 'Monitoring calls...')
	else
		Memo1.Lines.Add( 'Error!');
	end;

procedure TfrmTAPIMon.FormDestroy(Sender: TObject);
	begin
	{ 終止TAPI,釋放當前窗體，推出程序后才執行 }
	if line <> 0 then
		lineClose(line);
	if lineApp <> 0 then
		lineShutDown(lineApp);
	frmMain.Monitor := False;
	end;

  { 關閉窗體}
procedure TfrmTAPIMon.FormClose(Sender: TObject; var Action: TCloseAction);
	begin
	Action := caFree;
	end;

end.