;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;	Current Version -- Ver 0.02 (2005.04)
;	CopyRight By Pmason_rose@msn.com
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DEBUG		equ		0
;		_Debug		"插入顯示字符串"
;		_Debug		"顯示寄存器或 double word 變量","edi 的值",edi
;		_Debug		"顯示兩個寄存器或 double word 變量","szTestByte 地址",offset szTestByte,"szTestText 地址",offset szTestText
;		_DebugString	"顯示內存中的字符串",addr szTestText
;		_DebugMemory	"顯示指定的內存內容",addr szTestByte,sizeof szTestByte
;Debug程序作者:羅云彬
;GIF顯示庫由aogo改編
;各個文件智力成果屬于各個文件作者
.386
.model flat, stdcall  ;32 bit memory model
option casemap :none  ;case sensitive

include	equ.inc
include jsyks.inc
include TabMain.asm

.code
start:

	invoke	GetModuleHandle,NULL
	mov		hInstance,eax
	invoke	InitGIFLib,hInstance,0	;初始化gif庫
    invoke	InitCommonControls
	invoke	DialogBoxParam,hInstance,LOGIN_DIALOG,NULL,addr DlgProc,NULL
	invoke	ExitProcess,0

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 登陸對話框過程
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DlgProc proc hWin:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM

	mov		eax,uMsg
	.if eax==WM_INITDIALOG
		push	hWin
		pop		hLOGIN_DIALOG
	.elseif eax==WM_COMMAND
		mov	eax,wParam
		.if		ax ==	IDC_EDITTEXT_PASSWD
			invoke	GetDlgItemText,hWin,IDC_EDITTEXT_PASSWD,addr szBuffer_Passwd,sizeof szBuffer_Passwd
		.elseif	ax ==	IDC_PUSHBUTTON_LOGIN
			invoke	My_Proc,hWin
;			invoke	My_Quit,hWin
		.elseif	ax ==	IDC_PUSHBUTTON_CANCEL
			invoke	My_Quit,hWin
		.endif
	.elseif eax==WM_CLOSE
			invoke	My_Quit,hWin
	.else
		mov		eax,FALSE
		ret
	.endif
	mov		eax,TRUE
	ret

DlgProc endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 初始化代碼
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
My_Proc		proc	hWin:HWND
		local	@dwItem
		invoke ODBCConnect,hWin
;;接下來,程序將獲得一個語句句柄.
		invoke SQLAllocHandle, SQL_HANDLE_STMT, hConn, addr hStmt
		.if ax==SQL_SUCCESS || ax==SQL_SUCCESS_WITH_INFO
			invoke lstrcpy, addr Conn, addr SQLStatement
			invoke lstrcat, addr Conn, addr WhereStatement
			invoke SQLBindParameter,hStmt, 1, SQL_PARAM_INPUT, SQL_C_CHAR, SQL_CHAR,25,0, addr SearchName,25,addr StrLenX
			invoke SQLPrepare, hStmt, addr Conn, sizeof Conn
		.else
			invoke MessageBox,hWin,addr AllocStmtFail, addr AppName, MB_OK+MB_ICONERROR
			invoke EndDialog, hWin,0
		.endif	
		
		invoke GetDlgItemText, hWin, IDC_EDITTEXT_USERNAME, addr SearchName, 25
		.if ax==0
			invoke MessageBox, hWin,addr NoData, addr AppName, MB_OK+MB_ICONERROR
			invoke GetDlgItem, hWin, IDC_EDITTEXT_USERNAME
			invoke SetFocus, eax
		.else
			invoke lstrlen,addr SearchName
			mov		StrLenX,eax
			invoke SQLExecute, hStmt
			invoke SQLBindCol, hStmt,1,SQL_C_CHAR, addr ThePasswd, sizeof ThePasswd,addr PasswdLength
			mov	@dwItem,0
			and	dwFlag,not	ID_LOGIN_ACEPT	;以后仔細測試此標志
			.while	TRUE
				invoke SQLFetch, hStmt
				.if	ax == SQL_SUCCESS || ax == SQL_SUCCESS_WITH_INFO
;綁定后返回的數據在   ThePasswd   的內存里
;比較字符串(區分大小寫)，用在搜索字符串,十六進制數據列,整數
					invoke	My_cmpstri,addr ThePasswd,addr szBuffer_Passwd,sizeof ThePasswd
					.if		eax
						or	dwFlag,ID_LOGIN_ACEPT	;用戶名和密碼正確則設置允許登錄標志
					.else
;;用戶名和密碼不正確則
					.endif
						inc	@dwItem
				.else
					.break
				.endif
			.endw
			test	dwFlag,ID_LOGIN_ACEPT
			.if	ZERO?
				invoke MessageBox,hWin,addr szErr_LOGIN,addr szNull,MB_OK
			.else
				invoke EndDialog,hWin,NULL
				invoke DialogBoxParam,hInstance,IDD_TABMAIN,NULL,addr DlgMainProc,NULL
			.endif
		.endif
	ret

