/* STARTUP(crt0.o) */
OUTPUT_ARCH(m68k)
OUTPUT_FORMAT("coff-m68k")
GROUP(-lgcc -lg -lm -lm2002 -lmcard -lconso -l6305 mifare530.a)

MEMORY
{
  ram   : ORIGIN = 0x05040000, LENGTH = 1792k
  rom   : ORIGIN = 0x0005000C, LENGTH = 704k
}

PROVIDE (__stack = 0);

SECTIONS
{
  .text :
  {
    *(.text)
     . = ALIGN(4);
     etext  =  .;
     __CTOR_LIST__ = .;
     LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
     *(.ctors)
     LONG(0)
     __CTOR_END__ = .;
     __DTOR_LIST__ = .;
     LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
     *(.dtors)
     LONG(0)
     __DTOR_END__ = .;
    _etext = ALIGN(4);
  } > rom


  .data :
  AT(_etext)
  {
    _data = .;
    *(.data)
    _edata = .;
  } > ram

  _e_romdata = _etext + SIZEOF(.data) ;
  FLASH_DB_START = _e_romdata % 65536 ?
                  (_e_romdata / 65536 + 1) * 65536 :
                  _e_romdata;
  .bss :
  {
	_start_bss = .;
	*(.bss)
        *(COMMON)
        _end = .;
  } > ram

  .nvram (NOLOAD):
  {
    *(.nvram)
  } > ram

  .heap ALIGN(2048) (NOLOAD) :
  {
        _heap_bottom = .;
         . += 1280k;       /* Heap Size = 1792(total) - 256K(global variables)  */
       _heap_top    = .;
  } > ram
}
ENTRY(_start)