<!--#include file = "Startup.asp"-->
<%

' ======================
' 功能：增加新聞保存頁
' 描述：對add.asp文件提交過來的表單數(shù)據(jù)進(jìn)行保存操作，有保存新聞標(biāo)題，新聞內(nèi)容，新聞標(biāo)題圖片；
'       同時保存所有此篇新聞所有相關(guān)的上傳或遠(yuǎn)程獲取的文件信息，有源文件名，保存文件名，保存路徑文件名。
' ======================

Call Header("增加新聞保存")
Call Content()
Call Footer()


' 本頁內(nèi)容區(qū)
Sub Content()
	Dim i

	' 取提交過來的數(shù)據(jù)
	' 注意取新聞內(nèi)容的方法，因?yàn)閷Υ蟊韱蔚淖詣犹幚?，一定要使用循環(huán)，否則大于100K的內(nèi)容將取不到，單個表單項(xiàng)的限制為102399字節(jié)（100K左右）
	Dim sTitle, sContent, sPicture
	sTitle = Request.Form("d_title")
	sPicture = Request.Form("d_picture")

	' 開始：eWebEditor編輯區(qū)取值-----------------
	sContent = ""
	For i = 1 To Request.Form("d_content").Count
		sContent = sContent & Request.Form("d_content")(i)
	Next
	' 結(jié)束：eWebEditor編輯區(qū)取值-----------------
	

	' 以下為所有通過編輯器上傳的所有文件相關(guān)信息，包括編輯區(qū)手動上傳的和自動遠(yuǎn)程上傳的
	' GetSafeStr函數(shù)為過濾一些特殊字符，防止有些人惡意的破壞此演示程序
	' 上傳或遠(yuǎn)程獲取前的原文件名，多個以"|"分隔
	Dim sOriginalFileName
	' 上傳后保存到本地服務(wù)器的文件名（不帶路徑），多個以"|"分隔
	Dim sSaveFileName
	' 上傳后保存到本地服務(wù)器的路徑文件名，多個以"|"分隔
	Dim sSavePathFileName
	sOriginalFileName = GetSafeStr(Request.Form("d_originalfilename"))
	sSaveFileName = GetSafeStr(Request.Form("d_savefilename"))
	sSavePathFileName = GetSafeStr(Request.Form("d_savepathfilename"))

	' 保存新聞內(nèi)容，同時取出自增的新聞ID
	Dim sNewsID
	sSql = "SELECT * FROM NewsData WHERE D_ID=0"
	oRs.Open sSql, oConn, 1, 3
	oRs.AddNew
	oRs("D_Title") = sTitle
	oRs("D_Content") = sContent
	oRs("D_Picture") = sPicture
	oRs("D_OriginalFileName") = sOriginalFileName
	oRs("D_SaveFileName") = sSaveFileName
	oRs("D_SavePathFileName") = sSavePathFileName
	oRs.Update
	sNewsID = oRs("D_ID")
	oRs.Close
	
	' 輸出成功保存信息
	Response.Write "新聞（ID：" & sNewsID & "）增加保存成功！"

End Sub

%>