;                    SMC1601接口程序（MCS51總線方式）
;***************************************************************************
;*  Title : Accessing to LCD-CONTROLLER                                    *
;*  Date :  2000.4.27                                                      *
;*  Support telephone:  0731-4167806,4167808(CHANGSHA SUNMAN)              *
;*  Support fax :0731-4167807  Support E-mail:sunman@public.cs.hn.cn       *
;*  Create by :褚建軍(chujianjun),朱長(zhǎng)春(zhuchangchun)                     *
;*  DESCRIPTION:This subroutine shows how to write data to LCD-CONTROLLER  *
;***************************************************************************
;連線圖: *LCM---8031* *LCM---8031* *LCM------------8031*
;        *DB0---P0.0* *DB4---P0.4* *RS-------------P2.0*
;        *DB1---P0.1* *DB5---P0.5* *RW-------------P2.1*
;        *DB2---P0.2* *DB6---P0.6* *E--NAND GATE---P2.7*  （參見(jiàn)說(shuō)明書(shū)）
;        *DB3---P0.3* *DB7---P0.7* *VLCD接10K可調(diào)電阻到GND*
;注:8031的晶振頻率為12MHz
;**************************************************************************
RSADDR  EQU     0100H
RWADDR  EQU     0200H
CSADDR  EQU     8000H
XPOS    EQU     20H        ;列方向地址指針（用于LCDPOS子程序）

        ORG     0000H
        JMP     START
START:  MOV     SP,#60H
MAIN:
        MOV     R7,#'0'    ;測(cè)試主程序
MN_PA:                     ;整屏循環(huán)顯示"0"到"9"及空格
        CALL    LCDRESET
        MOV     A,R7
        CALL    LCDFILL
        CALL    DELAY400MS
        INC     R7
        MOV     A,R7
        CJNE    A,#'9'+1,MN_PA
        MOV     A,#' '
        CALL    LCDFILL
        CALL    DELAY400MS
        JMP     MAIN
LCDFILL:       
        MOV     B,A
        MOV     XPOS,#0    ;整屏顯示A中所代表字符
LFL_PA: MOV     A,B
        CALL    LCDWRITE
        INC     XPOS
        MOV     A,XPOS
        CJNE    A,#16,LFL_PA
        RET

LCDPOS:                        ;設(shè)置第XPOS個(gè)字符的DDRAM地址
        PUSH    ACC
        ANL     XPOS,#0FH      ;X位置范圍(0到15)
        MOV     A,XPOS         ;XPOS對(duì)應(yīng)DDRAM地址
        JNB     ACC.3,LPS_LAX  ;(前8個(gè)字符)X: 第0-----7個(gè)字符
        ANL     A,#07H         ;       DDRAM:   0-----7(十六進(jìn)制)
        ADD     A,#40H         ;(后8個(gè)字符)X: 第8----15個(gè)字符
;                              ;       DDRAM:   40---47(十六進(jìn)制)
LPS_LAX:ORL     A,#80H         ;設(shè)置DDRAM地址
        CALL    LCDWC
        POP     ACC
        RET

LCDWRITE:                      ;定位寫(xiě)字符子程序
        CALL    LCDPOS         ;定位顯示地址
        CALL    LCDWD          ;寫(xiě)字符
        RET

LCDRESET:                       ;初始化程序
        CALL    DELAY5MS        ;延時(shí)15MS
        CALL    DELAY5MS
        CALL    DELAY5MS
        MOV     A,#38H          ;顯示模式設(shè)置(不檢測(cè)忙信號(hào))
        CALL    LCDWCN          ;共三次
        CALL    DELAY5MS
        MOV     A,#38H
        CALL    LCDWCN
        CALL    DELAY5MS
        MOV     A,#38H               
        CALL    LCDWCN

        MOV     A,#38H          ;顯示模式設(shè)置(以后均檢測(cè)忙信號(hào))
        CALL    LCDWC
        MOV     A,#08H          ;顯示關(guān)閉
        CALL    LCDWC
        MOV     A,#01H          ;顯示清屏
        CALL    LCDWC
        MOV     A,#06H          ;顯示光標(biāo)移動(dòng)設(shè)置
        CALL    LCDWC
        MOV     A,#0CH          ;顯示開(kāi)及光標(biāo)設(shè)置
        CALL    LCDWC
        RET
LCDWC:                          ;送控制字子程序(檢測(cè)忙信號(hào))
        CALL    WAITIDLE
LCDWCN:                         ;送控制字子程序(不檢測(cè)忙信號(hào))
        MOV     DPTR,#CSADDR    ;CS=1 RS=0 RW=0
        MOVX    @DPTR,A
        RET
LCDWD:                              ;寫(xiě)字符子程序
        CALL    WAITIDLE
        MOV     DPTR,#CSADDR+RSADDR ;CS=1 RS=1 RW=0
        MOVX    @DPTR,A
        RET
WAITIDLE:
        PUSH    ACC                 ;正常讀寫(xiě)操作之前必須檢測(cè)LCD控制器狀態(tài)
        MOV     DPTR,#CSADDR+RWADDR ;CS=1 RS=0 RW=1
WTD_PA: MOVX    A,@DPTR             ;DB7:    0  LCD控制器空閑
        JB      ACC.7,WTD_PA        ;        1  LCD控制器忙
        POP     ACC
        RET
DELAY5MS:
        MOV     R1,#25              ;延時(shí)子程序(5MS)
DL5_PA: MOV     R2,#100
        DJNZ    R2,$
        DJNZ    R1,DL5_PA
        RET
DELAY400MS:
        MOV     R0,#20              ;延時(shí)子程序(400MS)
DL4_PA: MOV     R1,#100
DL4_PB: MOV     R2,#100
        DJNZ    R2,$
        DJNZ    R1,DL4_PB
        DJNZ    R0,DL4_PA
        RET
        END