min_Pascal語言的語法用BNF描述如下（空語句用empty表示）：
<程序> -> Program<程序名>；<塊體>?
<塊體> -> [<常數定義部份>]［<類型定義部份>][<變量定義部分>]
        {<過程定義>}<復合語句>
<常數定義部份> -> const <常數定義>{<常數定義>}
<常數定義> -> <常數名>＝<常數>；
<類型定義部份> -> type <類型定義>{<類型定義>}
<類型定義> -> <類型名>＝<新類型>；
<新類型> -> <數組類型>|<記錄類型>
<數組類型> -> array[<下標域>] of <類型名>
<下標域> -> <常數>??<常數>
<記錄類型> -> record<域表>end
<域表> -> <記錄節>{；<記錄節>}
<記錄節> -> <域名>{,<域名>}：<類型名>
<變量定義部份> -> var<變量定義>{<變量定義>}
<變量定義> -> <變量組>；
<變量組>-> <變量名>{,<變量名>}：<類型名>
<過程定義>-> Procedure <過程名><過程塊>；
<過程塊>-> [（<形參表>）]；<塊體>
<形參表>-> <參數定義>{；<參數定義>}
<參數定義>-> [var]<變量組>
<語句>-> <賦位語句>|<過程語句>|<if語句>|<while語句>|<復合語句>|empty
<賦值語句>-> <變量訪問>：＝<表達式>
<過程語句>-> <過程名>[(<實參表>)]
<實參表> -> <實參>{,<實參>}
<實參>-> <表達式>|<變量訪問>
<if語句>-> if<表達式>then<語句>[eIse<語句>]
<while語句>-> while<表達式>do<語句>
<復合語句>-> begin <語句>{；<語句>}end
<表達式>-> <簡單表達式>[<關系算符><簡單表達式>]
<關系算符>-> <|=|>|<=|>=|<>
<簡單表達式>-> [+|-]<項>{<加法算符><項>}
<加法算符> -> ＋|-|or
<項>-> <因子>{<乘法算符><因子>}
<乘法算符>-> *|div|mod|and
<因子> -> <常數>|<變量訪問>|(<表達式>)|not<因子>
<變量訪問> -> <變量名>{<選擇器>}
<選擇器> -> <下標選擇器>|<域選擇器>
<下標選擇器> -> [<表達式>]
<域選擇器> -> ?<域名>
<常數> -> <整數>|<常數名>
<整數> -><數字>{<數字>}
<名字> -> <字母>{<字母>|<數字>}
注：<常數名>，<變量名>,<類型名>,<過程名>,<域名>統稱為<名字>。{,}是元語言符號。