VALUEH	EQU		20H				;暫存TH1的值
VALUEL	EQU		21H			   	;暫存TL1的值
DVALUE0	EQU		22H				;暫存計(jì)數(shù)值的BCD碼
DVALUE1	EQU		23H
DVALUE2	EQU		24H
DVALUE3	EQU		25H
DVALUE4	EQU		26H
CNT		EQU		30H
KEY		EQU		P3.7
		ORG		00H
		SJMP	START
		ORG		0BH
		LJMP	INT_T0
START:	MOV		DPTR,#TABLE

		MOV		20H,#00H	 	;存儲空間初始化
		MOV		21H,#00H
		MOV		22H,#00H
		MOV		23H,#00H
		MOV		24H,#00H
		MOV		25H,#00H
		MOV		26H,#00H
		MOV		30H,#00H

		MOV		TMOD,#51H		;定時(shí)器0工作在定時(shí)方式
								;定時(shí)器1工作在計(jì)數(shù)方式
		MOV		TH0,#(65536-50000)/256
		MOV		TL0,#(65536-50000)MOD 256
		MOV		TH1,#00H
		MOV		TL1,#00H
		MOV		IE,#8AH
WAIT:	JB		KEY,$
		LCALL	DELAY
		JB		KEY,$			;按鍵為低電平時(shí),開始計(jì)數(shù)
		SETB	TR0
		SETB	TR1
W1:		LCALL	DISP			;顯示計(jì)數(shù)值
		JNB		KEY,W1
		LJMP	START
INT_T0:	MOV		TH0,#(65536-50000)/256
		MOV		TL0,#(65536-50000)MOD 256
		INC		CNT
		MOV		A,CNT
		CJNE	A,#20,RETUNE	;是否計(jì)滿1秒
		MOV		CNT,#00H
		CLR		TR0
		CLR		TR1
		MOV		VALUEL,TL1		;存放計(jì)數(shù)值
		MOV		VALUEH,TH1
		LCALL	HTOD			;將十六進(jìn)制數(shù)轉(zhuǎn)換為十進(jìn)制數(shù)
RETUNE:	RETI
;************************
;這段程序?qū)ALUEH/VALUEL中的16進(jìn)制數(shù)轉(zhuǎn)成10進(jìn)制并且把5位數(shù)依次存入
;DVALUE0至DVALUE4
HTOD:	MOV		R2,VALUEH
		MOV		R3,VALUEL
		CLR		A
		MOV		R4,A
		MOV		R5,A
		MOV		R6,A
		MOV		R7,#10H
LOOP1:	CLR		C
		MOV	A,R3
		RLC	A
		MOV	R3,A
		MOV	A,R2
		RLC	A
		MOV	R2,A
		MOV	A,R6
		ADDC	A,R6
		DA	A
		MOV	R6,A
		MOV	A,R5
		ADDC	A,R5
		DA	A
		MOV	R5,A
		MOV	A,R4
		ADDC	A,R4
		DA	A
		MOV	R4,A
		DJNZ	R7,LOOP1
CZ:		MOV	R0,#DVALUE4
		MOV	A,R6
		ANL	A,#0FH
		MOV	@R0,A
		DEC	R0
		MOV	A,R6
		SWAP	A
		ANL	A,#0FH
		MOV	@R0,A
		DEC	R0
		MOV	A,R5
		ANL	A,#0FH
		MOV	@R0,A
		DEC	R0
		MOV	A,R5
		SWAP	A
		ANL	A,#0FH
		MOV	@R0,A
		DEC	R0
		MOV	A,R4
		ANL	A,#0FH
		MOV	@R0,A
		RET
;***************************
DISP:	MOV		P2,0FFH		   	;顯示子程序
		CLR		P2.0
		MOV		A,DVALUE4
		MOVC	A,@A+DPTR
		MOV		P0,A
		LCALL	DELAY
		SETB	P2.0
		CLR		P2.1
		MOV		A,DVALUE3
		MOVC	A,@A+DPTR
		MOV		P0,A
		LCALL	DELAY
		SETB	P2.1
		CLR		P2.2
		MOV		A,DVALUE2
		MOVC	A,@A+DPTR
		MOV		P0,A
		LCALL	DELAY
		SETB	P2.2
		CLR		P2.3
		MOV		A,DVALUE1
		MOVC	A,@A+DPTR
		MOV		P0,A
		LCALL	DELAY
		SETB	P2.3
		CLR		P2.4
		MOV		A,DVALUE0
		MOVC	A,@A+DPTR
		MOV		P0,A
		LCALL	DELAY
		SETB	P2.4
		RET
DELAY:	MOV		R6,#10		  	;延時(shí)5毫秒
D1:		MOV		R7,#248
		DJNZ	R7,$
		DJNZ	R6,D1
		RET
TABLE: 	DB 		3FH,06H,5BH,4FH,66H
		DB		6DH,7DH,07H,7FH,6FH
		END