/*****
;FileName: IicSMasU.a51
;Describe: 51 系列模擬I2C 總線主控器驅(qū)動程序
;Date: 2003/11/12
;*****/
$include (IicSMasU.inc)
public _IicTxdRxd
public SlvAddr
public SubAddr
/*******************************************************************************
*
;Name: bit _IicTxdRxd(TxdByte,RxdByte,&IicDataBuf)
;Describe: 發(fā)送數(shù)據(jù)給被控器/接收來自被控器的數(shù)據(jù)
;Input: TxdByte=要發(fā)送數(shù)據(jù)的字節(jié)數(shù)
; RxdByte=要接收數(shù)據(jù)的字節(jié)數(shù)
; IicDataBuf=發(fā)送/接收緩沖區(qū)的首字節(jié)
; (SlvAddr(被控器地址),SubAddr(單元地址))
;Output: C(Retry=1):操作失敗標(biāo)志
; IicDataBuf=接收到的數(shù)據(jù)的首字節(jié)(主接收時有效)
;調(diào)用說明:
; A.現(xiàn)行地址寫: SlvAddr(寫) !!!(帶SubAddr 的器件不能使用該子程序)
; TxdByte=(發(fā)送數(shù)據(jù)字節(jié)數(shù)(SubAddr 為第一個要發(fā)送的數(shù)據(jù)))
; RxdByte=0
; B.指定地址寫: SlvAddr(寫),SubAddr
; TxdByte=(1+發(fā)送數(shù)據(jù)字節(jié)數(shù))
; RxdByte=0
; C.現(xiàn)行地址讀: SlvAddr(讀)

; TxdByte=0
; RxdByte=要接收數(shù)據(jù)的字節(jié)數(shù)
; D.指定地址讀: SlvAddr(讀),SubAddr
; TxdByte=1
; RxdByte=要接收數(shù)據(jù)的字節(jié)數(shù)
;Nesting level: 1
;Change: A,C,R1, R4~R7
;*******************************************************************************
****/
BitSegIicSM SEGMENT BIT overlayable
RSEG BitSegIicSM
Retry: dbit 1 ;指明I2C 最后的數(shù)據(jù)傳送失敗應(yīng)該重復(fù)操作
BITEA: DBIT 1 ;存中斷狀態(tài)
DataSegIicSM SEGMENT DATA overlayable
RSEG DataSegIicSM
SlvAddr: ds 1 ;被控器地址
SubAddr: ds 1 ;單元地址
TxdByte equ r7 ;要發(fā)送數(shù)據(jù)的字節(jié)數(shù)(第一傳遞參數(shù))
RxdByte equ r5 ;要接收數(shù)據(jù)的字節(jié)數(shù)(第二傳遞參數(shù))
WaitXTm macro X ;延時X 個機(jī)器周期
if X=0
exitm
endif
if X=1
nop
endif
if X=2
nop
nop
endif
if X=3
nop
nop
nop
endif
if X>255
error "the number of X is too much"
else
mov r6,#X/2
DJNZ r6,$
endif

endm
CodeSegIicSM SEGMENT CODE
RSEG CodeSegIicSM
_IicTxdRxd:
SETB Retry ;設(shè)置錯誤標(biāo)志位
/*****
;發(fā)送起動條件
;*****/
SendStart:
SETB SDA
SETB SCL
WaitXTm IicDelay
CLR SDA ;產(chǎn)生起始信號
WaitXTm IicDelay
CLR SCL ;結(jié)束起動條件
/*****
;送被控器地址地址,數(shù)據(jù)
;*****/
SendSlaAdr:
MOV A,SlvAddr
CJNE TxdByte,#0,SendSlaAdr1
SETB ACC.0 ;TxdByte=0 時進(jìn)行讀操作
SendSlaAdr1:
SETB C ;檢測應(yīng)答位時釋放SDA 線
CALL XmByte
JC IicErr ;無應(yīng)答出錯
JB ACC.0,ReceiveData ;SlaAdr.0=1 時進(jìn)行讀操作
;寫操作
MOV A,SubAddr
SendData:
SETB C ;檢測應(yīng)答位時釋放SDA 線
CALL XmByte
JC IicErr ;無應(yīng)答出錯
MOV A,@R1
INC R1
DJNZ TxdByte,SendData
DEC R1
MOV A,RxdByte
JNZ SendStart ;RxdByte>0 時進(jìn)行讀操作
JMP SendStop

/*****
;Name: RcvByte
;Describe: 接收1 字節(jié)數(shù)據(jù)(接收8 位,發(fā)送+1 位(非)應(yīng)答位)
;Input: C=1:發(fā)送非應(yīng)答位(通知slave 停止通信)
; C=0:發(fā)送應(yīng)答位(通知slave 繼續(xù)發(fā)送后續(xù)字節(jié))
;Output: A=接收到的數(shù)據(jù), C=(非)應(yīng)答位
;Use: A,R4,C,R6(WaitXTm)
;*****/
RcvByte:
MOV A,#0FFH ;釋放SDA 線允許輸入
/*****
;Name: XmByte
;Describe: 發(fā)送1 字節(jié)數(shù)據(jù)(發(fā)送8 位,接收1 位(非)應(yīng)答位)
;Input: A=待發(fā)送的數(shù)據(jù), C=1(檢測應(yīng)答位時釋放SDA 線)
;Output: C=1:slave 非應(yīng)答(slave 不響應(yīng))
; C=0:slave 應(yīng)答(slave 接收成功)
;Use: A,R4,C,R6(WaitXTm)
;*****/
XmByte:
MOV R4,#9 ;設(shè)置數(shù)據(jù)格式為8 位+1 位(非)應(yīng)答位
RXBit:
RLC A ;左移數(shù)據(jù)
MOV SDA,C ;output data
SETB SCL
MOV C,SDA ;input data
WaitXTm IicDelay
CLR SCL
WaitXTm IicDelay
DJNZ R4,RXBit ;重復(fù)操作直到處理完所有數(shù)據(jù)位
RET
ReceiveData:
MOV A,RxdByte
CJNE A,#2,ReceiveData1 ;RxdByte=1(最后一個字節(jié))時,發(fā)送非應(yīng)答位(C=1)
;否則發(fā)送應(yīng)答位(C=0)
ReceiveData1:
CALL RcvByte
MOV @R1,A
INC R1
DJNZ RxdByte,ReceiveData
/*****
?  
;產(chǎn)生I2C 停止條件程序
;*****/
SendStop:
CLR Retry ;清除錯誤標(biāo)志位
IicErr: ;出錯返回
CLR SDA
SETB SCL
WaitXTm IicDelay
SETB SDA
MOV C,Retry ;RETURN ERROR FLAG(C=Retry)
RET
END

C語言聲明：
extern bit IicTxdRxd(uchar TxdByte,uchar RxdByte, uchar *IicDataBuf);
//函數(shù)定義(程序入口地?
extern data uchar SlvAddr; //被控器從地址
extern data uchar SubAddr; //單元地址子地?

直接調(diào)用即可。