;這是關于DS18B20的讀寫程序,數據腳IN,晶振11.0592mhz
;溫度傳感器18B20匯編程序,采用器件默認的12位轉化,最大轉化時間750微秒
;可以將檢測到的溫度直接顯示到AT89C51開發實驗板的兩個數碼管上
;顯示溫度00到99度,很準確哦~~無需校正!

ORG 0000H

;單片機內存分配申明!
TEMPER_L EQU 29H;用于保存讀出溫度的低8位
TEMPER_H EQU 28H;用于保存讀出溫度的高8位
FLAG1 EQU 38H;是否檢測到DS18B20標志位
a_bit equ 20h ;數碼管個位數存放內存位置
b_bit equ 21h ;數碼管十位數存放內存位置
in equ P3.3
FF1 EQU P2.7
FF2 EQU P2.6


MAIN: 

LCALL GET_TEMPER;調用讀溫度子程序

;進行溫度顯示,這里我們考慮用網站提供的兩位數碼管來顯示溫度
;顯示范圍00到99度,顯示精度為1度
;因為12位轉化時每一位的精度為0.0625度,我們不要求顯示小數所以可以拋棄29H的低4位
;將28H中的低4位移入29H中的高4位,這樣獲得一個新字節,這個字節就是實際測量獲得的溫度
;這個轉化溫度的方法可是我想出來的哦~~非常簡潔無需乘于0.0625系數

MOV A,29H
MOV C,40H;將28H中的最低位移入C
RRC A
MOV C,41H
RRC A
MOV C,42H
RRC A
MOV C,43H
RRC A
MOV 29H,A

LCALL DISPLAY;調用數碼管顯示子程序

CPL P1.0
AJMP MAIN


; 這是DS18B20復位初始化子程序
INIT_1820:
SETB IN
NOP
CLR IN
;主機發出延時537微秒的復位低脈沖
MOV R1,#3
TSR1:MOV R0,#107
DJNZ R0,$
DJNZ R1,TSR1
SETB IN;然后拉高數據線
NOP
NOP
NOP
MOV R0,#25H
TSR2:
JNB IN,TSR3;等待DS18B20回應
DJNZ R0,TSR2
LJMP TSR4 ; 延時
TSR3:
SETB FLAG1 ; 置標志位,表示DS1820存在
CLR P1.7;檢查到DS18B20就點亮P1.7LED
LJMP TSR5
TSR4:
CLR FLAG1 ; 清標志位,表示DS1820不存在
CLR P1.1
LJMP TSR7

TSR5:
MOV R0,#117
TSR6:
DJNZ R0,TSR6 ; 時序要求延時一段時間
TSR7:
SETB IN
RET

; 讀出轉換后的溫度值
GET_TEMPER:
SETB IN
LCALL INIT_1820;先復位DS18B20
JB FLAG1,TSS2
CLR P1.2
RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
TSS2:
CLR P1.3;DS18B20已經被檢測到!!!!!!!!!!!!!!!!!!
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 發出溫度轉換命令
LCALL WRITE_1820

;這里通過調用顯示子程序實現延時一段時間,等待AD轉換結束,12位的話750微秒
LCALL DISPLAY

LCALL INIT_1820;準備讀溫度前先復位

MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820

MOV A,#0BEH ; 發出讀溫度命令
LCALL WRITE_1820

LCALL READ_18200; 將讀出的溫度數據保存到35H/36H 
CLR P1.4

RET

;寫DS18B20的子程序(有具體的時序要求)
WRITE_1820:
MOV R2,#8;一共8位數據
CLR C
WR1:
CLR IN
MOV R3,#5
DJNZ R3,$
RRC A
MOV IN,C
MOV R3,#21
DJNZ R3,$
SETB IN
NOP
DJNZ R2,WR1
SETB IN
RET

; 讀DS18B20的程序,從DS18B20中讀出兩個字節的溫度數據 
READ_18200:
MOV R4,#2 ; 將溫度高位和低位從DS18B20中讀出
MOV R1,#29H ; 低位存入29H(TEMPER_L),高位存入28H(TEMPER_H)
RE00:
MOV R2,#8;數據一共有8位
RE01:
CLR C
SETB IN
NOP
NOP
CLR IN
NOP
NOP
NOP
SETB IN

MOV R3,#8
RE10: 
DJNZ R3,RE10

MOV C,IN

MOV R3,#21
RE20: 
DJNZ R3,RE20

RRC A
DJNZ R2,RE01
MOV @R1,A
DEC R1
DJNZ R4,RE00
RET

;顯示子程序
display: mov a,29H;將29H中的十六進制數轉換成10進制 
mov b,#10 ;10進制/10=10進制
div ab
mov b_bit,a ;十位在a
mov a_bit,b ;個位在b
mov dptr,#numtab ;指定查表啟始地址
mov r0,#4 
dpl1: mov r1,#250 ;顯示1000次
dplop: mov a,a_bit ;取個位數
MOVC A,@A+DPTR ;查個位數的7段代碼
mov p0,a ;送出個位的7段代碼
clr FF2 ;開個位顯示
acall d1ms ;顯示1ms
setb FF2
mov a,b_bit ;取十位數
MOVC A,@A+DPTR ;查十位數的7段代碼
mov p0,a ;送出十位的7段代碼
clr FF1 ;開十位顯示
acall d1ms ;顯示1ms
setb FF1
djnz r1,dplop ;100次沒完循環
djnz r0,dpl1 ;4個100次沒完循環
ret

;1MS延時
D1MS: MOV R7,#80 
DJNZ R7,$
RET

;實驗板上的7段數碼管0～9數字的共陰顯示代碼
numtab:  DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H,0FFH;;
;DB 0CFH,03H,5DH,5BH,93H,0DAH,0DEH,43H,0DFH,0DBH

end