-- 庫聲明
library IEEE;
use IEEE.STD_LOGIC_1164.all;
use WORK.UART_PACKAGE.ALL;

-- 實體聲明
entity baudrate_generator is
	-- 類屬參數(shù)聲明
	generic (
	FULL_PULSE_COUNT : BD_COUNT := BD9600_FPC;
	RISE_PULSE_COUNT : BD_COUNT := BD9600_HPC );
	-- 端口聲明
	port (
	clk : in std_logic;
	reset_n : in std_logic;
	ce : in std_logic;
	bg_out : out std_logic;
	indicator : out std_logic );
	
end baudrate_generator;

--}} End of automatically maintained section
-- 結(jié)構(gòu)體
architecture baudrate_generator of baudrate_generator is
begin

	-- enter your statements here --
	-- 主過程
	-- main process
	main : process( clk, reset_n )
	variable clk_count : BD_COUNT; 
	begin
		-- 判斷復位信號
		if reset_n = '0' then
			bg_out <= '0';
			indicator <= '0';
			clk_count := 0;
		-- 在時鐘信號的上升沿動作
		elsif rising_edge(clk) then
			-- 判斷使能信號
			if ce = '1' then
				-- 經(jīng)過了RISE_PULSE_COUNT個計數(shù)，數(shù)脈沖上升
				if clk_count = RISE_PULSE_COUNT-1 then		-- pulse rise
					bg_out <= '1';
					clk_count := clk_count+1;
				-- 經(jīng)過了FULL_PULSE_COUNT個計數(shù)，數(shù)脈沖下降
				elsif clk_count = FULL_PULSE_COUNT-1 then	-- indicator output and pulse fall
					-- 輸出提示信號，使其為高
					indicator <= '1';
					bg_out <= '0';
					-- 重置計數(shù)器計數(shù)為0
					clk_count := 0;
				-- 恢復提示信號為低
				elsif clk_count = 0 then
					indicator <= '0';
					clk_count := clk_count+1;
				else
					clk_count := clk_count+1;
				end if;
			end if;
		end if;
	end process;

end baudrate_generator;