<!--#include file = "Startup.asp"-->

<%

' ======================
' 功能：修改新聞
' 描述：提供一個(gè)修改表單，包括新聞標(biāo)題和新聞內(nèi)容，新聞內(nèi)容使用eWebEditor進(jìn)行編輯；
'       同時(shí)接收上傳文件，以便刪除新聞時(shí)，同時(shí)刪除上傳文件；
'       并由編輯區(qū)中上傳的文件，提供標(biāo)題新聞的圖片選擇；
'		功能與新增相同，不同在于只是修改表單具有初始值。
' ======================

Call Header("修改新聞")
Call Content()
Call Footer()


' 本頁(yè)內(nèi)容區(qū)
Sub Content()
	
	' 傳入?yún)?shù)：新聞ID
	Dim sNewsID
	sNewsID = Trim(Request("id"))

	' 新聞ID有效性驗(yàn)證，防止有些人惡意的破壞此演示程序
	If IsNumeric(sNewsID) = False Then
		GoError "請(qǐng)通過(guò)頁(yè)面上的鏈接進(jìn)行操作，不要試圖破壞此演示系統(tǒng)。"
	End If

	' 從數(shù)據(jù)庫(kù)中取初始值
	Dim sTitle, sContent, sPicture, sOriginalFileName, sSaveFileName, sSavePathFileName
	sSql = "SELECT * FROM NewsData WHERE D_ID=" & sNewsID
	oRs.Open sSql, oConn, 0, 1
	If Not oRs.Eof Then
		sTitle = oRs("D_Title")
		sContent = oRs("D_Content")
		sPicture = oRs("D_Picture")
		sOriginalFileName = oRs("D_OriginalFileName")
		sSaveFileName = oRs("D_SaveFileName")
		sSavePathFileName = oRs("D_SavePathFileName")
	Else
		GoError "無(wú)效的新聞ID，請(qǐng)點(diǎn)頁(yè)面上的鏈接進(jìn)行操作！"
	End If
	oRs.Close

	' 把帶"|"的字符串轉(zhuǎn)為數(shù)組，用于初始下拉框表單
	Dim aSavePathFileName
	aSavePathFileName = Split(sSavePathFileName, "|")

	' 根據(jù)新聞內(nèi)容中相關(guān)上傳文件為數(shù)據(jù)，初始下拉框表單
	' 函數(shù)InitSelect，根據(jù)數(shù)組值及初始值返回下拉框輸出字串，具體請(qǐng)見(jiàn)startup.asp文件中函數(shù)的說(shuō)明部分
	Dim sOptionSavePath
	sOptionSavePath = InitSelect("d_picture", aSavePathFileName, aSavePathFileName, sPicture, "", "無(wú)")

	%>

	<Script Language=JavaScript>
	// 當(dāng)上傳圖片等文件時(shí)，往下拉框中填入圖片路徑，可根據(jù)實(shí)際需要更改此函數(shù)
	function doChange(objText, objDrop){
		if (!objDrop) return;
		var str = objText.value;
		var arr = str.split("|");
		var nIndex = objDrop.selectedIndex;
		objDrop.length=1;
		for (var i=0; i<arr.length; i++){
			objDrop.options[objDrop.length] = new Option(arr[i], arr[i]);
		}
		objDrop.selectedIndex = nIndex;
	}

	// 表單提交客戶端檢測(cè)
	function doSubmit(){
		if (document.myform.d_title.value==""){
			alert("新聞標(biāo)題不能為空！");
			return false;
		}
		// getHTML()為eWebEditor自帶的接口函數(shù)，功能為取編輯區(qū)的內(nèi)容
		if (eWebEditor1.getHTML()==""){
			alert("新聞內(nèi)容不能為空！");
			return false;
		}
		document.myform.submit();
	}
	</Script>
	
	<form action="modifysave.asp?id=<%=sNewsID%>" method="post" name="myform">
	<% '取源文件名 %>
	<input type=hidden name=d_originalfilename value="<%=sOriginalFileName%>">
	<% '取保存的方件名（帶路徑），如果不要帶路徑的填充下拉框，可以在下面的表單項(xiàng)加入onchange事件 %>
	<input type=hidden name=d_savefilename value="<%=sSaveFileName%>">
	<% '取保存的文件名，使用帶路徑的填充下拉框 %>
	<input type=hidden name=d_savepathfilename onchange="doChange(this,document.myform.d_picture)" value="<%=sSavePathFileName%>">

	<table cellspacing=3 align=center>
	<tr>
		<td>新聞標(biāo)題：</td>
		<% ' 函數(shù)inHTML：去除Html格式，用于從數(shù)據(jù)庫(kù)中取出值填入輸入框時(shí)，具體請(qǐng)見(jiàn)startup.asp文件中函數(shù)的說(shuō)明 %>
		<td><input type="text" name="d_title" value="<%=inHTML(sTitle)%>" size="90"></td>
	</tr>
	<tr>
		<td>標(biāo)題圖片：</td>
		<td><%=sOptionSavePath%> 當(dāng)編輯區(qū)有插入圖片時(shí)，將自動(dòng)填充此下拉框</td>
	</tr>
	<tr>
		<td>新聞內(nèi)容：</td>
		<td>
			<%
			' ewebeditor.asp文件調(diào)用的參數(shù)：
			'	id：下面表單項(xiàng)textarea的名稱，在此表單中是d_content，注意大小寫
			'	style：編輯器的樣式名稱，可在eWebEditor的后臺(tái)設(shè)置
			'	originalfilename：用于獲取源文件名的表單項(xiàng)名，在此表單中是d_originalfilename
			'	savefilename：用于獲取保存文件名的表單項(xiàng)名，在此表單中是d_savefilename
			'	savepathfilename：用于獲取保存帶路徑文件名的表單項(xiàng)名，在此表單中是d_savepathfilename

			' 請(qǐng)一定要用Server.HtmlEncode()函數(shù)對(duì)內(nèi)容進(jìn)行轉(zhuǎn)換，否則將有可以出現(xiàn)某些內(nèi)容出了編輯區(qū)的情況
			%>
			<textarea name="d_content" style="display:none"><%=Server.HtmlEncode(sContent)%></textarea>
			<iframe ID="eWebEditor1" src="../../ewebeditor.asp?id=d_content&style=s_newssystem&originalfilename=d_originalfilename&savefilename=d_savefilename&savepathfilename=d_savepathfilename" frameborder="0" scrolling="no" width="550" HEIGHT="350"></iframe>
		</td>
	</tr>
	</table>
	<p align=center><input type=button name=btnSubmit value=" 提 交 " onclick="doSubmit()"> <input type=reset name=btnReset value=" 重 填 "></p>
	</form>

	<%
End Sub

%>