ＭＣＳ－５１浮點(diǎn)運(yùn)算子程序庫(kù)及其使用說(shuō)明
  
    
    １．雙字節(jié)定點(diǎn)操作數(shù)：用[R0]或[R1]來(lái)表示存放在由R0或R1指示的連續(xù)單元中的數(shù)
據(jù)，地址小的單元存放高字節(jié)。如果[R0]=1234H，若(R0)=30H，則(30H)=12H，(31H)=34H。
    ２．二進(jìn)制浮點(diǎn)操作數(shù)：用三個(gè)字節(jié)表示，第一個(gè)字節(jié)的最高位為數(shù)符，其余七位為
階碼（補(bǔ)碼形式），第二字節(jié)為尾數(shù)的高字節(jié)，第三字節(jié)為尾數(shù)的低字節(jié)，尾數(shù)用雙字節(jié)
純小數(shù)（原碼）來(lái)表示。當(dāng)尾數(shù)的最高位為１時(shí)，便稱(chēng)為規(guī)格化浮點(diǎn)數(shù)，簡(jiǎn)稱(chēng)操作數(shù)。在

程序說(shuō)明中，也用[R0]或[R1]來(lái)表示R0或R1指示的浮點(diǎn)操作數(shù)，例如：當(dāng)[R0]=-6.000時(shí)，
則二進(jìn)制浮點(diǎn)數(shù)表示為83C000H。若(R0)=30H，則(30H)=83H,(31H)=0C0H,(32H)=00H。
    ３．十進(jìn)制浮點(diǎn)操作數(shù)：用三個(gè)字節(jié)表示，第一個(gè)字節(jié)的最高位為數(shù)符，其余七位為
階碼（二進(jìn)制補(bǔ)碼形式），第二字節(jié)為尾數(shù)的高字節(jié)，第三字節(jié)為尾數(shù)的低字節(jié)，尾數(shù)用
雙字節(jié)ＢＣＤ碼純小數(shù)（原碼）來(lái)表示。當(dāng)十進(jìn)制數(shù)的絕對(duì)值大于１時(shí)，階碼就等于整數(shù)
部分的位數(shù)，如 876.5 的階碼是03H，-876.5 的階碼是 83H；當(dāng)十進(jìn)制數(shù)的絕對(duì)值小于1

時(shí)，階碼就等于 80H 減去小數(shù)點(diǎn)后面零的個(gè)數(shù)，例如 0.00382 的階碼是 7EH，-0.00382
的階碼是 0FEH。在程序說(shuō)明中，用[R0]或[R1]來(lái)表示R0或R1指示的十進(jìn)制浮點(diǎn)操作數(shù)。例
如有一個(gè)十進(jìn)制浮點(diǎn)操作數(shù)存放在30H、31H、32H中，數(shù)值是 -0.07315，即-0.7315乘以10
的-1次方，則(30H)=0FFH，31H=73H，(32H)=15H。若用[R0]來(lái)指向它，則應(yīng)使(R0)=30H。
    ４．運(yùn)算精度：?jiǎn)未味c(diǎn)運(yùn)算精度為結(jié)果最低位的當(dāng)量值；單次二進(jìn)制浮點(diǎn)算術(shù)運(yùn)算
的精度優(yōu)于十萬(wàn)分之三；單次二進(jìn)制浮點(diǎn)超越函數(shù)運(yùn)算的精度優(yōu)于萬(wàn)分之一；ＢＣＤ碼浮

點(diǎn)數(shù)本身的精度比較低（萬(wàn)分之一到千分之一），不宜作為運(yùn)算的操作數(shù)，僅用于輸入或
輸出時(shí)的數(shù)制轉(zhuǎn)換。不管那種數(shù)據(jù)格式，隨著連續(xù)運(yùn)算的次數(shù)增加，精度都會(huì)下降。
    ５．工作區(qū)：數(shù)據(jù)工作區(qū)固定在A、B、R2～R7，數(shù)符或標(biāo)志工作區(qū)固定在PSW和23H單
元(位1CH～1FH)。在浮點(diǎn)系統(tǒng)中，R2、R3、R4和位1FH為第一工作區(qū)，R5、R6、R7和位1EH
為第二工作區(qū)。用戶(hù)只要不在工作區(qū)中存放無(wú)關(guān)的或非消耗性的信息，程序就具有較好的
透明性。
    ６．子程序調(diào)用范例：由于本程序庫(kù)特別注意了各子程序接口的相容性，很容易采用

