!采用均勻網格劃分，同時取消兩種墊片,DMX=6.415,最大第一主應力263.629，28個子部計算完畢
/clear,nostart
/config,nres,5000
/prep7
!定義單元類型
et,1,solid65            !混凝土單元
et,2,pipe20		!鋼筋單元
et,3,plane42		!用于拉伸成體單元之用

!定義實常數
r,1,18,8.99		!縱向受拉鋼筋實常數	
r,2,8,3.99		!縱向受壓鋼筋，箍筋實常數
r,3			!混凝土
			
!定義材料屬性
mp,ex,1,24000		!混凝土材料屬性
mp,prxy,1,0.2		
tb,conc,1,1,9
tbdata,,0.4,1,3,-1

mp,ex,2,2e5		!縱向受拉鋼筋
mp,prxy,2,0.3
tb,bkin,2,1,2,1
tbdata,,350

mp,ex,3,2e5		!橫向箍筋，受壓鋼筋材料屬性
mp,prxy,3,0.25
tb,bkin,3,1,2,1
tbdata,,200

/pnum,node,1
/pnum,elem,1

!!產生所有的節點**********!!!
n,1
n,9,150
fill,1,9
ngen,11,9,1,9,1,,30
ngen,19,1000,1,99,1,,,-75
/view,1,1,1,1	

!!!!!!!箍筋，受壓鋼筋*******!!!!
type,2
real,2
mat,3
!水平箍筋
*do,ii,11,16,1
  e,ii,ii+1
*enddo
*do,ii,83,88,1
  e,ii,ii+1
*enddo
!豎直箍筋
*do,ii,11,74,9
  e,ii,ii+9
*enddo
*do,ii,17,80,9
  e,ii,ii+9
*enddo
!產生整個模型的箍筋
egen,19,1000,1,28,1
!此時最大的單元編號為532

!縱向受壓鋼筋
*do,ii,83,17083,1000
  e,ii,ii+1000
*enddo
*do,ii,89,17089,1000
  e,ii,ii+1000
*enddo


!!!!!縱向受拉鋼筋************!!!!!!!!!!
type,2
real,1
mat,2
*do,ii,11,17011,1000
  e,ii,ii+1000
*enddo
*do,ii,17,17017,1000
  e,ii,ii+1000
*enddo
!此時最大單元編號為604
/view,1,1,1,1
/pnum,elem,0
/pnum,node,0
/eshape,1
eplot

!!!**********生成面單元，以便拉伸成體單元!!!!!!

k,1
k,2,150,
k,3,150,300
k,4,,300
a,1,2,3,4

lsel,s,loc,y,0
lsel,a,loc,y,300
lesize,all,,,8
lsel,all
lsel,s,loc,x,0
lsel,a,loc,x,150
lesize,all,,,10
type,3
amesh,all

type,1			!拉伸成混凝土單元
real,3
mat,1
extopt,esize,18
extopt,aclear,1
vext,all,,,,,-1350


/pnum,mat,1
/pnum,node,0
/pnum,elem,0
/view,1,1,1,1
eplot
allsel
nummrg,all
numcmp,all
eplot


/solu
nsel,s,loc,y,-0		!右邊界約束
nsel,r,loc,z,-1275
d,all,uy
d,all,ux


asel,s,loc,z,0		!對稱面約束
da,all,symm

nsel,all		!施加外部載荷
nsel,s,loc,y,300
nsel,r,loc,z,-600
d,all,uy,-5

allsel
gplot

nlgeom,on
NSUBST,200   
OUTRES,ALL,ALL  
NEQIT,50
pred,on
CNVTOL,F, ,0.05,2,0.5
allsel
SOLVE   
FINISH 

/post1
allsel
/DEVICE,VECTOR,1
PLCRACK,0,1			!顯示第一開裂位置
PLCRACK,0,2			!顯示第二開裂位置
!/DEVICE,VECTOR,0
!PLNSOL,U,Y,0,1

!ESEL,S,TYPE,,2
!PLNSOL,S,1,0,1