<%@ Language=VBScript CODEPAGE=936%>
<% Option Explicit %>
<%
'☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
'★                                                                  ★
'☆                eWebEditor - eWebSoft在線編輯器                   ☆
'★                                                                  ★
'☆  版權所有: eWebSoft.com                                          ☆
'★                                                                  ★
'☆  程序制作: eWeb開發團隊                                          ☆
'★            email:webmaster@webasp.net                            ★
'☆            QQ:589808                                             ☆
'★                                                                  ★
'☆  相關網址: [產品介紹]http://www.eWebSoft.com/Product/eWebEditor/ ☆
'★            [支持論壇]http://bbs.eWebSoft.com/                    ★
'☆                                                                  ☆
'★  主頁地址: http://www.eWebSoft.com/   eWebSoft團隊及產品         ★
'☆            http://www.webasp.net/     WEB技術及應用資源網站      ☆
'★            http://bbs.webasp.net/     WEB技術交流論壇            ★
'★                                                                  ★
'☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
%>

<%

' ============================================
' 常用全局變量
' ============================================
' 數據庫對象
Dim oConn, oRs, sSql


' ============================================
' 初始數據處理
' ============================================
' 初始化數據庫連接
Call DBConnBegin()


' ********************************************
' 以下為數據庫相關函數
' ********************************************
' ============================================
' 初始化數據庫連接對象
' 使用原則：最遲調用，最早釋放
' ============================================
Sub DBConnBegin()
	' 如果數據庫對象已打開，不要再打開
	If IsObject(oConn) = True Then Exit Sub

	' 你可以不需要打開數據庫連接對象而直接打開記錄集對象，但如果你需要打開多個記錄集對象的話，效率是很低的。
	' 如果你不創建一個數據庫連接對象，ADO會在每個記錄集打開時自動創建一個新的數據庫連接對象，就算你用的是相同的SQL語句。
	Set oConn = Server.CreateObject("ADODB.Connection")

	On Error Resume Next
	' Access數據庫
	oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("db.mdb")
	
	If Err.Number > 0 Then
		' 顯示錯誤信息,并且發送郵件通知管理員
		'Call DBConnError(Err)
		
		' 完全地退出正在運行的腳本
		Response.End
	End If

	' 創建一個記錄集
	Set oRs = Server.CreateObject( "ADODB.Recordset" )
End Sub

' ============================================
' 釋放數據庫連接對象
' ============================================
Sub DBConnEnd()
	On Error Resume Next
	oRs.Close
	Set oRs = Nothing
	oConn.Close
	Set oConn = Nothing
End Sub



' ********************************************
' 以下為常用函數
' ********************************************
' ============================================
' 錯誤返回處理
' ============================================
Sub GoError(str)
	Call DBConnEnd()
	Response.Write "<script language=javascript>alert('" & str & "\n\n系統將自動返回前一頁面...');history.back();</script>"
	Response.End
End Sub

' ============================================
' 得到安全字符串,在查詢中或有必要強行替換的表單中使用
' ============================================
Function GetSafeStr(str)
	GetSafeStr = Replace(Replace(Replace(Trim(str), "'", ""), Chr(34), ""), ";", "")
End Function

' ============================================
' 把字符串進行HTML解碼,替換server.htmlencode
' 去除Html格式，用于顯示輸出
' ============================================
Function outHTML(str)
	Dim sTemp
	sTemp = str
	outHTML = ""
	If IsNull(sTemp) = True Then
		Exit Function
	End If
	sTemp = Replace(sTemp, "&", "&amp;")
	sTemp = Replace(sTemp, "<", "&lt;")
	sTemp = Replace(sTemp, ">", "&gt;")
	sTemp = Replace(sTemp, Chr(34), "&quot;")
	sTemp = Replace(sTemp, Chr(10), "<br>")
	outHTML = sTemp
End Function

' ============================================
' 去除Html格式，用于從數據庫中取出值填入輸入框時
' 注意：value="?"這邊一定要用雙引號
' ============================================
Function inHTML(str)
	Dim sTemp
	sTemp = str
	inHTML = ""
	If IsNull(sTemp) = True Then
		Exit Function
	End If
	sTemp = Replace(sTemp, "&", "&amp;")
	sTemp = Replace(sTemp, "<", "&lt;")
	sTemp = Replace(sTemp, ">", "&gt;")
	sTemp = Replace(sTemp, Chr(34), "&quot;")
	inHTML = sTemp
End Function

' ===============================================
' 初始化下拉框
'	s_FieldName	: 返回的下拉框名	
'	a_Name		: 定值名數組
'	a_Value		: 定值值數組
'	v_InitValue	: 初始值
'	s_Sql		: 從數據庫中取值時,select name,value from table
'	s_AllName	: 空值的名稱,如:"全部","所有","默認"
' ===============================================
Function InitSelect(s_FieldName, a_Name, a_Value, v_InitValue, s_Sql, s_AllName)
	Dim i
	InitSelect = "<select name='" & s_FieldName & "' size=1>"
	If s_AllName <> "" Then
		InitSelect = InitSelect & "<option value=''>" & s_AllName & "</option>"
	End If
	If s_Sql <> "" Then
		oRs.Open s_Sql, oConn, 0, 1
		Do While Not oRs.Eof
			InitSelect = InitSelect & "<option value=""" & inHTML(oRs(1)) & """"
			If oRs(1) = v_InitValue Then
				InitSelect = InitSelect & " selected"
			End If
			InitSelect = InitSelect & ">" & outHTML(oRs(0)) & "</option>"
			oRs.MoveNext
		Loop
		oRs.Close
	Else
		For i = 0 To UBound(a_Name)
			InitSelect = InitSelect & "<option value=""" & inHTML(a_Value(i)) & """"
			If a_Value(i) = v_InitValue Then
				InitSelect = InitSelect & " selected"
			End If
			InitSelect = InitSelect & ">" & outHTML(a_Name(i)) & "</option>"
		Next
	End If
	InitSelect = InitSelect & "</select>"
End Function

' ============================================
' 每頁頭部內容
' ============================================
Sub Header(str)
	Response.Write "<HTML><HEAD><TITLE>eWebEditor在線編輯器 - 例子：新聞系統</TITLE><style>body,p,td,input {font-size:9pt}</style></HEAD><BODY>"
	Response.Write "<p align=center><a href='list.asp'>新聞列表</a> | <a href='add.asp'>增加新聞</a></p>"
	Response.Write "<p align=center><b>" & str & "</b></p>"
End Sub

' ============================================
' 每頁底部內容
' ============================================
Sub Footer()
	Call DBConnEnd()
	Response.Write "</BODY></HTML>"
End Sub

%>