#include          "msp430x14x.h" // Standard Equations
;******************************************************************************
;   MSP-FET430P140 Demo - ADC12, Single Conversion on Single Channel
;
;   Description: This program will show how to perform a single conversion
;                on a single channel
;
;   This example shows how to perform a single ADC12 conversion on a single
;   channel. It uses AVcc for the reference and performs a single conversion on 
;   Channel A0. The conversion results are stored in ADC12MEM0 and are moved to 
;   R5 after the convserion is complete. Test by applying a voltage to channel 
;   A0, then setting and running to a break point at "jmp Mainloop."  To view 
;   the conversion results, open a register window in C-Spy and view the 
;   contents of R5.
;
;
;                MSP430F149
;              ---------------
;             |               |
;             |      A0 (P6.0)|<---- Vin
;             |               |
;
;
;       M.Mitchell
;       Texas Instruments, Inc
;       January, 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
main        ORG     01100h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov     #0A00h,SP               ; Initialize stackpointer
StopWDT     mov     #WDTPW+WDTHOLD,&WDTCTL  ; Stop watchdog
            bis.b   #BIT0,&P6SEL            ; Enable A/D channel A0
                                            ;
SetupADC12  mov     #ADC12ON+SHT0_2,&ADC12CTL0 ; Turn on ADC12, set samp. time
            mov     #SHP,&ADC12CTL1         ; Use sampling timer    
            bis     #ENC,&ADC12CTL0         ; Enable conversions
                                            ;            
Mainloop    bis     #ADC12SC,&ADC12CTL0     ; Start conversions
testIFG     bit     #BIT0,&ADC12IFG         ; Conversion done?
            jz      testIFG                 ; No, test again
            mov     &ADC12MEM0,R5           ; Move result
            jmp     Mainloop                ; SET BREAKPOINT HERE
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors         
;------------------------------------------------------------------------------
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ;
            END