<!--#include file = "Startup.asp"-->

<%

' ======================
' 功能：刪除新聞
' 描述：新聞刪除后，頁面轉向新聞列表頁。
'       刪除新聞的同時，刪除此新聞相關的上傳文件。
' ======================

Call Header("刪除新聞")
Call Content()
Call Footer()


' 本頁內容區
Sub Content()

	' 取參數：新聞ID
	Dim sNewsID
	sNewsID = Trim(Request("id"))

	' 新聞ID有效性驗證，防止有些人惡意的破壞此演示程序
	If IsNumeric(sNewsID) = False Then
		GoError "請通過頁面上的鏈接進行操作，不要試圖破壞此演示系統。"
	End If

	' 從新聞數據表中取出相關的上傳文件
	' 上傳后保存到本地服務器的路徑文件名，多個以"|"分隔
	' 刪除文件，要取帶路徑的文件名才可以，并且只要這個就可以了，原來存的原文件名或不帶路徑的保存文件名可用于其它地方使用
	Dim sSavePathFileName
	
	sSql = "SELECT D_SavePathFileName FROM NewsData WHERE D_ID=" & sNewsID
	oRs.Open sSql, oConn, 0, 1
	If Not oRs.Eof Then
		sSavePathFileName = oRs("D_SavePathFileName")
	Else
		GoError "無效的新聞ID，請點頁面上的鏈接進行操作！"
	End If
	oRs.Close

	' 把帶"|"的字符串轉為數組
	Dim aSavePathFileName
	aSavePathFileName = Split(sSavePathFileName, "|")

	' 刪除新聞相關的文件，從文件夾中
	Dim i
	For i = 0 To UBound(aSavePathFileName)
		' 按路徑文件名刪除文件
		Call DoDelFile(aSavePathFileName(i))
	Next

	' 刪除新聞
	sSql = "DELETE FROM NewsData WHERE D_ID=" & sNewsID
	oConn.Execute sSql

	' 3秒轉向新聞列表頁
	response.write "<p align=center>新聞刪除成功，3秒后自動返回新聞列表頁！<script>window.setTimeout(""location.href='list.asp'"",3000);</script></p>"

End Sub

' 刪除指定的文件
Sub DoDelFile(sPathFile)
	On Error Resume Next
	Dim oFSO
	Set oFSO = Server.CreateObject("Scripting.FileSystemObject")
	oFSO.DeleteFile(Server.MapPath(sPathFile))
	Set oFSO = Nothing
End Sub

%>