;********************MUBCDNEG********************
;本程序實現多字節非壓縮BCD碼求補。
;入口參數：待處理的數據地址在SADR中,字節數在CNT中。
;出口參數：結果地址在SADR中,字節數在CNT中.
;占用資源：W,FSR,STATUS,020H,023H,028H,一重堆棧。
;說    明: 0求補還是0.

           IFNDEF       MUBCDNEG1
            #DEFINE     MUBCDNEG1

MUBCDNEG    MOVF        CNT,W
            MOVWF       TEMP1       ;TEMP1作計數器
            MOVF        SADR,W
            MOVWF       FSR
            MOVF        INDF,W
            SUBLW       0AH         ;用10減最低位
            MOVWF       INDF
            INCF        FSR,F
            DECF        TEMP1,F
LOOP15      MOVF        INDF,W
            SUBLW       9           ;用9減其它位
            MOVWF       INDF
            INCF        FSR,F
            DECFSZ      TEMP1,F
            GOTO        LOOP15
            MOVF        CNT,W
            MOVWF       TEMP1       ;重新獲得字節數
            SUBWF       FSR,F       ;重新獲得首地址
LOOP16      MOVLW       6           ;十進制調整
            ADDWF       INDF,W
            BTFSS       STATUS,DC
            RETURN
            CLRF        INDF
            INCF        FSR,F
            INCF        INDF,F
            DECFSZ      TEMP1,F
            GOTO        LOOP16
            DECF        INDF,F
            RETURN
           ENDIF