VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CgPod"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'QQ:75347626
'MSN:whailin2000@hotmail.com
Option Explicit

Dim m_CgPodh As CgPodh
Dim m_Hwbm As Hwbm

Dim m_CgPod_CgPodhno As Double
Dim m_CgPod_HwBmCode As String
Dim m_CgPod_HwBmno As Double

Dim m_CgPodQty As Double
Dim m_CgPodPrice As Double
Dim m_CgPodAmt As Double
Dim m_CgPodIQty As Double

Dim m_CgPodDDat As String
Dim m_CgPodBz As String

Dim m_CgPodSysDat As String
Dim m_CgPodSysTime As String
Dim m_CgPodNo As Double

Dim m_CgPodId As Integer
Dim m_CgPodKey As Double

Private Sub Class_Initialize()
   m_CgPodId = -1
End Sub

Public Property Get Name() As String
   Name = "CgPod"
End Property

Public Property Get CgPodId() As Integer
   CgPodId = m_CgPodId
End Property

Public Property Get CgPodKey() As Double
   CgPodKey = m_CgPodKey
End Property

Public Property Get CgPodh() As CgPodh
   If m_CgPodh Is Nothing Then
      Set m_CgPodh = New CgPodh
      m_CgPodh.Requery "", m_CgPod_CgPodhno
   End If
   Set CgPodh = m_CgPodh
End Property

Public Property Get Hwbm() As Hwbm
   If m_Hwbm Is Nothing Then
      Set m_Hwbm = New Hwbm
      m_Hwbm.Requery "", m_CgPod_HwBmno
   End If
   Set Hwbm = m_Hwbm
End Property

Public Property Get CgPod_CgPodhno() As Double
   CgPod_CgPodhno = m_CgPod_CgPodhno
End Property

Public Property Get CgPod_HwBmno() As Double
   CgPod_HwBmno = m_CgPod_HwBmno
End Property

Public Property Get CgPodQty() As Double
   CgPodQty = m_CgPodQty
End Property

Public Property Get CgPodPrice() As Double
   CgPodPrice = m_CgPodPrice
End Property

Public Property Get CgPodAmt() As Double
   CgPodAmt = m_CgPodAmt
End Property

Public Property Get CgPodIQty() As Double
   CgPodIQty = m_CgPodIQty
End Property

Public Property Get CgPodDDat() As String
   CgPodDDat = m_CgPodDDat
End Property

Public Property Get CgPodBz() As String
   CgPodBz = m_CgPodBz
End Property

Public Property Get CgPodSysDat() As String
   CgPodSysDat = m_CgPodSysDat
End Property

Public Property Get CgPodSysTime() As String
   CgPodSysTime = m_CgPodSysTime
End Property

Public Property Get CgPodNo() As Double
   CgPodNo = m_CgPodNo
End Property

Public Property Let CgPodId(vCgPodId As Integer)
   m_CgPodId = vCgPodId
End Property

Public Property Let CgPodKey(vCgPodKey As Double)
   m_CgPodKey = vCgPodKey
End Property

Public Property Set CgPodh(vCgPodh As CgPodh)
   Set m_CgPodh = vCgPodh
End Property

Public Property Let CgPod_HwBmCode(vCgPod_HwBmCode As String)
   If Trim(vCgPod_HwBmCode) = "" Then
      Err.Raise vbObjectError + 1, , "貨物編碼不能為空！"
      Exit Property
   End If
   If m_CgPod_HwBmCode <> vCgPod_HwBmCode Then
      Dim Rs As ADODB.Recordset
      Set Rs = Conn.Execute("SELECT HWBMNO FROM HWBMREC WHERE HWBMCODE='" & vCgPod_HwBmCode & "'")
      If Rs.EOF Then
         Rs.Close
         Set Rs = Nothing
         Err.Raise vbObjectError + 1, , "錄入的貨物編碼不存在！"
         Exit Property
      End If
      m_CgPod_HwBmno = Rs!HwBmNo
      Rs.Close
      Set Rs = Nothing
   End If
   m_CgPod_HwBmCode = vCgPod_HwBmCode
End Property

Public Property Let CgPodQty(vCgPodQty As Double)
   If vCgPodQty <= 0 Then
      Err.Raise vbObjectError + 1, , "訂單數量必須大于零！"
      Exit Property
   End If
   m_CgPodQty = vCgPodQty
   m_CgPodAmt = vCgPodQty * m_CgPodPrice
End Property

