VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "clsVchQueryBI"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
'--------------------------------
'時間:2001.11.12
'版權:北京用友軟件股份有限公司
'設計:章景峰
'編碼:章景峰
'說明:U8資金管理---業務對象
'--------------------------------
Option Explicit
Private Const m_conBIStyle As Long = 10

Public Function Init(ByVal DataSourceName As String, Optional ByVal BIStyle As Long = m_conBIStyle) As U8FDEso.EntityObject
    Dim objEO       As U8FDEso.EntityObject
    Dim objOID      As U8FDEso.OIDObject
    Dim objDataMgr  As New U8FDMgr.DataManager
    Dim objOIDMgr   As New U8FDMgr.OIDManager
    
    Set objEO = objDataMgr.LoadEOMetaData(DataSourceName, BIStyle)
    Set objOID = objOIDMgr.GetNewOID(DataSourceName, BIStyle, False)
    Set objEO.OID = objOID
    Set Init = objEO
    
    Set objDataMgr = Nothing
    Set objOIDMgr = Nothing
    Set objOID = Nothing
    Set objEO = Nothing
End Function

Public Function MoveTo(ByVal DataSourceName As String, MoveMode As U8FDEso.MoveModeEnum, Optional ByVal BIStyle As Long = m_conBIStyle, Optional OID As U8FDEso.OIDObject) As U8FDEso.EntityObject
    Dim objEO      As U8FDEso.EntityObject
    Dim objDataMgr As New U8FDMgr.DataManager
    
    Set objEO = objDataMgr.LoadEOMetaData(DataSourceName, BIStyle)
    
    If Not OID Is Nothing Then Set objEO.OID = OID
    If con.State = adStateClosed Then con.Open DataSourceName
    If objDataMgr.MoveTo(con, objEO, MoveMode) Then
        Set MoveTo = objEO
    Else
        Set MoveTo = Nothing
    End If
    
    Set objDataMgr = Nothing
    Set objEO = Nothing
End Function

Public Function Save(ByVal DataSourceName As String, EO As U8FDEso.EntityObject, Optional ByVal BIStyle As Long = m_conBIStyle) As Boolean
    Dim objDataMgr As New U8FDMgr.DataManager
    Dim objOIDMgr  As New U8FDMgr.OIDManager
    Dim objOID     As U8FDEso.OIDObject
    
    If Not Validate(DataSourceName, EO) Then Exit Function
    If EO.State = esoAddNew Then
        Set objOID = objOIDMgr.GetNewOID(DataSourceName, BIStyle, True)
        Set EO.OID = objOID
    End If
    
    If con.State = adStateClosed Then con.Open DataSourceName
    Save = objDataMgr.Save(con, EO)
    
    Set objDataMgr = Nothing
    Set objOIDMgr = Nothing
    Set objOID = Nothing
End Function

Public Function Delete(ByVal DataSourceName As String, EO As U8FDEso.EntityObject, Optional ByVal BIStyle As Long = m_conBIStyle) As Boolean
    Dim objDataMgr As New U8FDMgr.DataManager
    
    If con.State = adStateClosed Then con.Open DataSourceName
    Delete = objDataMgr.Delete(con, EO)
    
    Set objDataMgr = Nothing
End Function

Public Function Validate(ByVal DataSourceName As String, EO As U8FDEso.EntityObject) As Boolean
    Select Case EO.State
        Case esoAddNew
        
        Case esoDelete
        
        Case esoEdit
        
        Case esoInitialized
        
        Case esoInstance
        
    End Select
    Validate = True
End Function

Public Function LoadVchEOs(DataSourceName As String, Optional IsAll As Boolean = False) As U8FDEso.Entities
    Dim objEOs  As New U8FDEso.Entities
    Dim objEO   As U8FDEso.EntityObject
    Dim sql     As String
    Dim rec     As New ADODB.Recordset
    
    If con.State = adStateClosed Then con.Open DataSourceName
    If IsAll Then
        sql = "Select * From FD_Entities Where iVchType <> 0 Order by iID"
    Else
        sql = "Select * From FD_Entities Where iVchType <> 0 and iIsUsed=1 Order by iID"
    End If
    
    rec.Open sql, con
    Do Until rec.EOF
        Set objEO = New U8FDEso.EntityObject
        
        With objEO
            .ID = rec!iID
            .Name = rec!sName
            .Caption = rec!sCaption
            .State = esoInstance
            .BIType = rec!iBIType
            .SourceOIDField = rec!sOIDSourceField
            .SourceTable = rec!sSourceTable
            .ParentField = IIf(IsNull(rec!sParentField), "", rec!sParentField)
            .TaskID = IIf(IsNull(rec!sTaskID), "", rec!sTaskID)
            .HelpContextID = IIf(IsNull(rec!sHelpContextID), "", rec!sHelpContextID)
            .Description = IIf(IsNull(rec!sDescription), "", rec!sDescription)
            .SheetID = IIf(IsNull(rec!iSheet), 0, rec!iSheet)
            .Rows = IIf(IsNull(rec!iRows), 0, rec!iRows)
            .Cols = IIf(IsNull(rec!iCols), 0, rec!iCols)
            .IsUsed = IIf(IsNull(rec!iIsUsed), 0, rec!iIsUsed)
            .PzSign = IIf(IsNull(rec!sPzSign), "", rec!sPzSign)
            .VchType = IIf(IsNull(rec!iVchType), "", rec!iVchType)
        End With
        
        objEOs.Append objEO, "K" & rec!iBIType
        
        rec.MoveNext
    Loop
    
    rec.Close
    Set rec = Nothing
    
    Set LoadVchEOs = objEOs
    
    Set objEO = Nothing
    Set objEOs = Nothing
End Function

Public Function SaveVchEOs(DataSourceName As String, EOS As U8FDEso.Entities) As Boolean
    Dim objDataMgr As New U8FDMgr.DataManager
    Dim i          As Integer
    
    If Not EOS Is Nothing Then
        For i = 1 To EOS.Count
            SaveVchEOs = objDataMgr.SaveEOMetaData(DataSourceName, EOS.Item(i), True)
        Next
    End If
    
    SaveVchEOs = True
    
    Set objDataMgr = Nothing
End Function