/*--------------------------------------------------------------------------*
 * This is an example linker directive file for the PC87591 in OBD mode.
 *	code_mem  section = first 56 Kbyte of the flash address space
 *  code_mem2 section = 64K-128K bytes of the flash address space
 *	data_mem  section = system RAM address space
 *--------------------------------------------------------------------------*/

MEMORY {
	code_mem0:	origin = 0x0,		    length=0x10
	code_mem:   origin=0x1000,              length=0xd000
	data_mem:   origin=0xE800,              length=0x1000
	code_mem2:  origin=0x10000,             length=0x10000
}

SECTIONS {
	.ramtext ALIGN(2) INTO(data_mem): { temp.o(.text) }

	.text ALIGN(2) INTO(code_mem0): {"start\release.o"(.text) }

	.text ALIGN(2) INTO(code_mem): {*(.text) }

	.rdata ALIGN(2) INTO(code_mem): { *(.rdata_2) *(.rdata_1) }

	.data ALIGN(2) INTO(data_mem) ROMINTO(code_mem):  { *(.data) *(.data_2) *(.data_1) }

	.bss ALIGN(2) INTO(data_mem): { *(.bss) *(.bss_2) *(.bss_1) } 

	.sb  ALIGN(2) INTO(data_mem): { *(.sb_1) *(.sb_2)}

	.init ALIGN(2) INTO(code_mem) : {}

/*--------------------------------------------------------------------------*
 * You may change the sizes of the following secsions to fit the actual size
 * your program requires.
 *--------------------------------------------------------------------------*/

	/* The following section is used for the program interrupt stack */
	.istack (NOLOAD) ALIGN(2) INTO(data_mem): {. += 0x10;}

	/* The following section is used for program stack and heap */
	/* The size has no meaning it is used only to mark the section */
	.stack (NOLOAD) ALIGN(2) INTO(data_mem): {. += 0x300;}
}

__ISTACK_START =  ADDR(.istack) + SIZEOF(.istack);

/* The stack begins at end of data_mem */
__STACK_START =  ADDR(.stack) + SIZEOF(.stack);

/* The heap begins at end of stack */
_HEAP$_START = ADDR(.stack) + 0x02;
_HEAP$_MAX = __STACK_START - 0x30;

__STATIC_BASE_START = ADDR(.sb);