積木方式（或流水線方式）完成一個(gè)公式的計(jì)算。以浮點(diǎn)運(yùn)算為例：
    計(jì)算   ｙ = Ｌｎ √ ｜ Ｓｉｎ （ａｂ／ｃ＋ｄ） ｜
    已知：a=-123.4；b=0.7577；c=56.34；d=1.276； 它們分別存放在30H、33H、36H、
39H開(kāi)始的連續(xù)三個(gè)單元中。用ＢＣＤ碼浮點(diǎn)數(shù)表示時(shí)，分別為a=831234H；b=007577H；
c=025634H；d=011276H。
    求解過(guò)程：通過(guò)調(diào)用ＢＴＯＦ子程序，將各變量轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)，再進(jìn)行各
種運(yùn)算，最后調(diào)用ＦＴＯＢ子程序，還原成十進(jìn)制形式，供輸出使用。程序如下：
TEST:	MOV  	R0,#39H   ；指向ＢＣＤ碼浮點(diǎn)操作數(shù)ｄ

LCALL	BTOF      ；將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)
	MOV  	R0,#36H   ；指向ＢＣＤ碼浮點(diǎn)操作數(shù)ｃ
	LCALL	BTOF      ；將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)
	MOV  	R0,#33H   ；指向ＢＣＤ碼浮點(diǎn)操作數(shù)ｂ
	LCALL	BTOF      ；將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)
	MOV  	R0,#30H   ；指向ＢＣＤ碼浮點(diǎn)操作數(shù)ａ
	LCALL	BTOF      ；將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)
	MOV  	R1,#33H   ；指向二進(jìn)制浮點(diǎn)操作數(shù)ｂ
	LCALL	FMUL      ；進(jìn)行浮點(diǎn)乘法運(yùn)算
	MOV  	R1,#36H   ；指向二進(jìn)制浮點(diǎn)操作數(shù)ｃ
	LCALL	FDIV      ；進(jìn)行浮點(diǎn)除法運(yùn)算

MOV  	R1,#39H   ；指向二進(jìn)制浮點(diǎn)操作數(shù)ｄ
	LCALL	FADD      ；進(jìn)行浮點(diǎn)加法運(yùn)算
	LCALL	FSIN      ；進(jìn)行浮點(diǎn)正弦運(yùn)算
	LCALL	FABS      ；進(jìn)行浮點(diǎn)絕對(duì)值運(yùn)算
	LCALL	FSQR      ；進(jìn)行浮點(diǎn)開(kāi)平方運(yùn)算
	LCALL	FLN       ；進(jìn)行浮點(diǎn)對(duì)數(shù)運(yùn)算
	LCALL	FTOB      ；將結(jié)果轉(zhuǎn)換成ＢＣＤ碼浮點(diǎn)數(shù)
STOP:	LJMP	STOP
	END
    運(yùn)行結(jié)果，[R0]=804915H，即ｙ=-0.4915，比較精確的結(jié)果應(yīng)該是-0.491437。

    （１）  標(biāo)號(hào)：  ＦＳＤＴ    功能：浮點(diǎn)數(shù)格式化

入口條件：待格式化浮點(diǎn)操作數(shù)在[R0]中。

出口信息：已格式化浮點(diǎn)操作數(shù)仍在[R0]中。
影響資源：PSW、A、R2、R3、R4、位1FH    堆棧需求：  ６字節(jié)

FSDT:	LCALL	MVR0	；將待格式化操作數(shù)傳送到第一工作區(qū)中
	LCALL	RLN	；通過(guò)左規(guī)完成格式化
	LJMP	MOV0	；將已格式化浮點(diǎn)操作數(shù)傳回到[R0]中

    （２）  標(biāo)號(hào)：  ＦＡＤＤ    功能：浮點(diǎn)數(shù)加法

入口條件：被加數(shù)在[R0]中，加數(shù)在[R1]中。
出口信息：OV=0時(shí)，和仍在[R0]中，OV=1時(shí)，溢出。
影響資源：PSW、A、B、R2～R7、位1EH、1FH  堆棧需求：  ６字節(jié)

FADD:	CLR	F0	；設(shè)立加法標(biāo)志

SJMP	AS	；計(jì)算代數(shù)和

    （３）  標(biāo)號(hào)：  ＦＳＵＢ    功能：浮點(diǎn)數(shù)減法

