;/****************************************Copyright (c)**************************************************
;**                               Guangzou ZLG-MCU Development Co.,LTD.
;**                                      graduate school
;**                                 http://www.zlgmcu.com
;**
;**--------------File Info-------------------------------------------------------------------------------
;** File Name: IRQ.s
;** Last modified Date:  2004-06-14
;** Last Version: 1.1
;** Descriptions: The irq handle that what allow the interrupt nesting. 
;**
;**------------------------------------------------------------------------------------------------------
;** Created By: Chenmingji
;** Created date:   2004-09-17
;** Version: 1.0
;** Descriptions: First version
;**
;**------------------------------------------------------------------------------------------------------
;** Modified by:
;** Modified date:
;** Version:
;** Descriptions:
;**
;********************************************************************************************************/

NoInt       EQU 0x80

USR32Mode   EQU 0x10
SVC32Mode   EQU 0x13
SYS32Mode   EQU 0x1f
IRQ32Mode   EQU 0x12
FIQ32Mode   EQU 0x11

    CODE32

    AREA    IRQ,CODE,READONLY

    MACRO
$IRQ_Label HANDLER $IRQ_Exception_Function

        EXPORT  $IRQ_Label                      ; Output Lable 輸出的標(biāo)號(hào)
        IMPORT  $IRQ_Exception_Function         ; Import Lable 引用的外部標(biāo)號(hào)

$IRQ_Label
        SUB     LR, LR, #4                      ; Calculate the returning address 計(jì)算返回地址
        STMFD   SP!, {R0-R3, R12, LR}           ; Protects the task environments 保存任務(wù)環(huán)境
        MRS     R3, SPSR                        ; Protects the status variable 保存狀態(tài)
        STMFD   SP, {R3,LR}^                    ; Protects SPSR and SP in user status, Notice: DO NOT write back.保存SPSR和用戶狀態(tài)的SP,注意不能回寫(xiě)
                                                ; If the SP is written back, it should be adjusted to its appropriate value later.如果回寫(xiě)的是用戶的SP，所以后面要調(diào)整SP
        NOP
        SUB     SP, SP, #4*2

        MSR     CPSR_c, #(NoInt | SYS32Mode)    ; Switch to the System Mode 切換到系統(tǒng)模式
       
        BL      $IRQ_Exception_Function         ; call the C interrupt handler funtion 調(diào)用c語(yǔ)言的中斷處理程序

        MSR     CPSR_c, #(NoInt | IRQ32Mode)    ; Switch bak to IRQ mode 切換回irq模式
        LDMFD   SP, {R3,LR}^                    ; Recover SPSR and SP in user status, Notic: DO NOT write back.恢復(fù)SPSR和用戶狀態(tài)的SP,注意不能回寫(xiě)
                                                ; If the SP is written back, it should be adjusted to its appropriate value later.如果回寫(xiě)的是用戶的SP，所以后面要調(diào)整SP
        MSR     SPSR_cxsf, R3
        ADD     SP, SP, #4*2                    ; 

        LDMFD   SP!, {R0-R3, R12, PC}^          ;
    MEND

;/* 以下添加中斷句柄，用戶根據(jù)實(shí)際情況改變 */
;/* Add interrupt handler here，user could change it as needed */

;Timer0_Handler  HANDLER Timer0

    END
;/*********************************************************************************************************
;**                            End Of File
;********************************************************************************************************/