;******************************************************************************
; 文件名：TIMEOUT.S
; 功能：使用定時(shí)器0實(shí)現(xiàn)1秒定時(shí),控制LED4閃爍。(中斷方式)
; 說(shuō)明：將跳線器JP4_LED4短接。
;******************************************************************************
				INCLUDE		LPC2294.INC
				EXPORT  	MAIN
                
VIC_BASE		EQU		0xFFFFF000
TIMER0_BASE		EQU		0xE0004000
				
LEDCON  		EQU		(1<<25)					;  P0.25引腳控制LED4，低電平點(diǎn)亮

                AREA    TIMEOUTC,CODE,READONLY 
                CODE32                         
                         
MAIN            MSR     CPSR_c, #0x5F			; 切換處理器工作模式，并允許IRQ中斷
            	LDR		R0,=PINSEL0				
				MOV		R1,#0x00000000			
				STR		R1,[R0]					; 設(shè)置管腳連接
				LDR		R0,=IO0DIR				
				LDR		R1,=LEDCON
				STR		R1,[R0]					; 設(shè)置BEEP控制口為輸出
				BL		SYSCLK_INI				; 設(shè)置系統(tǒng)時(shí)鐘
				
				LDR		R0,=MEMMAP
    			MOV		R1,#0x02
				STR		R1,[R0]					; REMAP操作(若寫(xiě)到片內(nèi)FLASH，則不需要REMAP)
			
TIME0_INI		; Fcclk = Fosc*4 = 11.0592MHz*4 = 44.2368MHz
	   			; Fpclk = Fcclk/4 = 44.2368MHz/4 = 11.0592MHz
	   			LDR		R0,=TIMER0_BASE
	   			MOV		R1,#99
	   			STR		R1,[R0,#0x0C]			; T0PR=99，設(shè)置定時(shí)器0分頻為100分頻，得110592Hz
	   			MOV		R1,#0x03
	   			STR		R1,[R0,#0x14]			; T0MCR=0x03，匹配通道0匹配中斷并復(fù)位T0TC
	   			LDR		R1,=110592				
	   			STR		R1,[R0,#0x18]			; T0MR0=110592，比較值(1S定時(shí)值)
	   			MOV		R1,#0x01
	   			STR		R1,[R0,#0x04]			; T0TCR=0x01，啟動(dòng)T0TC
				
				; 設(shè)置定時(shí)器0中斷IRQ
				LDR		R0,=VIC_BASE
				MOV		R1,#0x00000000
				STR		R1,[R0,#0x0C]			; VICIntSelect=0x00000000
				MOV		R1,#0x24
				STR		R1,[R0,#0x200]			; VICVectCntl0=0x24
				LDR		R1,=IRQ_TIME0
				STR		R1,[R0,#0x100]			; VICVectAddr0=(int)IRQ_TIME0
				MOV		R1,#0x00000010
				STR		R1,[R0,#0x10]			; VICIntEnable=0x00000010			
						
WAIT_IRQ		B		WAIT_IRQ	


;******************************************************************************		
; 名稱：SYSCLK_INI
; 功能：設(shè)置系統(tǒng)時(shí)鐘。(M值為4，P值為2)
; 入口參數(shù)：無(wú)
; 出口參數(shù)：無(wú)
; 占用資源：R0、R1		
;******************************************************************************
SYSCLK_INI	
			LDR		R0,=VPBDIV
			MOV		R1,#0x00
			STR		R1,[R0]					; VPBDIV=0x00
			
			LDR		R0,=PLLCFG
			MOV		R1,#0x23
			STR		R1,[R0]					; PLLCFG=0x23，設(shè)置M值為4，P值為2
			LDR		R0,=PLLCON
			MOV		R1,#0x01
			STR		R1,[R0]					; PLLCON=0x01
			LDR		R0,=PLLFEED
			MOV		R1,#0xAA
			STR		R1,[R0]					; PLLFEED=0xAA
			MOV		R1,#0x55
			STR		R1,[R0]					; PLLFEED=0x55
WAIT_OK		LDR		R0,=PLLSTAT				
			LDR		R1,[R0]
			ANDS	R1,R1,#0x0400
			BEQ		WAIT_OK					; 等待PLL鎖定
			
			LDR		R0,=PLLCON
			MOV		R1,#0x03
			STR		R1,[R0]
			LDR		R0,=PLLFEED
			MOV		R1,#0xAA
			STR		R1,[R0]
			MOV		R1,#0x55
			STR		R1,[R0]	
			
			MOV		PC,LR		    
              
                                
;******************************************************************************
; 名稱：IRQ_TIME0
; 功能：TIME0中斷服務(wù)程序，取反LEDCON控制口。
; 入口參數(shù)：無(wú)
; 出口參數(shù)：無(wú)
; 占用資源：R0、R1
;******************************************************************************
IRQ_TIME0	
				LDR		R0,=IO0SET
				LDR		R1,[R0]					; 讀取IO0SET的值
				ANDS	R1,R1,#LEDCON
				LDREQ	R0,=IO0SET				; 設(shè)置R0=IO0SET
				LDRNE	R0,=IO0CLR				; 設(shè)置R0=IO0CLR
				MOV		R1,#LEDCON
				STR		R1,[R0]
			 
				LDR		R0,=T0IR
				MOV		R1,#0x01
				STR		R1,[R0]					; 清除中斷標(biāo)志
			
				LDR		R0,=VICVectAddr
				MOV		R1,#0
				STR		R1,[R0]					; VICVectAddr=0						
   				SUBS	PC,LR,#4				; IRQ中斷返回 
                
                LTORG                           ; 聲明文字池
                
                
                END