入口條件：被減數(shù)在[R0]中，減數(shù)在[R1]中。
出口信息：OV=0時(shí)，差仍在[R0]中，OV=1時(shí)，溢出。
影響資源：PSW、A、B、R2～R7、位1EH、1FH    堆棧需求：６字節(jié)

FSUB:	SETB	F0	；設(shè)立減法標(biāo)志
AS:	LCALL	MVR1	；計(jì)算代數(shù)和。先將[R1]傳送到第二工作區(qū)
	MOV	C,F0	；用加減標(biāo)志來(lái)校正第二操作數(shù)的有效符號(hào)
	RRC	A
	XRL	A,@R1
	MOV	C,ACC.7
ASN:	MOV	1EH,C	；將第二操作數(shù)的有效符號(hào)存入位1EH中
	XRL	A,@R0	；與第一操作數(shù)的符號(hào)比較

RLC	A
	MOV	F0,C	；保存比較結(jié)果
	LCALL	MVR0	；將[R0]傳送到第一工作區(qū)中
	LCALL	AS1	；在工作寄存器中完成代數(shù)運(yùn)算
MOV0:	INC	R0	；將結(jié)果傳回到[R0]中的子程序入口
	INC	R0
	MOV	A,R4	；傳回尾數(shù)的低字節(jié)
	MOV	@R0,A
	DEC	R0
	MOV	A,R3	；傳回尾數(shù)的高字節(jié)
	MOV	@R0,A
	DEC	R0
	MOV	A,R2	；取結(jié)果的階碼
	MOV	C,1FH	；取結(jié)果的數(shù)符
	MOV	ACC.7,C	；拼入階碼中
	MOV	@R0,A
	CLR	ACC.7	；不考慮數(shù)符
	CLR	OV	；清除溢出標(biāo)志
	CJNE	A,#3FH,MV01；階碼是否上溢？

SETB	OV	；設(shè)立溢出標(biāo)志
MV01:	MOV	A,@R0	；取出帶數(shù)符的階碼
	RET
MVR0:	MOV	A,@R0	；將[R0]傳送到第一工作區(qū)中的子程序
	MOV	C,ACC.7	；將數(shù)符保存在位1FH中
	MOV	1FH,C
	MOV	C,ACC.6	；將階碼擴(kuò)充為８ｂｉｔ補(bǔ)碼
	MOV	ACC.7,C
	MOV	R2,A	；存放在R2中
	INC	R0
	MOV	A,@R0	；將尾數(shù)高字節(jié)存放在R3中
	MOV	R3,A
	INC	R0
	MOV	A,@R0	；將尾數(shù)低字節(jié)存放在R4中
	MOV	R4,A
	DEC	R0	；恢復(fù)數(shù)據(jù)指針
	DEC	R0
	RET
MVR1:	MOV	A,@R1	；將[R1]傳送到第二工作區(qū)中的子程序

MOV	C,ACC.7	；將數(shù)符保存在位1EH中
	MOV	1EH,C
	MOV	C,ACC.6	；將階碼擴(kuò)充為８ｂｉｔ補(bǔ)碼
	MOV	ACC.7,C
	MOV	R5,A	；存放在R5中
	INC	R1
	MOV	A,@R1	；將尾數(shù)高字節(jié)存放在R6中
	MOV	R6,A
	INC	R1
	MOV	A,@R1	；將尾數(shù)低字節(jié)存放在R7中
	MOV	R7,A
	DEC	R1	；恢復(fù)數(shù)據(jù)指針
	DEC	R1
	RET
AS1:	MOV	A,R6	；讀取第二操作數(shù)尾數(shù)高字節(jié)
	ORL	A,R7
	JZ	AS2	；第二操作數(shù)為零，不必運(yùn)算
	MOV	A,R3	；讀取第一操作數(shù)尾數(shù)高字節(jié)
	ORL	A,R4
	JNZ	EQ
	MOV	A,R6	；第一操作數(shù)為零，結(jié)果以第二操作數(shù)為準(zhǔn)

MOV	R3,A
	MOV	A,R7
	MOV	R4,A
	MOV	A,R5
	MOV	R2,A
	MOV	C,1EH
	MOV	1FH,C
AS2:	RET
EQ:	MOV	A,R2	；對(duì)階，比較兩個(gè)操作數(shù)的階碼
	XRL	A,R5
	JZ	AS4	；階碼相同，對(duì)階結(jié)束
	JB	ACC.7,EQ3；階符互異
	MOV	A,R2	；階符相同，比較大小
	CLR	C
	SUBB	A,R5
	JC	EQ4
