?? frmdepartment.frm
字號:
VERSION 5.00
Begin VB.Form Department
BorderStyle = 1 'Fixed Single
Caption = "系部信息管理"
ClientHeight = 1905
ClientLeft = 45
ClientTop = 330
ClientWidth = 4455
LinkTopic = "Form1"
MaxButton = 0 'False
MDIChild = -1 'True
MinButton = 0 'False
ScaleHeight = 1905
ScaleWidth = 4455
Begin VB.TextBox txtNum
Height = 270
Left = 1635
MaxLength = 8
TabIndex = 11
Top = 232
Width = 1995
End
Begin VB.TextBox txtName
Height = 270
Left = 1635
MaxLength = 20
TabIndex = 10
Top = 622
Width = 1995
End
Begin VB.PictureBox picNavigation
AutoSize = -1 'True
BorderStyle = 0 'None
Height = 360
Left = 885
ScaleHeight = 360
ScaleWidth = 2685
TabIndex = 8
Top = 1312
Width = 2685
Begin VB.TextBox txtNews
Height = 300
Left = 690
Locked = -1 'True
TabIndex = 9
TabStop = 0 'False
Top = 15
Width = 1275
End
Begin VB.CommandButton cmdMove
Height = 300
Index = 2
Left = 1950
Picture = "frmDepartment.frx":0000
Style = 1 'Graphical
TabIndex = 6
Top = 15
Width = 345
End
Begin VB.CommandButton cmdMove
Height = 300
Index = 3
Left = 2280
Picture = "frmDepartment.frx":0044
Style = 1 'Graphical
TabIndex = 7
Top = 15
Width = 345
End
Begin VB.CommandButton cmdMove
Height = 300
Index = 0
Left = 30
Picture = "frmDepartment.frx":0093
Style = 1 'Graphical
TabIndex = 4
Top = 15
Width = 345
End
Begin VB.CommandButton cmdMove
Height = 300
Index = 1
Left = 360
Picture = "frmDepartment.frx":00E0
Style = 1 'Graphical
TabIndex = 5
Top = 15
Width = 345
End
End
Begin VB.CommandButton cmdAdd
Caption = "添加"
Height = 300
Left = 727
TabIndex = 0
Top = 997
Width = 735
End
Begin VB.CommandButton cmdDelete
Caption = "刪除"
Height = 300
Left = 1477
TabIndex = 1
Top = 997
Width = 735
End
Begin VB.CommandButton cmdExit
Cancel = -1 'True
Caption = "退出"
Height = 315
Left = 2992
TabIndex = 3
Top = 990
Width = 735
End
Begin VB.CommandButton cmdSave
Caption = "保存"
Height = 300
Left = 2227
TabIndex = 2
Top = 997
Width = 735
End
Begin VB.Label Label1
AutoSize = -1 'True
Caption = "系部編號"
Height = 180
Left = 825
TabIndex = 13
Top = 247
Width = 720
End
Begin VB.Label Label2
AutoSize = -1 'True
Caption = "系部名稱"
Height = 180
Left = 825
TabIndex = 12
Top = 652
Width = 720
End
End
Attribute VB_Name = "Department"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Dim isAdding As Boolean '定義操作狀態標志
Dim objDepart As Recordset '用于保存數據庫中的系部信息記錄
Dim objCn As Connection '用于建立數據庫聯接
Private Sub cmdExit_Click()
Unload Me '關閉系部信息管理窗體
End Sub
Private Sub Form_Load()
'建立數據庫聯接
Set objCn = New Connection '實例化聯接對象
With objCn '建立數據庫聯接
.Provider = "SQLOLEDB"
.ConnectionString = "User ID=sa;PWD=123;Data Source=(local);" & _
"Initial Catalog=自測考試"
.Open
End With
'獲取系部信息記錄
Set objDepart = New Recordset '實例化objDepart對象
With objDepart
Set .ActiveConnection = objCn '設置數據庫聯接
.CursorLocation = adUseClient '指定使用客戶端游標
.CursorType = adOpenStatic '指定使用靜態游標
.LockType = adLockOptimistic
.Open "SELECT * FROM 系部信息" '獲取系部信息記錄
End With
'觸發按鈕單擊事件，顯示第一個記錄
cmdMove(0).Value = True
End Sub
Private Sub cmdMove_Click(Index As Integer)
With objDepart
Select Case Index '切換當前記錄
Case 0 '使第一個記錄成為當前記錄
If .RecordCount > 0 And Not .BOF Then .MoveFirst
Case 1 '使上一個記錄成為當前記錄
If .RecordCount > 0 And Not .BOF Then
.MovePrevious
If .BOF Then .MoveFirst
End If
Case 2 '使下一個記錄成為當前記錄
If .RecordCount > 0 And Not .EOF Then
.MoveNext
If .EOF Then .MoveLast
End If
Case 3 '使最后一個記錄成為當前記錄
If .RecordCount > 0 And Not .EOF Then .MoveLast
End Select
If .RecordCount < 1 Then
txtNews = "記錄：無" '顯示無記錄提示
txtNum = ""
txtName = ""
Else
'顯示當前記錄數據
txtNum = .Fields("編號")
txtName = .Fields("名稱")
'顯示當前記錄編號和記錄總數
txtNews = "記錄：" & .AbsolutePosition & "/" & .RecordCount
End If
End With
If isAdding Then isAdding = False
End Sub
Private Sub cmdAdd_Click()
txtNews = "添加新記錄"
txtNum = ""
txtName = ""
isAdding = True
txtNum.SetFocus
End Sub
Private Sub cmdDelete_Click()
'根據是否處于添加記錄狀態執行不同的操作
If isAdding Then
'退出添加記錄狀態，顯示當前記錄
isAdding = False
If objDepart.BOF And objDepart.EOF Then
txtNews = "記錄：無" '顯示無記錄提示
Else
'顯示當前記錄數據
txtNum = objDepart.Fields("編號")
txtName = objDepart.Fields("名稱")
'顯示當前記錄編號和記錄總數
txtNews = "記錄：" & objDepart.AbsolutePosition & "/" & objDepart.RecordCount
End If
Else
If objDepart.RecordCount > 0 Then
'檢查在教師信息和學生信息表中是否使用了當前記錄的編號
'如果被使用，則不執行刪除操作
Dim objTemp As New Recordset
With objTemp
Set .ActiveConnection = objCn '設置數據庫聯接
.CursorLocation = adUseClient '指定使用客戶端器游標
.CursorType = adOpenStatic '指定使用靜態游標
'獲取使用了該編號的第一條記錄
.Open "SELECT TOP 1 * FROM 學生信息 WHERE 系部='" & Trim(txtNum) & "'"
If .RecordCount > 0 Then
MsgBox "編號被《學生信息》表使用，不能刪除當前記錄！", , "系部信息管理"
Exit Sub
End If
.Close
End With
Set objTemp = Nothing
'可以刪除，請求確認執行刪除操作
If MsgBox("是否刪除當前記錄？", vbYesNo + vbQuestion, "系部信息管理") = vbYes Then
'執行刪除當前記錄操作
objDepart.Delete
'顯示下一記錄數據
cmdMove(2).Value = True
Else
'顯示當前記錄數據
txtNum = objDepart.Fields("編號")
txtName = objDepart.Fields("名稱")
'顯示當前記錄編號和記錄總數
txtNews = "記錄：" & objDepart.AbsolutePosition & "/" _
& objDepart.RecordCount
End If
End If
End If
End Sub
Private Sub cmdSave_Click()
If Len(Trim(txtNum)) <> 8 Then
MsgBox "系部編號必須為8位字符串！", vbCritical, "系部信息管理"
txtNum.SetFocus
txtNum.SelStart = 0
txtNum.SelLength = Len(txtNum)
Exit Sub
End If
If Trim(txtName) = "" Then
MsgBox "系部名稱不能為空！", vbCritical, "系部信息管理"
txtName.SetFocus
txtName = ""
Exit Sub
End If
'在進一步保存添加的新記錄或修改的當前記錄之前，檢查編號是否重復
Dim objCopy As New Recordset
Set objCopy = objDepart.Clone
If objCopy.RecordCount > 0 Then
objCopy.MoveFirst
objCopy.Find "編號='" & Trim(txtNum) & "'"
If (isAdding And Not objCopy.EOF) Or (Not isAdding And Not objCopy.EOF And _
objCopy.AbsolutePosition <> objDepart.AbsolutePosition) Then
MsgBox "編號：" & Trim(txtNum) & "已被使用，請使用其他編號！", _
vbCritical, "系部信息管理"
txtNum.SetFocus
txtNum.SelStart = 0
txtNum.SelLength = Len(txtNum)
Exit Sub '編號重復，直接退出
End If
End If
'編號不重復，執行下一步保存操作
With objDepart
If isAdding Then
'添加新記錄
.AddNew
Else
'保存被修改的當前記錄
If objDepart.Fields("編號") <> Trim(txtNum) Then
If MsgBox("修改編號將影響《教師信息》和《學生信息》表中的相關記錄，是否繼續？", _
vbYesNo + vbQuestion, "系部信息管理") = vbNo Then
'取消保存操作，還原當前記錄
txtNum = .Fields("編號")
txtName = .Fields("名稱")
Exit Sub '退出過程
End If
End If
End If
'修改記錄
.Fields("編號") = Trim(txtNum)
.Fields("名稱") = Trim(txtName)
'執行更新操作
objDepart.Update
MsgBox "數據保存成功！", vbInformation, "系部信息管理"
isAdding = False
'顯示當前記錄編號和記錄總數
txtNews = "記錄：" & objDepart.AbsolutePosition & "/" & objDepart.RecordCount
End With
End Sub
Private Sub Form_Unload(Cancel As Integer)
objCn.Close '關閉數據聯接
Set objCn = Nothing '釋放數據庫聯接
Set objDepart = Nothing '釋放記錄集對象
End Sub
Private Sub txtName_KeyPress(KeyAscii As Integer)
'如果敲回車鍵，使保存按鈕獲得焦點
If KeyAscii = vbKeyReturn Then cmdSave.SetFocus
End Sub
'限制編號輸入
Private Sub txtNum_KeyPress(KeyAscii As Integer)
'如果敲回車鍵，使下一控件獲得焦點
If KeyAscii = vbKeyReturn Then SendKeys "{TAB}"
If Not (Chr(KeyAscii) Like "[0-9]" Or KeyAscii = vbKeyBack) Then
KeyAscii = 0 '輸入不是數字或退格鍵，取消輸入
End If
End Sub
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -