<!--#include file = "Include/Startup.asp"-->
<!--#include file = "Include/md5.asp"-->
<!--#include file = "admin_private.asp"-->
<%
'☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
'★                                                                  ★
'☆                eWebEditor - eWebSoft在線編輯器                   ☆
'★                                                                  ★
'☆  版權(quán)所有: eWebSoft.com                                          ☆
'★                                                                  ★
'☆  程序制作: eWeb開(kāi)發(fā)團(tuán)隊(duì)                                          ☆
'★            email:webmaster@webasp.net                            ★
'☆            QQ:589808                                             ☆
'★                                                                  ★
'☆  相關(guān)網(wǎng)址: [產(chǎn)品介紹]http://www.eWebSoft.com/Product/eWebEditor/ ☆
'★            [支持論壇]http://bbs.eWebSoft.com/                    ★
'☆                                                                  ☆
'★  主頁(yè)地址: http://www.eWebSoft.com/   eWebSoft團(tuán)隊(duì)及產(chǎn)品         ★
'☆            http://www.webasp.net/     WEB技術(shù)及應(yīng)用資源網(wǎng)站      ☆
'★            http://bbs.webasp.net/     WEB技術(shù)交流論壇            ★
'★                                                                  ★
'☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
%>

<%

sPosition = sPosition & "修改用戶名及密碼"

Call Header()
Call Content()
Call Footer()


Sub Content()
	Select Case sAction
	Case "MODI"
		' 修改操作
		Call DoModi()
	Case Else
		' 修改表單
		Call ShowForm()
	End Select
End Sub

' 顯示修改表單
Sub ShowForm()
%>
<script language=javascript>
// 客戶端驗(yàn)證表單的有效性
function checklogin() {
	var obj;
	obj=document.myform.newusr;
	obj.value=BaseTrim(obj.value);
	if (obj.value=="") {
		BaseAlert(obj, "新用戶名不能為空！");
		return false;
	}
	obj=document.myform.newpwd1;
	obj.value=BaseTrim(obj.value);
	if (obj.value=="") {
		BaseAlert(obj, "新密碼不能為空！");
		return false;
	}
	if (document.myform.newpwd1.value!=document.myform.newpwd2.value){
		BaseAlert(document.myform.newpwd1, "新密碼和確認(rèn)密碼不相同！");
		return false;
	}
	return true;
}
</script>

<br>
<table border=0 cellpadding=0 cellspacing=0 align=center class=form1>
<form action='?action=modi' method=post name=myform onsubmit="return checklogin()">
<tr><th>&nbsp;&nbsp;修改您的登錄用戶及密碼（每項(xiàng)必填）</th></tr>
<tr><td>新用戶名：<input type=text class=input size=20 name=newusr value="<%=inHTML(Session("eWebEditor_User"))%>">&nbsp;&nbsp;舊用戶名：<span class=highlight1><%=outHTML(Session("eWebEditor_User"))%></span></td></tr>
<tr><td>新 密 碼：<input type=password class=input size=20 name=newpwd1 maxlength=30>&nbsp;&nbsp;確認(rèn)密碼：<input type=password class=input size=20 name=newpwd2 maxlength=30></td></tr>
<tr><td align=center><input type=image border=0 src='admin/submit.gif' align=absmiddle>&nbsp;<a href='javascript:document.myform.reset()'><img border=0 src='admin/reset.gif' align=absmiddle></a></td></tr>
</form>
</table>
<br><br>

<%
End Sub

' 修改操作
Sub DoModi()
	' 服務(wù)器端驗(yàn)證表單的有效性
	If IsSelfRefer() = False Then
		Go_Error "提交表單有問(wèn)題！！！"
	End If

	Dim sNewUsr, sNewPwd1, sNewPwd2
	sNewUsr = Trim(Request("newusr"))
	sNewPwd1 = Trim(Request("newpwd1"))
	sNewPwd2 = Trim(Request("newpwd2"))

	If sNewUsr = "" Then
		Go_Error "新用戶名不能為空！"
	End If
	If sNewPwd1 = "" then
		Go_Error "新密碼不能為空！"
	End If
	If sNewPwd1 <> sNewPwd2 Then
		Go_Error "新密碼和確認(rèn)密碼不相同！"
	End If

	sSql = "select * from ewebeditor_system"
	oRs.Open sSql, oConn, 1, 3
	If Not oRs.Eof Then
		oRs("sys_username") = md5(sNewUsr)
		oRs("sys_userpass") = md5(sNewPwd1)
		oRs.Update
	End If
	oRs.Close

	Response.Write "<br><p align=center class=title>修改用戶名及密碼</p>" & _
		"<br><table border=0 cellspacing=20 align=center>" & _
		"<tr valign=top><td><img src='admin/do_ok.gif' border=0></td><td><b><span class=highlight2>登錄用戶名及密碼修改成功！</span></b><br><br><ul>我現(xiàn)在<br><br><li><a href='admin_default.asp'>返回后臺(tái)管理首頁(yè)</a><li><a href='admin_modipwd.asp'>重新修改</a></ul></td></tr>" & _
		"</table><br><br>"

End Sub

%>