EQ2:	CLR	C	；第二操作數(shù)右規(guī)一次
	MOV	A,R6	；尾數(shù)縮小一半
	RRC	A
	MOV	R6,A
	MOV	A,R7
	RRC	A
	MOV	R7,A
	INC	R5	；階碼加一
	ORL	A,R6	；尾數(shù)為零否？
	JNZ	EQ	；尾數(shù)不為零，繼續(xù)對(duì)階

MOV	A,R2	；尾數(shù)為零，提前結(jié)束對(duì)階
	MOV	R5,A
	SJMP	AS4
EQ3:	MOV	A,R2	；判斷第一操作數(shù)階符
	JNB	ACC.7,EQ2；如為正，右規(guī)第二操作數(shù)
EQ4:	CLR	C
	LCALL	RR1	；第一操作數(shù)右規(guī)一次
	ORL	A,R3	；尾數(shù)為零否？
	JNZ	EQ	；不為零，繼續(xù)對(duì)階
	MOV	A,R5	；尾數(shù)為零，提前結(jié)束對(duì)階
	MOV	R2,A
AS4:	JB	F0,AS5	；尾數(shù)加減判斷
	MOV	A,R4	；尾數(shù)相加
	ADD	A,R7
	MOV	R4,A
	MOV	A,R3	
	ADDC	A,R6
	MOV	R3,A
	JNC	AS2
	LJMP	RR1	；有進(jìn)位，右規(guī)一次

AS5:	CLR	C	；比較絕對(duì)值大小
	MOV	A,R4
	SUBB	A,R7
	MOV	B,A
	MOV	A,R3
	SUBB	A,R6
	JC	AS6
	MOV	R4,B	；第一尾數(shù)減第二尾數(shù)
	MOV	R3,A
	LJMP	RLN	；結(jié)果規(guī)格化
AS6:	CPL	1FH	；結(jié)果的符號(hào)與第一操作數(shù)相反
	CLR	C	；結(jié)果的絕對(duì)值為第二尾數(shù)減第一尾數(shù)
	MOV	A,R7
	SUBB	A,R4
	MOV	R4,A
	MOV	A,R6
	SUBB	A,R3
	MOV	R3,A
RLN:	MOV	A,R3	；浮點(diǎn)數(shù)規(guī)格化
	ORL	A,R4	；尾數(shù)為零否？
	JNZ	RLN1
	MOV	R2,#0C1H；階碼取最小值
	RET     	
RLN1:	MOV	A,R3

JB	ACC.7,RLN2；尾數(shù)最高位為一否？
	CLR	C	；不為一，左規(guī)一次
	LCALL	RL1
	SJMP	RLN	；繼續(xù)判斷
RLN2:	CLR	OV	；規(guī)格化結(jié)束
	RET
RL1:	MOV	A,R4	；第一操作數(shù)左規(guī)一次
	RLC	A	；尾數(shù)擴(kuò)大一倍
	MOV	R4,A
	MOV	A,R3
	RLC	A
	MOV	R3,A
	DEC	R2	；階碼減一
	CJNE	R2,#0C0H,RL1E；階碼下溢否？
	CLR	A
	MOV	R3,A	；階碼下溢，操作數(shù)以零計(jì)
	MOV	R4,A
	MOV	R2,#0C1H
RL1E:	CLR	OV
	RET
RR1:	MOV	A,R3	；第一操作數(shù)右規(guī)一次
	RRC	A	；尾數(shù)縮小一半

MOV	R3,A
	MOV	A,R4
	RRC	A
	MOV	R4,A
	INC	R2	；階碼加一
	CLR	OV	；清溢出標(biāo)志
	CJNE	R2,#40H,RR1E；階碼上溢否？
	MOV	R2,#3FH	；階碼溢出
	SETB	OV
RR1E:	RET

    （４）  標(biāo)號(hào)：  ＦＭＵＬ    功能：浮點(diǎn)數(shù)乘法

入口條件：被乘數(shù)在[R0]中，乘數(shù)在[R1]中。
出口信息：OV=0時(shí)，積仍在[R0]中，OV=1時(shí)，溢出。
影響資源：PSW、A、B、R2～R7、位1EH、1FH    堆棧需求：６字節(jié)

FMUL:	LCALL	MVR0	；將[R0]傳送到第一工作區(qū)中
	MOV	A,@R0
	XRL	A,@R1	；比較兩個(gè)操作數(shù)的符號(hào)

