!/FILNAME,OIL_PIPE_STRESS_ANALYSIS
!/TITLE,STRESS ANALYSIS TO AN UNDERGROUND OIL PIPELINE

!定義APDL參數：尺寸、材料和載荷參數
DIAMETER=420                !管道外徑，單位為mm
THICKNESS=10                !管道壁厚，單位為mm
!RADIUS1=210                !管道外半徑，單位為mm
!RADIUS2=200                !管道內半徑，單位為mm
YOUNG=2.1E5                 !管道材料彈性模量，單位為MPa
TANG=0.81E5                 !管道材料剪切模量，單位為MPa
POSONG=0.3                  !泊松比
DENSITY=7.8E-9              !管道材料密度，單位為噸/立方毫米
DEPTH=3.02                  !腐蝕缺陷深度，    單位為mm
PRESSURE=7.64               !管道內壓，        單位為MPa
YIELDSTRESS=312             !管道材料屈服應力，單位為MPa
RESISTANCE=450              !管道材料抗拉強度，單位為MPa
RADIUS1=DIAMETER/2          !管道外半徑，單位為mm
RADIUS2=RADIUS1-THICKNESS   !管道內半徑，單位為mm
LIMITSTATUSFUN=0            !管道的極限狀態函數值

!參數化定義有限元模型
/PREP7
!定義單元類型
ET,1,PLANE82
KEYOPT,1,3,2
KEYOPT,1,5,0
KEYOPT,1,6,0

!定義材料屬性 
MP,EX,1,YOUNG              !輸入彈性模量
MP,PRXY,1,POSONG           !輸入泊松比
MP,DENS,1,DENSITY          !輸入密度
TB,BKIN,1,1,2              !動力學硬化
TBDATA,,YIELDSTRESS,TANG   !輸入屈服強度和剪切模量

!創建幾何模型 
CYL4,,,RADIUS2,0,RADIUS1,90
WPROT,-45
CYL4,0,RADIUS1,DEPTH
ASBA,1,2
WPROT,45 
/RGB,INDEX,100,100,100,0
/RGB,INDEX,80,80,80,13
/RGB,INDEX,60,60,60,14
/RGB,INDEX,0,0,0,15
!APLOT
!/TITLE,GEOMETRIC MODEL
!/REPLOT

!對面進行網格劃分
!APLOT
SMRT,1  
MSHAPE,0,2D 
MSHKEY,0
CM,_Y,AREA  
ASEL, , , ,3 
CM,_Y1,AREA 
CHKMSH,'AREA'   
CMSEL,S,_Y  
AMESH,_Y1   
CMDELE,_Y   
CMDELE,_Y1  
CMDELE,_Y2
ALLSEL
!/TITLE,ELEMENTS IN MODEL
!EPLOT
FINISH

!施加載荷和邊界條件并執行求解
/SOLU
!結構非線性分析
ANTYPE,0
NLGEOM,ON
PRED,ON
TIME,1
NSUBST,100,1000,1
AUTOTS,1
OUTRES,ALL,1
   
!弧長法
!ARCLEN,1,25,0.001   
!AUTOTS,-1.0 
!RESCONTRL,DEFINE,ALL,1,1

!選擇內表面節點并施加壓力載荷
!LPLOT
LSEL,S,,,3
NSLL,S,1
SF,ALL,PRES,PRESSURE

!選擇兩個端面并施加位移約束
LSEL,S,,,2
NSLL,S,1
D,ALL,UX
LSEL,S,,,4
NSLL,S,1
D,ALL,UY
ALLSEL

!執行求解
SOLVE
SAVE
FINISH

!結果后處理
/POST1
SET,LAST
!顯示管道變形和未變形形狀
!/TITLE,DEFORMED SHAPE AND UNDEFORMED SHAPE
!PLDISP,1

!繪制X方向位移等值線圖
!/TITLE,CONTOUR OF DISPLACEMENT IN X DIRECTION
!PLNSOL,U,X

!繪制Y方向位移等值線圖
!/TITLE,CONTOUR OF DISPLACEMENT IN Y DIRECTION
!PLNSOL,U,Y

!繪制合位移等值線圖
!/TITLE,CONTOUR OF SUM DISPLACEMENTS
!PLNSOL,U,SUM

!繪制X方向應力等值線圖
!/TITLE,STRESS CONTOUR IN X DIRECTION
!PLNSOL,S,X

!繪制Y方向應力等值線圖
!/TITLE,STRESS CONTOUR IN Y DIRECTION
!PLNSOL,S,Y

!繪制等效應力等值線圖
!/TITLE,CONTOUR OF EQUIVALENT STRESS
!PLNSOL,S,EQV

!繪制等效應變等值線圖
!/TITLE,CONTOUR OF EQUIVALENT STRAIN
!PLNSOL,EPTO,EQV

!提取管道的最大應力值
NSEL,ALL                             !選中所有節點
NSORT,S,EQV,1,1                      !按照應力絕對值的升序進行節點排序
*GET,MAXSTRESS,SORT,0,MAX            !提取最大絕對值應力值并賦值給MAXSTRESS
LIMITSTATUSFUN=RESISTANCE-MAXSTRESS     !計算管道的極限狀態函數值并賦值給LIMITSTATUSFUN
!/TITLE,
FINISH