/****************************************************************************
模塊名稱：Signal  文件名：signal.v
模塊功能：用于產生測試信號，對所設計的EEPROM_WR模塊進行測試。Signal模塊
          能對被測試模塊產生的ack信號產生響應，發出模仿MCU的數據、地址信號
          和讀/寫信號。被測試的模塊在接收到信號后會發出寫/讀EEPROM虛擬模塊
          的信號。  
模塊說明：本模塊為行為模塊，不可綜合為門級網表。而且本模塊為教學目的做了許
          多簡化，功能不完整，不能用做商業目的。
****************************************************************************/
// 信號源模型：
`timescale 1ns/1ns
`define timeslice1 200
`define CheckByteNum 16
module Signal(RESET,CLK,RD,WR,ADDR,ACK,DATA); 
output RESET;        //復位信號
output CLK;          //時鐘信號
output RD,WR;        //讀寫信號
output[10:0] ADDR;    //11位地址信號
input ACK;           //讀寫周期的應答信號
inout[7:0] DATA;      //數據線
reg RESET;
reg CLK;
reg RD,WR;
reg W_R;            //低位：寫操作；高位：讀操作 
reg[10:0] ADDR;  
reg[7:0]  data_to_eeprom;
reg[10:0] addr_mem[0:255];
reg[7:0]  data_mem[0:255];
reg[7:0]  ROM[0:2047]; 
integer i,j;
integer OUTFILE;
assign DATA = (W_R) ?  8'bz : data_to_eeprom ;

//------------------------------------時鐘信號輸入------------------------------
always #(`timeslice1/2)
   CLK = ~CLK; 

//----------------------------------- 讀寫信號輸入------------------------------
initial 
   begin
     RESET = 1;
     i   = 0; 
     j   =0;
     W_R = 0;
     CLK = 0;    			
     RD  = 0;
     WR  = 0;
     #1000 ;
     RESET = 0; 
repeat(`CheckByteNum)  //連續寫15次數據，調試成功后可以增加到全部地址覆蓋測試
      begin	
        # (5 * `timeslice1);
	    WR = 1; 
	    # (`timeslice1);
	    WR = 0;
	   @ (posedge ACK);  //EEPROM_WR轉換模塊請求寫數據
     end
    #(10 * `timeslice1);
    W_R = 1;   //開始讀操作
    repeat(`CheckByteNum)  //連續讀15次數據 
      begin
     	# (5 * `timeslice1);
     	RD = 1;
       # ( `timeslice1 );
     	RD = 0;
   	   @ (posedge ACK);  //EEPROM_WR轉換模塊請求讀數據
      end
   end                 
//-----------------------------------------寫操作-----------------------------
initial 
  begin
    $display("writing-----writing-----writing-----writing");
    # (2*`timeslice1);
    for(i=0;i<=`CheckByteNum-1;i=i+1)
      begin
       ADDR = addr_mem[i];              //輸出寫操作的地址   
       data_to_eeprom = data_mem[i];    //輸出需要轉換的平行數據
       $fdisplay(OUTFILE,"@%0h  %0h",ADDR, data_to_eeprom);
        //把輸出的地址和數據記錄在已經打開的eeprom.dat文件中
       @(posedge ACK) ;    //EEPROM_WR轉換模塊請求寫數據        
     end
 end   

//----------------------------------------讀操作----------------------------
initial
  @(posedge W_R)
   begin
    ADDR = addr_mem[0];
    $fclose (OUTFILE);    //關閉已經打開的eeprom.dat文件
    $readmemh("./eeprom.dat",ROM);  //把數據文件的數據讀到ROM中

    $display("Begin READING-----READING-----READING-----READING");
     for(j = 0; j <=`CheckByteNum; j = j+1)   // 檢查的寫到eeprom中的字節是否正確，先檢查15個字節     
     begin
        ADDR = addr_mem[j]; 
        if (j<=15)    
         begin     
            @(posedge ACK);
               if(DATA == ROM[ADDR]) //比較并顯示發送的數據和接收到的數據是否一致
              $display("DATA %0h == ROM[%0h]---READ RIGHT",DATA,ADDR);
            else
                $display("DATA %0h != ROM[%0h]---READ WRONG",DATA,ADDR);  
         end
        else
          $display ("All the bytes written in eeprom have been checked!!");     
             
     end
     $stop;
     
  end   

initial
  begin
   OUTFILE = $fopen("./eeprom.dat");  // 打開一個名為eeprom.dat的文件備用
   $readmemh("./addr.dat",addr_mem);  // 把地址數據存入地址存儲器
   $readmemh("./data.dat",data_mem);  // 把準備寫入EEPROM的數據存入數據存儲器
end

endmodule