RLC	A
	MOV	1FH,C	；保存積的符號(hào)
	LCALL	MUL0	；計(jì)算積的絕對(duì)值
	LJMP	MOV0	；將結(jié)果傳回到[R0]中
MUL0:	LCALL	MVR1	；將[R1]傳送到第二工作區(qū)中
MUL1:	MOV	A,R3	；第一尾數(shù)為零否？
	ORL	A,R4
	JZ	MUL6
	MOV	A,R6	；第二尾數(shù)為零否？
	ORL	A,R7
	JZ	MUL5
	MOV	A,R7	；計(jì)算R3R4×R6R7－→R3R4
	MOV	B,R4
	MUL	AB
	MOV	A,B
	XCH	A,R7
	MOV	B,R3
	MUL	AB
	ADD	A,R7
	MOV	R7,A
	CLR	A
	ADDC	A,B
	XCH	A,R4
	MOV	B,R6
	MUL	AB
	ADD	A,R7

MOV	R7,A
	MOV	A,B
	ADDC	A,R4
	MOV	R4,A
	CLR	A
	RLC	A
	XCH	A,R3
	MOV	B,R6
	MUL	AB
	ADD	A,R4
	MOV	R4,A
	MOV	A,B
	ADDC	A,R3
	MOV	R3,A
	JB	ACC.7,MUL2；積為規(guī)格化數(shù)否？
	MOV	A,R7	；左規(guī)一次
	RLC	A
	MOV	R7,A
	LCALL	RL1
MUL2:	MOV	A,R7
	JNB	ACC.7,MUL3
	INC	R4
	MOV	A,R4
	JNZ	MUL3
	INC	R3
	MOV	A,R3
	JNZ	MUL3
	MOV	R3,#80H
	INC	R2
MUL3:	MOV	A,R2	；求積的階碼
	ADD	A,R5
MD:	MOV	R2,A	；階碼溢出判斷

JB	ACC.7,MUL4
	JNB	ACC.6,MUL6
	MOV	R2,#3FH	；階碼上溢，設(shè)立標(biāo)志
	SETB	OV
	RET
MUL4:	JB	ACC.6,MUL6
MUL5:	CLR	A	；結(jié)果清零（因子為零或階碼下溢）
	MOV	R3,A
	MOV	R4,A
	MOV	R2,#41H
MUL6:	CLR	OV
	RET

    （５）  標(biāo)號(hào)：  ＦＤＩＶ    功能：浮點(diǎn)數(shù)除法

入口條件：被除數(shù)在[R0]中，除數(shù)在[R1]中。
出口信息：OV=0時(shí)，商仍在[R0]中，OV=1時(shí)，溢出。
影響資源：PSW、A、B、R2～R7、位1EH、1FH   堆棧需求：  ５字節(jié)

FDIV:	INC	R0
	MOV	A,@R0
	INC	R0

ORL	A,@R0
	DEC	R0
	DEC	R0
	JNZ	DIV1
	MOV	@R0,#41H；被除數(shù)為零，不必運(yùn)算
	CLR	OV
	RET
DIV1:	INC	R1
	MOV	A,@R1
	INC	R1  	
	ORL	A,@R1
	DEC	R1
	DEC	R1  	
	JNZ	DIV2	
	SETB	OV	；除數(shù)為零，溢出
	RET     	
DIV2:	LCALL	MVR0	；將[R0]傳送到第一工作區(qū)中
	MOV	A,@R0
	XRL	A,@R1	；比較兩個(gè)操作數(shù)的符號(hào)
	RLC	A
	MOV	1FH,C	；保存結(jié)果的符號(hào)
	LCALL	MVR1	；將[R1]傳送到第二工作區(qū)中
	LCALL	DIV3	；調(diào)用工作區(qū)浮點(diǎn)除法
	LJMP	MOV0	；回傳結(jié)果

DIV3:	CLR	C	；比較尾數(shù)的大小
	MOV	A,R4
	SUBB	A,R7
	MOV	A,R3
	SUBB	A,R6
	JC	DIV4
	LCALL	RR1	；被除數(shù)右規(guī)一次
	SJMP	DIV3
DIV4:	CLR	A	；借用R0R1R2作工作寄存器
	XCH	A,R0	；清零并保護(hù)之
	PUSH	ACC
	CLR	A
	XCH	A,R1
	PUSH	ACC
	MOV	A,R2
	PUSH	ACC
	MOV	B,#10H	；除法運(yùn)算，R3R4／R6R7－→R0R1
