;------------------------------------------------------------------------------
;-         ATMEL Microcontroller Software Support  -  ROUSSET  -
;------------------------------------------------------------------------------
; The software is delivered "AS IS" without warranty or condition of any
; kind, either express, implied or statutory. This includes without
; limitation any warranty or condition with respect to merchantability or
; fitness for any particular purpose, or against the infringements of
; intellectual property rights of others.
;-----------------------------------------------------------------------------
;- File source          : it_handler.s
;- Object               : Example of IT handler calling a C function
;- Compilation flag     : None
;-
;- 1.0 16/03/01 	ODi, : Creation ARM ADS
;------------------------------------------------------------------------------
	AREA        itHandler, CODE, READONLY
;------------------------------------------------------------------------------
;- LISR vector handler for system peripherals
;--------------------------------------------
;- This macro save the context, call the LISR dispatch routine, and restore
;- the context
;------------------------------------------------------------------------------
    INCLUDE   AT91RM3400.inc

;--------------------------------
;- ARM Core Mode and Status Bits
;--------------------------------

ARM_MODE_USER           EQU     0x10
ARM_MODE_FIQ            EQU     0x11
ARM_MODE_IRQ            EQU     0x12
ARM_MODE_SVC            EQU     0x13
ARM_MODE_ABORT          EQU     0x17
ARM_MODE_UNDEF          EQU     0x1B
ARM_MODE_SYS            EQU     0x1F

I_BIT                   EQU     0x80
F_BIT                   EQU     0x40
T_BIT                   EQU     0x20


;- IRQ Entry
;- Register initialization
;-      Banked Registers        ; Irq_register
;-      SPSR need to be saved for nested interrupt
;-      R13_irq <- Irq Stack register
;-      R14_irq <- Irq link register
;-      Outpout in ARM_MODE_SVC
;-----------
            MACRO
            IRQ_ENTRY

;- Adjust and save LR_irq in IRQ stack
            sub         lr, lr, #4
            stmfd       sp!, {lr}

;- Write in the IVR to support Protect Mode
;- No effect in Normal Mode
;- De-assert the NIRQ and clear the source in Protect Mode
            ldr         r14, =AT91C_BASE_AIC
            str         r14, [r14, #AIC_IVR]

;- Save SPSR and r0 in IRQ stack
            mrs         r14, SPSR
            stmfd       sp!, {r14}

;- Enable Interrupt and Switch in Supervisor Mode
           msr         CPSR_c, #ARM_MODE_SVC

;- Save scratch/used registers and LR in User Stack
            stmfd       sp!, { r0-r3, r12, r14}

            MEND

;- IRQ Exit
;-----------
            MACRO
     	    IRQ_EXIT
;- Restore scratch/used registers and LR from User Stack
            ldmia       sp!, { r0-r3, r12, r14}

;- Disable Interrupt and switch back in IRQ mode
            msr         CPSR_c, #I_BIT :OR: ARM_MODE_IRQ

;- Mark the End of Interrupt on the AIC
            ldr         r14, =AT91C_BASE_AIC
            str         r14, [r14, #AIC_EOICR]

;- Restore SPSR_irq and r0 from IRQ stack
            ldmia       sp!, {r14}
            msr         SPSR_cxsf, r14

;- Restore adjusted  LR_irq from IRQ stack directly in the PC
            ldmia       sp!, {pc}^

            MEND

;------------------------------------------------------------------------------
	EXPORT AT91F_ST_ASM_HANDLER
	IMPORT AT91F_ST_HANDLER

AT91F_ST_ASM_HANDLER
	IRQ_ENTRY

	ldr     r1, =AT91F_ST_HANDLER
	mov     r14, pc
	bx      r1

	IRQ_EXIT

;------------------------------------------------------------------------------
; AT91F_ASM_DBGU_Handler
; ---------------------
;       Handler called by the AIC
;       
;	Save context
;       Call C handler
; 	Restore context
;------------------------------------------------------------------------------
	EXPORT AT91F_ASM_DBGU_Handler
	IMPORT AT91F_DBGU_Handler
	
AT91F_ASM_DBGU_Handler
	IRQ_ENTRY
	
	ldr     r1, =AT91F_DBGU_Handler
	mov     r14, pc
	bx      r1

	IRQ_EXIT

	END