;漢諾塔問題：第1個接到任務的人叫第2個人把n-1只diskes從開始地送到中間地，自己只需要把最下面一只disk放到目的地，再叫第2個人把他
;原來搬到中間的n-1只diskes都搬到目的地。而第2個人則叫第3個人去把n-2只diskes從第2個人的開始地送到從第2個人的中間地，從第2個人
;只需要把最下面一只disk放到自己的目的地，再叫第3個人把他原來搬到第2個人中間地的n-2只diskes都搬到第2個人目的地。如此類推。
DATA     SEGMENT
PANM     DB 'C:\Hanoi.txt',0
COUNT    DW ?
BUF      DB 40955 DUP (' ')
STR      DB 'Welcome To Hanoi!$'
STR0     DB 'input the number of diskes(01~13):$'
ERR      DB 'ERROR!$'
STR1     DB 'The steps to move the diskes(From A to C)have been save to C:\Hanoi.txt$'
DATA     ENDS
STACK    SEGMENT PARA STACK 'STACK'
         DB 10 DUP (?)
STACK    ENDS
CODE     SEGMENT
         ASSUME CS:CODE,SS:STACK,DS:DATA

   START:MOV AX,DATA
         MOV DS,AX

      L1:CALL ENTER1
         LEA DX,STR
         CALL DISP9
         CALL ENTER1

         LEA DX,STR0
         CALL DISP9
         MOV AH,01H
         INT 21H
         SUB AL,30H
         JC ER9                                         ;小于0跳
         CMP AL,9
         JA ER9                                         ;大于9跳
         MOV DL,10
         MUL DL
         MOV CL,AL                                      ;保存十位

         MOV AH,01H
         INT 21H
         SUB AL,30H
         JC ER9
         CMP AL,9
         JA ER9
         ADD CL,AL                                      ;加上個位

         CMP CL,13
         JA ER9                                         ;大于13跳
         CMP CL,0
         JE ER9                                         ;等于0跳
         CALL ENTER1

         LEA DX,STR1
         CALL DISP9
         CALL ENTER1

         MOV BH,41H                                     ;diskes的最開始的起始位置A
         MOV BL,42H                                     ;最開始時沒有東西的中間位置B
         MOV CH,43H                                     ;所有diskes的目標位置C
         LEA SI,BUF
         MOV AX,0H
         CALL Hanoi                                     ;入口參數CL即diskes的數目,和A,B,C
         MOV COUNT,AX

         LEA DX,PANM
         MOV CX,0H
         MOV AH,3CH
         INT 21H                                        ;新建文件
         JC EXT                                         ;失敗就結束
         MOV BX,AX
         MOV AL,02H
         MOV AH,3DH
         INT 21H                                        ;打開文件
         JC EXT                                         ;失敗就結束

         LEA DX,BUF
         MOV AH,40H
         MOV CX,COUNT
         INT 21H                                        ;寫文件
         MOV AH,3EH
         INT 21H                                        ;關閉文件
     EXT:MOV AH,4CH
         INT 21H

     ER9:CALL ENTER1
         CALL ENTER1
         LEA DX,ERR
         MOV AH,09H
         INT 21H                                        ;輸出ERROR
         CALL ENTER1
         JMP L1

Hanoi    PROC                                           ;入口參數CL即diskes的數目,和BH(起始),BL(中間),CH(目的)，AX（記錄個數）、BX、CX不受子程序保護
         CMP CL,1                                       ;判斷是否被分配到一只disk
         JE DISP                                        ;不是就把n只disk從它的現在的起始位移到現在的目的地
         DEC CL
         PUSH BX
         PUSH CX
         XCHG BL,CH                                     ;分配下一個人的任務(指派其開始為BH、中間為CH、目的BL),故交換CL與BL
         CALL Hanoi                                     ;命令下一個人完成n-1只diskes從開始,借助目的,放到中間

         POP CX
         POP BX
         CALL DISP1                                     ;自己就只把最下面的disk放到現在的目的地

         XCHG BH,BL                                     ;分配下一個人的任務(指派其開始為BL、中間為BH、目的CH),故交換BH與BL
         CALL Hanoi                                     ;命令下一個人完成n-1只diskes從中間,借助開始,放到目的
         RET

    DISP:CALL DISP1                                     ;最后被分配一只disk的人把disk直接放到目的地
         RET
Hanoi    ENDP
DISP1    PROC                                           ;保存該人把一只disk從起始地送到目的地的路徑到BUF,AX記錄字符個數，SI不受子程序保護
         MOV [SI],BH
         INC SI
         MOV BYTE PTR [SI],2DH
         INC SI
         MOV BYTE PTR [SI],3EH
         INC SI
         MOV [SI],CH
         INC SI
         MOV BYTE PTR [SI],20H
         INC SI
         ADD AX,5
         RET
DISP1    ENDP
ENTER1   PROC                                            ;回車換行
         PUSH DX
         PUSH AX
         MOV DL,0DH
         MOV AH,02H
         INT 21H
         MOV DL,0AH
         MOV AH,02H
         INT 21H
         POP AX
         POP DX
         RET
ENTER1   ENDP
DISP9    PROC                                            ;9號功能
         PUSH AX
         MOV AH,09H
         INT 21H
         POP AX
         RET
DISP9    ENDP
CODE     ENDS
         END START