Public Property Let CgPodPrice(vCgPodPrice As Double)
   If vCgPodPrice < 0 Then
      Err.Raise vbObjectError + 1, , "訂單單價不能小于零！"
      Exit Property
   End If
   m_CgPodPrice = vCgPodPrice
   m_CgPodAmt = vCgPodPrice * m_CgPodQty
End Property

Public Property Let CgPodDDat(vCgPodDDat As String)
   m_CgPodDDat = vCgPodDDat
End Property

Public Property Let CgPodBz(vCgPodDBz As String)
   m_CgPodBz = vCgPodDBz
End Property

Public Sub Save()
On Error GoTo Errorhandle
      
   If m_CgPodId = -1 Then
      Cmd.CommandText = "{CALL CgPodREC_INSERT(?,?,?,?,?,?,?,?,?,?)}"
      Cmd(0) = m_CgPodh.CgPodhNo
      Cmd(1) = m_CgPod_HwBmno
      Cmd(2) = m_CgPodQty
      Cmd(3) = m_CgPodPrice
      Cmd(4) = m_CgPodAmt
      Cmd(5) = m_CgPodDDat
      Cmd(6) = m_CgPodBz
      Cmd(7).Direction = adParamOutput 'CgPodSysDate
      Cmd(8).Direction = adParamOutput 'CgPodSysTime
      Cmd(9).Direction = adParamOutput 'CgPodNo
   Else
      Cmd.CommandText = "{CALL CgPodREC_UPDATE(?,?,?,?,?,?,?)}"
      Cmd(0) = m_CgPodNo
      Cmd(1) = m_CgPod_HwBmno
      Cmd(2) = m_CgPodQty
      Cmd(3) = m_CgPodPrice
      Cmd(4) = m_CgPodAmt
      Cmd(5) = m_CgPodDDat
      Cmd(6) = m_CgPodBz
   End If
   
   Cmd.Execute
   
   If m_CgPodId = -1 Then
      m_CgPodSysDat = Cmd(7)
      m_CgPodSysTime = Cmd(8)
      m_CgPodNo = Cmd(9)
      m_CgPodId = 1
   End If
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Sub Del()
On Error GoTo Errorhandle
      
   Cmd.CommandText = "{CALL CgPodREC_DELETE(?)}"
   Cmd(0) = m_CgPodNo
   
   Conn.BeginTrans
   Cmd.Execute
   If CgPodh.CgPods.Count = 1 Then
      CgPodh.Del
   End If
   Conn.CommitTrans
   
Exit Sub
Errorhandle:
   Conn.RollbackTrans
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Function Requery(vCgPodNo As Double) As Integer
   Dim mRs As ADODB.Recordset
On Error GoTo Errorhandle
   Requery = -1
   Set mRs = Conn.Execute("SELECT CgPod_CgPodHNO,CgPod_HWBMCODE=HWBMCODE,CgPod_HWBMNO,CgPodQTY,CgPodPRICE,CgPodAMT,CgPodIQty,CgPodDDAT,CgPodBZ,CgPodSYSDAT,CgPodSYSTIME,CgPodNO FROM CgPodREC,HWBMREC WHERE CgPodNO=" & CStr(vCgPodNo) & " AND HWBMNO=CgPod_HWBMNO")
   If Not mRs.EOF Then
      BatchLet mRs!CgPod_CgPodhno, mRs!CgPod_HwBmCode, mRs!CgPod_HwBmno, mRs!CgPodQty, mRs!CgPodPrice, mRs!CgPodAmt, mRs!CgPodIQty, mRs!CgPodDDat, mRs!CgPodBz, mRs!CgPodSysDat, mRs!CgPodSysTime, mRs!CgPodNo
   End If
   Set mRs = Nothing
Exit Function
Errorhandle:
   Set mRs = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Function

Public Sub BatchLet(ParamArray Properties() As Variant)
   
   m_CgPod_CgPodhno = Properties(0)
   m_CgPod_HwBmCode = Properties(1)
   m_CgPod_HwBmno = Properties(2)
   m_CgPodQty = Properties(3)
   m_CgPodPrice = Properties(4)
   m_CgPodAmt = Properties(5)
   m_CgPodIQty = Properties(6)
   m_CgPodDDat = Properties(7)
   m_CgPodBz = Properties(8)
   m_CgPodSysDat = Properties(9)
   m_CgPodSysTime = Properties(10)
   m_CgPodNo = Properties(11)

   m_CgPodId = 1

End Sub