;=================== 硬件實驗九  A/D轉換實驗 ========================
        ORG 000H
		LJMP MAIN

		ORG 05A0H
MAIN:
SE11:   MOV SP,#53H
        MOV 7EH,#00H
        MOV 7DH,#08H
        MOV 7CH,#00H
        MOV 7BH,#09H
        MOV 7AH,#10H
        MOV 79H,#10H            ;顯示緩沖區初值
LO18:   CALL DIS	            ;顯示
        MOV A,#00H
        MOV DPTR,#0FFE0H
        MOVX @DPTR,A            ;0809的0通道采樣
        CALL DIS	;SSEE
        MOVX A,@DPTR            ;取出采樣值
        mov dptr,#0ffe4h        ;new add --> 138 Y1
        cpl a                   ;new add
        movx @dptr,a            ;new add --> 驅動發光二極管
        cpl a                   ;new add
        MOV R0,#79H
        CALL PTDS               ;采樣值送顯示緩沖區
        SJMP LO18               ;循環
;---------------------------
PTDS:   MOV R1,A                ;拆送顯示緩沖區
        ACALL PTDS1
        MOV A,R1
        SWAP A
PTDS1:  ANL A,#0FH
        MOV @R0,A
        INC R0
        RET
;---------------------------
DIS:    PUSH DPH
        PUSH DPL
        SETB RS1
        MOV R0,#7EH
        MOV R2,#20H
        MOV R3,#00H
        MOV DPTR,#LS0
LS2:    MOV A,@R0
        MOVC A,@A+DPTR
        MOV R1,#0DCH
        MOVX @R1,A
        MOV A,R2
        INC R1
        MOVX @R1,A
LS1:    DJNZ R3,LS1
        CLR C
        RRC A
        MOV R2,A
        DEC R0
        JNZ LS2
        movx @r0,a
	    dec r0
	    cpl a
	    movx @r0,a
        CLR RS1
        POP DPL
        POP DPH
        RET
;-------------------------------------
LS0:    DB 0C0H,0F9H,0A4H,0B0H,99H,92H
        DB 82H,0F8H,80H,90H,88H,83H,0C6H
        DB 0A1H,86H,8EH,0FFH,0CH,89H,7FH,0BFH
;--------------------------------------
        END