/clear
/prep7  
et,1,plane42
et,2,solid45
mp,ex,1,2.5e10       !樁的彈性模量
mp,nuxy,1,0.2        !樁的泊松比
mp,dens,1,2500       !樁的密度
mp,ex,2,2.5e8        !土的彈性模量
mp,nuxy,2,0.4        !土的泊松比
mp,dens,2,2000       !土的密度   
tb,dp,2 
tbdata,1,19,32,30       !粘聚力c為19,摩擦角為32度,膨脹角為30

RECTNG,0,1,0,8,      !面1
RECTNG,1,5,0,6,      !面2
RECTNG,0,5,0,-16,    !面3
/pnum,area,1
/pnum,line,1
asel,s,,,2,3,1
aglue,all
numcmp,all
allsel
aplot

lsel,s,,,1,3,2       !劃分面1  
lesize,all,,,2  
lsel,s,,,2,4,2  
lesize,all,,,16
amesh,1 

lsel,s,,,6,8,2       !劃分面2
lesize,all,0.5  
lsel,s,,,5
lesize,all,0.5
lsel,s,,,7
lesize,all,0.5
amesh,2 

lsel,s,,,11             !劃分面3
lesize,all,0.5  
lsel,s,,,12
lesize,all,0.5
lsel,s,,,10
lesize,all,0.5  
lsel,s,,,9
lesize,all,0.5  
amesh,3


EXTOPT,ESIZE,2,0,        !拉伸成體1
EXTOPT,ACLEAR,1
type,2
mat,1
VEXT,1,,,,,-1

EXTOPT,ESIZE,2,0,        !拉伸成體2，3
EXTOPT,ACLEAR,1
mat,2
VEXT,2,3,1,,,-1
allsel
/view,1,1,1,1
eplot

k,1001,5,6,-5
k,1002,5,0,-5
k,1003,5,-16,-5
l,18,1001
l,1001,1002
l,1002,17
l,1002,1003
l,1003,21
al,22,36,37,38          !面4和面5
al,30,38,39,40

EXTOPT,ESIZE,10,0,      
EXTOPT,ACLEAR,1
VEXT,19,20,1,-5         !拉伸成體4和5
vplot    

vsel,s,,,4,5,1
vplot
lsel,s,,,36,52,1
lesize,all,0.5
type,2
mat,2
vmesh,all               !劃分體4和5
allsel
                 
vsel,s,,,2,5,1           !合并體2，3，4，5上的重復單元及節點
VPLOT   
ESLV,S
NSLV,S,1  
EPLOT 
nummrg,all
numcmp,all
numcmp,all
allsel
/pnum,area,1
/view,1,1,1,1
/ang,1
/pnum,mat,1,2
eplot

!接觸單元設置
allsel
et,3,170
et,4,173
keyopt,4,9,0
keyopt,4,12,2
r,10
real,10
mp,mu,2,0.2

vsel,s,,,1
vplot
asel,s,,,4,6,1
aplot
cm,target,area
type,3
nsla,s,1
esurf,all
esel,s,type,,3
eplot
/psyms,esys,1
allsel

vsel,s,,,2,5,1
vplot
asel,s,,,13
asel,a,,,17
asel,a,,,22
aplot
cm,contact,area
type,4
nsla,s,1
esurf,all
esel,s,type,,4
eplot
/psyms,esys,1
allsel
gplot
finish

/solu
asel,s,loc,x,0
aplot
DA,all,symm
asel,s,loc,x,5
DA,all,all
aplot
asel,s,loc,z,0
da,all,symm
asel,s,loc,z,-5
da,all,all
asel,s,loc,y,-16
da,all,all
allsel

ACEL,0,9.8,0,
nsel,s,loc,y,8
esln,s
eplot
sfe,all,3,pres,,50
antype,static
nlgeom,on
time,1
nsub,100
outres,all,all
allsel
solv
finish