My_Proc		endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 退出程序 -- 保存數據
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
My_Quit		proc	hWin:HWND
	invoke SQLFreeHandle, SQL_HANDLE_STMT, hStmt
	invoke ODBCDisconnect,hWin
	invoke EndDialog,hWin,0
	ret

My_Quit		endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 連接數據庫
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
ODBCConnect proc hWin:DWORD
	invoke SQLAllocHandle, SQL_HANDLE_ENV, SQL_NULL_HANDLE, addr hEnv
;	調用SQLAllocHandle來分配一個環境句柄
	.if ax==SQL_SUCCESS || ax==SQL_SUCCESS_WITH_INFO
;   獲得環境句柄后,程序調用SQLSetEnvAttr來表示將要使用ODBC 3.x的語法.
		invoke SQLSetEnvAttr, hEnv,SQL_ATTR_ODBC_VERSION, SQL_OV_ODBC3,0
		.if ax==SQL_SUCCESS || ax==SQL_SUCCESS_WITH_INFO
;   程序將通過調用SQLAllocHandle獲得連接句柄來實現連接
			invoke SQLAllocHandle, SQL_HANDLE_DBC, hEnv, addr hConn
			.if ax==SQL_SUCCESS || ax==SQL_SUCCESS_WITH_INFO
				invoke lstrcpy,addr ConnectString,addr strConnect
				invoke lstrcat,addr ConnectString, addr ProgPath
				invoke lstrcat, addr ConnectString,addr DBName
;;  接著填寫連接字符串.完整的連接字符串將被用在ConnectionString
;>當連接字符串完成,程序將調用SQLDriverConnect來通過MS Access ODBC 驅動程序連接
				invoke SQLSetConnectAttr,hConn,SQL_ATTR_ODBC_CURSORS,SQL_CUR_USE_ODBC,0
				invoke SQLDriverConnect, hConn, hWin, addr ConnectString, sizeof ConnectString, \
						addr Conn, sizeof Conn,addr StrLenX, SQL_DRIVER_COMPLETE
				.if ax==SQL_SUCCESS || ax==SQL_SUCCESS_WITH_INFO
;;現在,到數據庫的連接已經建立并被打開,并一直保持打開狀態直到用戶選擇關閉
;					invoke MessageBox,hWin, addr Conn,addr ConnectCaption,MB_OK+MB_ICONINFORMATION
				.else
					invoke SQLFreeHandle, SQL_HANDLE_DBC, hConn
					invoke SQLFreeHandle, SQL_HANDLE_ENV, hEnv
					invoke MessageBox, hWin, addr ConnFail, addr AppName, MB_OK+MB_ICONERROR
				.endif
			.else
				invoke SQLFreeHandle, SQL_HANDLE_ENV, hEnv
				invoke MessageBox, hWin, addr AllocConnFail, addr AppName, MB_OK+MB_ICONERROR
			.endif
		.else
			invoke SQLFreeHandle, SQL_HANDLE_ENV, hEnv
			invoke MessageBox, hWin, addr SetAttrFail, addr AppName, MB_OK+MB_ICONERROR
		.endif
	.else
		invoke MessageBox, hWin, addr AllocEnvFail, addr AppName, MB_OK+MB_ICONERROR	
	.endif
	ret
ODBCConnect endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 斷開數據庫
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
ODBCDisconnect proc hWin:DWORD
	invoke SQLDisconnect, hConn
	invoke SQLFreeHandle, SQL_HANDLE_DBC, hConn
	invoke SQLFreeHandle, SQL_HANDLE_ENV, hEnv
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
	invoke MessageBox,hWin,addr Disconnect, addr AppName,MB_OK+MB_ICONINFORMATION
	ret
ODBCDisconnect endp

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;------------------------------------------------------
;比較字符串(區分大小寫)，用在搜索字符串,十六進制數據列,整數
;相等返回true,否則返回false
My_cmpstr proc uses esi edi ecx lpSrc,lpDest,nLen
	xor eax,eax
	mov esi,lpSrc
	mov edi,lpDest
	mov ecx,nLen
	repz cmpsb
	.if zero?
		inc eax;mov eax,true
	.endif
	ret
My_cmpstr endp
;比較字符串(不分大小寫)，用在搜索不分大小的字符串
;相等返回true,否則返回false
My_cmpstri proc uses esi edi ebx ecx lpSrc,lpDest,nLen
	xor eax,eax
	mov esi,lpSrc
	mov edi,lpDest
	mov ecx,nLen
_cmpnext_:
	mov ah,[esi]
	mov al,[edi]
	inc esi
	inc edi
	mov bh,ah
	sub bh,al
	.if zero?
		loop _cmpnext_
	.elseif bh=='a'-'A' || bh=='A'-'a'
		.if ((ah>='a' && ah<='z') || (ah>='A' && ah<='Z')) && \
					((al>='a' && al<='z') || (al>='A' && al<='Z'))
			loop _cmpnext_
		.endif
	.endif
	xor eax,eax
	.if ecx==0
		inc eax;mov eax,true
	.endif
	ret
My_cmpstri endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
end start