DIV5:	CLR	C
	MOV	A,R1
	RLC	A
	MOV	R1,A
	MOV	A,R0
	RLC	A
	MOV	R0,A
	MOV	A,R4
	RLC	A
	MOV	R4,A
	XCH	A,R3
	RLC	A

XCH	A,R3
	MOV	F0,C
	CLR	C
	SUBB	A,R7
	MOV	R2,A
	MOV	A,R3
	SUBB	A,R6
	ANL	C,/F0
	JC	DIV6
	MOV	R3,A
	MOV	A,R2
	MOV	R4,A
	INC	R1
DIV6:	DJNZ	B,DIV5
	MOV	A,R6	；四舍五入
	CLR	C
	RRC	A
	SUBB	A,R3
	CLR	A
	ADDC	A,R1	；將結(jié)果存回R3R4
	MOV	R4,A
	CLR	A
	ADDC	A,R0
	MOV	R3,A
	POP	ACC	；恢復(fù)R0R1R2
	MOV	R2,A
	POP	ACC
	MOV	R1,A
	POP	ACC
	MOV	R0,A
	MOV	A,R2	；計(jì)算商的階碼
	CLR	C
	SUBB	A,R5

LCALL	MD	；階碼檢驗(yàn)
	LJMP	RLN	；規(guī)格化

    （６）  標(biāo)號(hào)：  ＦＣＬＲ      功能：浮點(diǎn)數(shù)清零

入口條件：操作數(shù)在[R0]中。
出口信息：操作數(shù)被清零。
影響資源：A    堆棧需求：  ２字節(jié)

FCLR:	INC	R0
	INC	R0
	CLR	A
	MOV	@R0,A
	DEC	R0
	MOV	@R0,A
	DEC	R0
	MOV	@R0,#41H
	RET 	

    （７）  標(biāo)號(hào)：  ＦＺＥＲ    功能：浮點(diǎn)數(shù)判零

入口條件：操作數(shù)在[R0]中。
出口信息：若累加器A為零，則操作數(shù)[R0]為零，否則不為零。
影響資源：A    堆棧需求：  ２字節(jié)

FZER:	INC	R0
	INC	R0
	MOV	A,@R0
	DEC	R0
	ORL	A,@R0
	DEC	R0
	JNZ	ZERO
	MOV	@R0,#41H
ZERO:	RET 	

    （８）  標(biāo)號(hào)：  ＦＭＯＶ    功能：浮點(diǎn)數(shù)傳送

入口條件：源操作數(shù)在[R1]中，目標(biāo)地址為[R0]。
出口信息：[R0]=[R1]，[R1]不變。
影響資源：A   堆棧需求：  ２字節(jié)

FMOV:	INC	R0
	INC	R0
	INC	R1
	INC	R1
	MOV	A,@R1
	MOV	@R0,A
	DEC	R0
	DEC	R1
	MOV	A,@R1
	MOV	@R0,A
	DEC	R0
	DEC	R1
	MOV	A,@R1
	MOV	@R0,A
	RET

    （９）  標(biāo)號(hào)：  ＦＰＵＳ    功能：浮點(diǎn)數(shù)壓棧

入口條件：操作數(shù)在[R0]中。
出口信息：操作數(shù)壓入棧頂。
影響資源：A、R2、R3    堆棧需求：  ５字節(jié)

FPUS:	POP	ACC	；將返回地址保存在R2R3中
	MOV	R2,A
	POP	ACC
	MOV	R3,A
	MOV	A,@R0	；將操作數(shù)壓入堆棧
	PUSH	ACC
	INC	R0
	MOV	A,@R0
	PUSH	ACC
	INC	R0
	MOV	A,@R0
	PUSH	ACC
	DEC	R0
	DEC	R0
	MOV	A,R3	；將返回地址壓入堆棧
	PUSH	ACC
	MOV	A,R2
	PUSH	ACC
	RET		；返回主程序

    （１０）  標(biāo)號(hào)：  ＦＰＯＰ    功能：浮點(diǎn)數(shù)出棧

入口條件：操作數(shù)處于棧頂。
出口信息：操作數(shù)彈至[R0]中。
影響資源：A、R2、R3    堆棧需求：  ２字節(jié)

FPOP:	POP	ACC	；將返回地址保存在R2R3中
	MOV	R2,A
	POP	ACC
	MOV	R3,A
	INC	R0