; 漢字寫入子程序(圖形方式)CCW2_PR
;  占用內(nèi)部資源：O_XL,O_YL,CODE,COUNT1,A,B,DPTR
;  內(nèi)部調(diào)用子程序：PR1
;  連接字庫：      CCTAB 
;  程序調(diào)用入口：  CCW2_PR
;  程序輸入變量：  O_XL,O_YL,CODE
CCW2_PR:MOV	A,CODE		; 計(jì)算漢字字模數(shù)據(jù)首地址
	MOV	B,#20H
	MUL	AB
	MOV	DPTR,#CGTAB     ; 漢字庫入口地址
	ADD	A,DPL
	MOV	DPL,A
	MOV	A,B
	ADDC	A,DPH
	MOV	DPH,A
	MOV	A,O_YL		; 計(jì)算光標(biāo)地址
        MOV     B,#PARA1        ; PARA1值等于SYSTEM SET 指令P9
        MUL     AB              ; 而P10=0
	ADD	A,O_XL
	MOV	O_XL,A		; 存光標(biāo)地址低字節(jié)
	MOV	A,B
	ADDC	A,#40H          ; 加入顯示二區(qū)起始地址SAD2H
	MOV	O_YL,A		; 存光標(biāo)地址高字節(jié)
	MOV	COM,#4FH	; CSRDIR 代碼(下移)
	LCALL	PR1
	MOV	COUNT1,#02H	; 設(shè)置計(jì)數(shù)器1=2
CCW2_1:	MOV	COM,#46H	; CSRW 代碼
	LCALL	PR1
	MOV	DAT1,O_XL	; 設(shè)置光標(biāo)地址CSR
	LCALL	PR2
	MOV	DAT1,O_YL
	LCALL	PR2
	MOV	COM,#42H	; MWRITE 代碼
	LCALL	PR1
	MOV	COUNT2,#10H	; 設(shè)置計(jì)數(shù)器2=16
CCW2_2: CLR	A
	MOVC	A,@A+DPTR	; 取字模數(shù)據(jù)
	MOV	DAT1,A
	INC	DPTR		; 指針加一
	LCALL	PR2		; 寫入數(shù)據(jù)
	DJNZ	COUNT2,CCW2_2	; 循環(huán)
	MOV	A,O_XL		; 修正光標(biāo)地址
	ADD	A,#01H		; (加一)
	MOV	O_XL,A
	MOV	A,O_YL
	ADDC	A,#00H
	MOV	O_YL,A
	DJNZ	COUNT1,CCW2_1	; 循環(huán)
	RET