;********************MCOBCDSHR********************
;本程序實現多字節壓縮BCD碼非循環右移1位(即除以10)。
;入口參數: 原數據地址在SADR中,字節數在CNT中。
;出口參數: 結果首地址在SADR中,字節數在CNT中,移出位在SOU的低四位。
;占用資源: W,STATUS,FSR,020H,023H,024H,兩重堆棧。
;說    明: 1.原數據將被沖掉.
;          2.加載本文件的同時也加載了另外一個文件"MSHR.ASM",
;            故用戶在使用這個子程序時可直接調用,不必重新加載.

           IFNDEF       MCOBCDSHR1
            #DEFINE     MCOBCDSHR1

MCOBCDSHR   DECF        CNT,W
            ADDWF       SADR,W      
            MOVWF       FSR         ;末地址
            MOVWF       SADR
NEXT14      MOVLW       0FH
            ANDWF       INDF,W
            SWAPF       SOU,F
            IORWF       SOU,F
            MOVLW       0F0H
            ANDWF       INDF,F
            ANDWF       SOU,W
            SWAPF       INDF,F
            IORWF       INDF,F
            MOVLW       0FH
            ANDWF       SOU,F       ;SOU低4位:INDF右移1位
            DECF        FSR,F
            DECFSZ      CNT,F
            GOTO        NEXT14
            MOVF        FSR,W
            SUBWF       SADR,W
            MOVWF       CNT         ;結果字節數
            SUBWF       SADR,F
            INCF        SADR,F      ;結果首地址
            RETURN
           ENDIF